072dcb5d2d05def46373bc67e4bf9b00295a0ee1
[potlatch2.git] / net / systemeD / halcyon / connection / Connection.as
1 package net.systemeD.halcyon.connection {
2
3     import flash.net.*;
4
5     import flash.events.EventDispatcher;
6     import flash.events.Event;
7         import net.systemeD.halcyon.Globals;
8         import net.systemeD.halcyon.connection.actions.*;
9
10         public class Connection extends EventDispatcher {
11
12         private static var connectionInstance:Connection = null;
13
14         protected static var policyURL:String;
15         protected static var apiBaseURL:String;
16         protected static var params:Object;
17
18         public static function getConnection(initparams:Object=null):Connection {
19             if ( connectionInstance == null ) {
20             
21                 params = initparams == null ? new Object() : initparams;
22                 policyURL = getParam("policy", "http://127.0.0.1:3000/api/crossdomain.xml");
23                 apiBaseURL = getParam("api", "http://127.0.0.1:3000/api/0.6/");
24                 var connectType:String = getParam("connection", "XML");
25                 
26                 if ( connectType == "XML" )
27                     connectionInstance = new XMLConnection();
28                 else if ( connectType == "OSM" )
29                     connectionInstance = new OSMConnection();
30                 else
31                     connectionInstance = new AMFConnection();
32             }
33             return connectionInstance;
34         }
35
36         public static function getParam(name:String, defaultValue:String):String {
37             return params[name] == null ? defaultValue : params[name];
38         }
39
40         public function get apiBase():String {
41             return apiBaseURL;
42         }
43
44         public static function get serverName():String {
45             return getParam("serverName", "Localhost");
46         }
47                 
48                 public static function getConnectionInstance():Connection {
49             return connectionInstance;
50                 }
51
52                 public function getEnvironment(responder:Responder):void {}
53
54         // connection events
55         public static var LOAD_STARTED:String = "load_started";
56         public static var LOAD_COMPLETED:String = "load_completed";
57         public static var SAVE_STARTED:String = "save_started";
58         public static var SAVE_COMPLETED:String = "save_completed";
59         public static var DATA_DIRTY:String = "data_dirty";
60         public static var DATA_CLEAN:String = "data_clean";
61         public static var NEW_CHANGESET:String = "new_changeset";
62         public static var NEW_CHANGESET_ERROR:String = "new_changeset_error";
63         public static var NEW_NODE:String = "new_node";
64         public static var NEW_WAY:String = "new_way";
65         public static var NEW_RELATION:String = "new_relation";
66         public static var NEW_POI:String = "new_poi";
67         public static var NODE_RENUMBERED:String = "node_renumbered";
68         public static var WAY_RENUMBERED:String = "way_renumbered";
69         public static var RELATION_RENUMBERED:String = "relation_renumbered";
70         public static var TAG_CHANGED:String = "tag_change";
71         public static var NODE_MOVED:String = "node_moved";
72         public static var WAY_NODE_ADDED:String = "way_node_added";
73         public static var WAY_NODE_REMOVED:String = "way_node_removed";
74         public static var WAY_REORDERED:String = "way_reordered";
75         public static var WAY_DRAGGED:String = "way_dragged";
76                 public static var NODE_DELETED:String = "node_deleted";
77                 public static var WAY_DELETED:String = "way_deleted";
78                 public static var RELATION_DELETED:String = "relation_deleted";
79                 public static var RELATION_MEMBER_ADDED:String = "relation_member_added";
80                 public static var RELATION_MEMBER_REMOVED:String = "relation_member_deleted";
81                 public static var ADDED_TO_RELATION:String = "added_to_relation";
82                 public static var REMOVED_FROM_RELATION:String = "removed_from_relation";
83                 public static var SUSPEND_REDRAW:String = "suspend_redraw";
84                 public static var RESUME_REDRAW:String = "resume_redraw";
85
86         // store the data we download
87         private var negativeID:Number = -1;
88         private var nodes:Object = {};
89         private var ways:Object = {};
90         private var relations:Object = {};
91         private var pois:Array = [];
92         private var changeset:Changeset = null;
93                 private var changesetUpdated:Number;
94                 private var modified:Boolean = false;
95                 public var nodecount:int=0;
96                 public var waycount:int=0;
97                 public var relationcount:int=0;
98
99         protected function get nextNegative():Number {
100             return negativeID--;
101         }
102
103         protected function setNode(node:Node, queue:Boolean):void {
104                         if (!nodes[node.id]) { nodecount++; }
105             nodes[node.id] = node;
106             if (node.loaded) { sendEvent(new EntityEvent(NEW_NODE, node),queue); }
107         }
108
109         protected function setWay(way:Way, queue:Boolean):void {
110                         if (!ways[way.id]) { waycount++; }
111             ways[way.id] = way;
112             if (way.loaded) { sendEvent(new EntityEvent(NEW_WAY, way),queue); }
113         }
114
115         protected function setRelation(relation:Relation, queue:Boolean):void {
116                         if (!relations[relation.id]) { relationcount++; }
117             relations[relation.id] = relation;
118             if (relation.loaded) { sendEvent(new EntityEvent(NEW_RELATION, relation),queue); }
119         }
120
121         protected function renumberNode(oldID:Number, node:Node, queue:Boolean):void {
122             nodes[node.id] = node;
123             if (node.loaded) { sendEvent(new EntityRenumberedEvent(NODE_RENUMBERED, node, oldID),queue); }
124             delete nodes[oldID];
125         }
126
127         protected function renumberWay(oldID:Number, way:Way, queue:Boolean):void {
128             ways[way.id] = way;
129             if (way.loaded) { sendEvent(new EntityRenumberedEvent(WAY_RENUMBERED, way, oldID),queue); }
130             delete ways[oldID];
131         }
132
133         protected function renumberRelation(oldID:Number, relation:Relation, queue:Boolean):void {
134             relations[relation.id] = relation;
135             if (relation.loaded) { sendEvent(new EntityRenumberedEvent(RELATION_RENUMBERED, relation, oldID),queue); }
136             delete relations[oldID];
137         }
138
139
140                 public function sendEvent(e:*,queue:Boolean):void {
141                         // queue is only used for AMFConnection
142                         dispatchEvent(e);
143                 }
144
145         public function registerPOI(node:Node):void {
146             if ( pois.indexOf(node) < 0 ) {
147                 pois.push(node);
148                 sendEvent(new EntityEvent(NEW_POI, node),false);
149             }
150         }
151
152         public function unregisterPOI(node:Node):void {
153             var index:uint = pois.indexOf(node);
154             if ( index >= 0 ) {
155                 pois.splice(index,1);
156             }
157         }
158
159         public function getNode(id:Number):Node {
160             return nodes[id];
161         }
162
163         public function getWay(id:Number):Way {
164             return ways[id];
165         }
166
167         public function getRelation(id:Number):Relation {
168             return relations[id];
169         }
170
171                 // Remove data from Connection
172                 // These functions are used only internally to stop redundant data hanging around
173                 // (either because it's been deleted on the server, or because we have panned away
174                 //  and need to reduce memory usage)
175
176                 protected function killNode(id:Number):void {
177                         if (!nodes[id]) return;
178             nodes[id].dispatchEvent(new EntityEvent(Connection.NODE_DELETED, nodes[id]));
179                         if (nodes[id].parentRelations.length>0) {
180                                 nodes[id]=new Node(id,0,{},false,0,0);
181                         } else {
182                                 delete nodes[id];
183                         }
184                         nodecount--;
185                 }
186
187                 protected function killWay(id:Number):void {
188                         if (!ways[id]) return;
189             ways[id].dispatchEvent(new EntityEvent(Connection.WAY_DELETED, ways[id]));
190                         if (ways[id].parentRelations.length>0) {
191                                 ways[id]=new Way(id,0,{},false,[]);
192                         } else {
193                                 delete ways[id];
194                         }
195                         waycount--;
196                 }
197
198                 protected function killRelation(id:Number):void {
199                         if (!relations[id]) return;
200             relations[id].dispatchEvent(new EntityEvent(Connection.RELATION_DELETED, relations[id]));
201                         if (relations[id].parentRelations.length>0) {
202                                 relations[id]=new Relation(id,0,{},false,[]);
203                         } else {
204                                 delete relations[id];
205                         }
206                         relationcount--;
207                 }
208
209                 protected function killWayWithNodes(id:Number):void {
210                         var way:Way=ways[id];
211                         var node:Node;
212                         for (var i:uint=0; i<way.length; i++) {
213                                 node=way.getNode(i);
214                                 if (node.isDirty) { continue; }
215                                 if (node.parentWays.length>1) {
216                                         node.removeParent(way);
217                                 } else {
218                                         killNode(node.id);
219                                 }
220                         }
221                         killWay(id);
222                 }
223                 
224
225
226         public function createNode(tags:Object, lat:Number, lon:Number, performCreate:Function):Node {
227             var node:Node = new Node(nextNegative, 0, tags, true, lat, lon);
228             performCreate(new CreateEntityAction(node, setNode));
229                         //markDirty();
230             return node;
231         }
232
233         public function createWay(tags:Object, nodes:Array, performCreate:Function):Way {
234             var way:Way = new Way(nextNegative, 0, tags, true, nodes.concat());
235             performCreate(new CreateEntityAction(way, setWay));
236                         //markDirty();
237             return way;
238         }
239
240         public function createRelation(tags:Object, members:Array, performCreate:Function):Relation {
241             var relation:Relation = new Relation(nextNegative, 0, tags, true, members.concat());
242             performCreate(new CreateEntityAction(relation, setRelation));
243                         //markDirty();
244             return relation;
245         }
246
247         public function getAllNodeIDs():Array {
248             var list:Array = [];
249             for each (var node:Node in nodes)
250                 list.push(node.id);
251             return list;
252         }
253
254         public function getAllWayIDs():Array {
255             var list:Array = [];
256             for each (var way:Way in ways)
257                 list.push(way.id);
258             return list;
259         }
260
261         public function getAllRelationIDs():Array {
262             var list:Array = [];
263             for each (var relation:Relation in relations)
264                 list.push(relation.id);
265             return list;
266         }
267
268         public function getMatchingRelationIDs(match:Object):Array {
269             var list:Array = [];
270                         var ok:Boolean;
271             for each (var relation:Relation in relations) {
272                                 ok=true;
273                                 if (relation.deleted) { ok=false; }
274                                 for (var k:String in match) {
275                                         if (!relation.getTagsHash()[k] || relation.getTagsHash()[k]!=match[k]) { ok=false; }
276                                 }
277                                 if (ok) { list.push(relation.id); }
278                         }
279             return list;
280         }
281
282                 public function getObjectsByBbox(left:Number, right:Number, top:Number, bottom:Number):Object {
283                         var o:Object = { nodesInside: [], nodesOutside: [], waysInside: [], waysOutside: [] };
284                         for each (var way:Way in ways) {
285                                 if (way.within(left,right,top,bottom)) { o.waysInside.push(way); }
286                                                                   else { o.waysOutside.push(way); }
287                         }
288                         for each (var node:Node in nodes) {
289                                 if (node.within(left,right,top,bottom)) { o.nodesInside.push(node); }
290                                                                    else { o.nodesOutside.push(node); }
291                         }
292                         return o;
293                 }
294
295                 public function purgeOutside(left:Number, right:Number, top:Number, bottom:Number):void {
296                         return;
297                         // ** this doesn't work - WayUIs stick around.
298                         // ** should purge POIs and relations too
299                         for each (var way:Way in ways) {
300                                 if (!way.within(left,right,top,bottom) && !way.isDirty) {
301                                         killWayWithNodes(way.id);
302                                 }
303                         }
304                 }
305
306                 public function markDirty():void {
307             if (!modified) { dispatchEvent(new Event(DATA_DIRTY)); }
308                         modified=true;
309                 }
310                 public function markClean():void {
311             if (modified) { dispatchEvent(new Event(DATA_CLEAN)); }
312                         modified=false;
313                 }
314                 public function get isDirty():Boolean {
315                         return modified;
316                 }
317
318                 // Changeset tracking
319
320         protected function setActiveChangeset(changeset:Changeset):void {
321             this.changeset = changeset;
322                         changesetUpdated = new Date().getTime();
323             sendEvent(new EntityEvent(NEW_CHANGESET, changeset),false);
324         }
325
326                 protected function freshenActiveChangeset():void {
327                         changesetUpdated = new Date().getTime();
328                 }
329                 
330                 protected function closeActiveChangeset():void {
331                         changeset = null;
332                 }
333         
334         public function getActiveChangeset():Changeset {
335                         if (changeset && (new Date().getTime()) > (changesetUpdated+58*60*1000)) {
336                                 closeActiveChangeset();
337                         }
338             return changeset;
339         }
340         
341
342         // these are functions that the Connection implementation is expected to
343         // provide. This class has some generic helpers for the implementation.
344                 public function loadBbox(left:Number, right:Number,
345                                                                 top:Number, bottom:Number):void {
346             }
347             
348             public function setAppID(id:Object):void {}
349             public function setAuthToken(id:Object):void {}
350             public function createChangeset(tags:Object):void {}
351                 public function closeChangeset():void {}
352             public function uploadChanges():void {}
353     }
354
355 }
356