better "drop point or drag map?" detection (same logic as P1)
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19         import net.systemeD.halcyon.Globals;
20
21 //      for experimental export function:
22 //      import flash.net.FileReference;
23 //      import com.adobe.images.JPGEncoder;
24
25     public class Map extends Sprite {
26
27                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
28                                                                                                                 // (for Landsat, 5120)
29                 public const MINSCALE:uint=13;                                  // don't zoom out past this
30                 public const MAXSCALE:uint=23;                                  // don't zoom in past this
31
32                 public var paint:MapPaint;                                              // sprite for ways and (POI/tagged) nodes in core layer
33                 public var vectorbg:Sprite;                                             // sprite for vector background layers
34
35                 public var scale:uint=14;                                               // map scale
36                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
37                 public var bigedge_l:Number= 999999;                    // area of largest whichways
38                 public var bigedge_r:Number=-999999;                    //  |
39                 public var bigedge_b:Number= 999999;                    //  |
40                 public var bigedge_t:Number=-999999;                    //  |
41
42                 public var edge_l:Number;                                               // current bounding box
43                 public var edge_r:Number;                                               //  |
44                 public var edge_t:Number;                                               //  |
45                 public var edge_b:Number;                                               //  |
46                 public var centre_lat:Number;                                   // centre lat/lon
47                 public var centre_lon:Number;                                   //  |
48
49                 public var baselon:Number;                                              // urllon-xradius/masterscale;
50                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
51                 public var mapwidth:uint;                                               // width (Flash pixels)
52                 public var mapheight:uint;                                              // height (Flash pixels)
53
54                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map
55                 private var _draggable:Boolean=true;                    //  |
56                 private var lastxmouse:Number;                                  //  |
57                 private var lastymouse:Number;                                  //  |
58                 private var downX:Number;                                               //  |
59                 private var downY:Number;                                               //  |
60                 private var downTime:Number;                                    //  |
61                 public const NOT_DRAGGING:uint=0;                               //  |
62                 public const NOT_MOVED:uint=1;                                  //  |
63                 public const DRAGGING:uint=2;                                   //  |
64                 public const TOLERANCE:uint=7;                                  //  |
65                 
66                 public var initparams:Object;                                   // object containing HTML page parameters
67
68                 public var backdrop:Object;                                             // reference to backdrop sprite
69                 public var tileset:TileSet;                                             // 900913 tile background
70                 private var tileurl:String='';                                  // internal tile URL
71                 private var styleurl:String='';                                 // internal style URL
72                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
73                 
74                 public var connection:Connection;                               // server connection
75                 public var vectorlayers:Object={};                              // VectorLayer objects 
76
77                 public const TILESPRITE:uint=0;
78                 public const VECTORSPRITE:uint=1;
79                 public const WAYSPRITE:uint=2;
80                 public const NAMESPRITE:uint=13;
81                 
82                 // ------------------------------------------------------------------------------------------
83                 // Map constructor function
84
85         public function Map(initparams:Object) {
86
87                         this.initparams=initparams;
88                         connection = Connection.getConnection(initparams);
89             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
90             connection.addEventListener(Connection.NEW_POI, newPOICreated);
91             connection.addEventListener(Connection.WAY_RENUMBERED, wayRenumbered);
92             connection.addEventListener(Connection.NODE_RENUMBERED, nodeRenumbered);
93                         gotEnvironment(null);
94
95                         addEventListener(Event.ENTER_FRAME, everyFrame);
96         }
97
98                 public function gotEnvironment(r:Object):void {
99                         var loader:Loader = new Loader();
100                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
101                         loader.load(new URLRequest("FontLibrary.swf"));
102                 }
103                 
104                 public function gotFont(r:Event):void {
105                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
106                         Font.registerFont(FontLibrary.DejaVu);
107
108                         if (initparams['lat'] != null) {
109                                 // parameters sent from HTML
110                                 init(initparams['lat'],
111                                          initparams['lon'],
112                                          initparams['zoom']);
113
114                         } else {
115                                 // somewhere innocuous
116                                 init(53.09465,-2.56495,17);
117                         }
118                 }
119
120                 // ------------------------------------------------------------------------------------------
121                 // Initialise map at a given lat/lon
122
123         public function init(startlat:Number,startlon:Number,startscale:uint=0):void {
124                         while (numChildren) { removeChildAt(0); }
125
126                         tileset=new TileSet(this);                                      // 0 - 900913 background
127                         addChild(tileset);                                                      //   |
128                         tileset.init(tileurl);                                          //   |
129
130                         vectorbg = new Sprite();                                        // 1 - vector background layers
131                         addChild(vectorbg);                                                     //   |
132
133                         paint = new MapPaint(this,-5,5);                        // 2 - core paint object
134                         addChild(paint);                                                        //   |
135                         paint.isBackground=false;                                       //   |
136
137                         if (styleurl) {                                                         // if we've only just set up paint, then setStyle won't have created the RuleSet
138                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
139                                 paint.ruleset.loadFromCSS(styleurl);
140                         }
141                         if (startscale>0) { scale=startscale; }
142
143                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
144                         baselon    =startlon          -(mapwidth /2)/scalefactor;
145                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
146                         addDebug("Baselon "+baselon+", basey "+basey);
147                         updateCoords(0,0);
148                         download();
149                         
150         }
151
152                 // ------------------------------------------------------------------------------------------
153                 // Recalculate co-ordinates from new Flash origin
154
155                 public function updateCoords(tx:Number,ty:Number):void {
156                         x=tx; y=ty;
157
158                         edge_t=coord2lat(-y          );
159                         edge_b=coord2lat(-y+mapheight);
160                         edge_l=coord2lon(-x          );
161                         edge_r=coord2lon(-x+mapwidth );
162                         setCentre();
163
164                         tileset.update();
165                 }
166                 
167                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
168                         var cy:Number=-(lat2coord(lat)-mapheight/2);
169                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
170                         updateCoords(cx,cy);
171                 }
172                 
173                 private function setCentre():void {
174                         centre_lat=coord2lat(-y+mapheight/2);
175                         centre_lon=coord2lon(-x+mapwidth/2);
176                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale}));
177                 }
178                 
179                 public function nudgeBackground(x:Number,y:Number):void {
180                         this.dispatchEvent(new MapEvent(MapEvent.NUDGE_BACKGROUND, { x: x, y: y }));
181                 }
182
183                 // Co-ordinate conversion functions
184
185                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
186                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
187                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
188                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
189
190                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
191                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
192
193                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
194                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
195
196 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
197 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
198
199
200                 // ------------------------------------------------------------------------------------------
201                 // Resize map size based on current stage and height
202
203                 public function updateSize(w:uint, h:uint):void {
204                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
205                         
206                         mapwidth = w;
207                         mapheight= h;
208             if ( backdrop != null ) {
209                 backdrop.width=mapwidth;
210                 backdrop.height=mapheight;
211             }
212             if ( mask != null ) {
213                 mask.width=mapwidth;
214                 mask.height=mapheight;
215             }
216                 }
217
218                 // ------------------------------------------------------------------------------------------
219                 // Download map data
220                 // (typically from whichways, but will want to add more connections)
221
222                 public function download():void {
223                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
224                         
225                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
226                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
227                         bigedge_l=edge_l; bigedge_r=edge_r;
228                         bigedge_b=edge_b; bigedge_t=edge_t;
229                         if (connection.waycount>1000) {
230                                 connection.purgeOutside(edge_l,edge_r,edge_t,edge_b);
231                         }
232                         addDebug("Calling download with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
233                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
234                 }
235
236         private function newWayCreated(event:EntityEvent):void {
237             var way:Way = event.entity as Way;
238                         if (!way.loaded || !way.within(edge_l,edge_r,edge_t,edge_b)) { return; }
239                         paint.createWayUI(way);
240         }
241
242         private function newPOICreated(event:EntityEvent):void {
243             var node:Node = event.entity as Node;
244                         if (!node.within(edge_l,edge_r,edge_t,edge_b)) { return; }
245                         paint.createNodeUI(node);
246         }
247
248                 private function wayRenumbered(event:EntityRenumberedEvent):void {
249             var way:Way = event.entity as Way;
250                         paint.renumberWayUI(way,event.oldID);
251                 }
252
253                 private function nodeRenumbered(event:EntityRenumberedEvent):void {
254             var node:Node = event.entity as Node;
255                         paint.renumberNodeUI(node,event.oldID);
256                 }
257
258         public function setHighlight(entity:Entity, settings:Object):void {
259                         if      ( entity is Way  ) { paint.wayuis[entity.id].setHighlight(settings); }
260                         else if ( entity is Node ) { paint.nodeuis[entity.id].setHighlight(settings); }
261         }
262
263         public function setHighlightOnNodes(way:Way, settings:Object):void {
264                         paint.wayuis[way.id].setHighlightOnNodes(settings);
265         }
266
267                 public function setPurgable(entity:Entity, purgable:Boolean):void {
268                         if ( entity is Way  ) {
269                                 var way:Way=entity as Way;
270                                 paint.wayuis[way.id].purgable=purgable;
271                                 for (var i:uint=0; i<way.length; i++) {
272                                         if (paint.nodeuis[way.getNode(i).id]) {
273                                                 paint.nodeuis[way.getNode(i).id].purgable=purgable;
274                                         }
275                                 }
276                         } else if ( entity is Node ) { 
277                                 paint.nodeuis[entity.id].purgable=purgable;
278                         }
279                 }
280
281         // Handle mouse events on ways/nodes
282         private var mapController:MapController = null;
283
284         public function setController(controller:MapController):void {
285             this.mapController = controller;
286         }
287
288         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
289             if ( mapController != null )
290                 mapController.entityMouseEvent(event, entity);
291                                 
292         }
293
294                 // ------------------------------------------------------------------------------------------
295                 // Add vector layer
296                 
297                 public function addVectorLayer(layer:VectorLayer):void {
298                         vectorlayers[layer.name]=layer;
299                         vectorbg.addChild(layer.paint);
300                 }
301
302                 // ------------------------------------------------------------------------------------------
303                 // Redraw all items, zoom in and out
304                 
305                 public function updateEntityUIs(redraw:Boolean,remove:Boolean):void {
306                         paint.updateEntityUIs(connection.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
307                         for each (var v:VectorLayer in vectorlayers) {
308                                 v.paint.updateEntityUIs(v.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
309                         }
310                 }
311                 public function redraw():void {
312                         paint.redraw();
313                         for each (var v:VectorLayer in vectorlayers) { v.paint.redraw(); }
314                 }
315                 public function redrawPOIs():void { 
316                         paint.redrawPOIs();
317                         for each (var v:VectorLayer in vectorlayers) { v.paint.redrawPOIs(); }
318                 }
319                 
320                 public function zoomIn():void {
321                         if (scale==MAXSCALE) { return; }
322                         changeScale(scale+1);
323                 }
324
325                 public function zoomOut():void {
326                         if (scale==MINSCALE) { return; }
327                         changeScale(scale-1);
328                 }
329
330                 private function changeScale(newscale:uint):void {
331                         addDebug("new scale "+newscale);
332                         scale=newscale;
333                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
334                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
335                         tileset.changeScale(scale);
336                         updateEntityUIs(true,true);
337                         download();
338                 }
339
340                 private function reportPosition():void {
341                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
342                 }
343                 
344                 public function setStyle(url:String):void {
345                         styleurl=url;
346                         if (paint) { 
347                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
348                                 paint.ruleset.loadFromCSS(url);
349                         }
350         }
351
352                 public function setBackground(url:String):void {
353                         tileurl=url;
354                         if (tileset) { tileset.init(url, url!=''); }
355                 }
356
357                 public function setDimming(dim:Boolean):void {
358                         if (tileset) { tileset.setDimming(dim); }
359                 }
360
361                 // ------------------------------------------------------------------------------------------
362                 // Export (experimental)
363                 // ** just a bit of fun for now!
364                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
365                 // to that area (will probably require creating a new DisplayObject with a different origin
366                 // and mask)
367 /*              
368                 public function export():void {
369                         addDebug("size is "+this.width+","+this.height);
370                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
371                         jpgSource.draw(this);
372                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
373                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
374                         var fileRef:FileReference = new FileReference();
375 //                      fileRef.save(jpgStream,'map.jpeg');
376                 }
377
378 */
379
380                 // ==========================================================================================
381                 // Events
382                 
383                 // ------------------------------------------------------------------------------------------
384                 // Mouse events
385                 
386                 public function set draggable(draggable:Boolean):void {
387                         _draggable=draggable;
388                         dragstate=NOT_DRAGGING;
389                 }
390
391                 public function mouseDownHandler(event:MouseEvent):void {
392                         if (!_draggable) { return; }
393                         dragstate=NOT_MOVED;
394                         lastxmouse=mouseX; downX=stage.mouseX;
395                         lastymouse=mouseY; downY=stage.mouseY;
396                         downTime=new Date().getTime();
397                 }
398         
399                 public function mouseUpHandler(event:MouseEvent=null):void {
400                         if (dragstate==DRAGGING) {
401                                 updateCoords(x,y);
402                                 updateEntityUIs(false, false);
403                                 download();
404                         }
405                         dragstate=NOT_DRAGGING;
406                 }
407         
408                 public function mouseMoveHandler(event:MouseEvent):void {
409                         if (!_draggable) { return; }
410                         if (dragstate==NOT_DRAGGING) { return; }
411                         
412                         if (dragstate==NOT_MOVED) {
413                                 if (new Date().getTime()-downTime<300) {
414                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE   && Math.abs(downY-stage.mouseY)<=TOLERANCE  ) return;
415                                 } else {
416                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE/2 && Math.abs(downY-stage.mouseY)<=TOLERANCE/2) return;
417                                 }
418                                 dragstate=DRAGGING;
419                         }
420                         
421                         x+=mouseX-lastxmouse;
422                         y+=mouseY-lastymouse;
423                         lastxmouse=mouseX; lastymouse=mouseY;
424                         setCentre();
425                 }
426         
427                 // ------------------------------------------------------------------------------------------
428                 // Do every frame
429
430                 private function everyFrame(event:Event):void {
431                         if (tileset) { tileset.serviceQueue(); }
432                 }
433
434                 // ------------------------------------------------------------------------------------------
435                 // Miscellaneous events
436                 
437                 public function keyUpHandler(event:KeyboardEvent):void {
438                         addDebug("pressed "+event.keyCode);
439                         if (event.keyCode==33) { zoomIn(); }                    // Page Up - zoom in
440                         if (event.keyCode==34) { zoomOut(); }                   // Page Down - zoom out
441 //                      if (event.keyCode==76) { reportPosition(); }    // L - report lat/long
442                 }
443
444                 public function connectionError(err:Object=null): void {
445                         addDebug("got error"); 
446                 }
447
448                 // ------------------------------------------------------------------------------------------
449                 // Debugging
450                 
451                 public function clearDebug():void {
452                         if (!Globals.vars.hasOwnProperty('debug')) return;
453                         Globals.vars.debug.text='';
454                 }
455                         
456                 public function addDebug(text:String):void {
457                         if (!Globals.vars.hasOwnProperty('debug')) return;
458                         if (!Globals.vars.debug.visible) return;
459                         Globals.vars.debug.appendText(text+"\n");
460                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
461                 }
462
463         }
464 }