net/systemeD/halcyon/connection/XMLConnection.as

   1 package net.systemeD.halcyon.connection {
   2
   3     import flash.events.*;
   4
   5         import flash.system.Security;
   6         import flash.net.*;
   7     import org.iotashan.oauth.*;
   8
   9         import net.systemeD.halcyon.Globals;
  10
  11         public class XMLConnection extends XMLBaseConnection {
  12
  13         //public var readConnection:NetConnection;
  14
  15                 public function XMLConnection() {
  16
  17                         if (Connection.policyURL!='')
  18                 Security.loadPolicyFile(Connection.policyURL);
  19             var oauthPolicy:String = Connection.getParam("oauth_policy", "");
  20             if ( oauthPolicy != "" ) {
  21                 trace(oauthPolicy);
  22                 Security.loadPolicyFile(oauthPolicy);
  23             }
  24                 }
  25
  26                 override public function loadBbox(left:Number,right:Number,
  27                                                                 top:Number,bottom:Number):void {
  28             var mapVars:URLVariables = new URLVariables();
  29             mapVars.bbox= left+","+bottom+","+right+","+top;
  30
  31             var mapRequest:URLRequest = new URLRequest(Connection.apiBaseURL+"map");
  32             mapRequest.data = mapVars;
  33
  34             var mapLoader:URLLoader = new URLLoader();
  35             mapLoader.addEventListener(Event.COMPLETE, loadedMap);
  36             mapLoader.addEventListener(IOErrorEvent.IO_ERROR, errorOnMapLoad);
  37             mapLoader.addEventListener(HTTPStatusEvent.HTTP_STATUS, mapLoadStatus);
  38             mapLoader.load(mapRequest);
  39             dispatchEvent(new Event(LOAD_STARTED));
  40                 }
  41
  42         private function errorOnMapLoad(event:Event):void {
  43             trace("error loading map");
  44         }
  45         private function mapLoadStatus(event:HTTPStatusEvent):void {
  46             trace("loading map status = "+event.status);
  47         }
  48
  49         protected var appID:OAuthConsumer;
  50         protected var authToken:OAuthToken;
  51
  52             override public function setAppID(id:Object):void {
  53                 appID = OAuthConsumer(id);
  54             }
  55
  56             override public function setAuthToken(id:Object):void {
  57                 authToken = OAuthToken(id);
  58             }
  59
  60         private var httpStatus:int = 0;
  61
  62         private function recordStatus(event:HTTPStatusEvent):void {
  63             httpStatus = event.status;
  64         }
  65
  66         private var lastUploadedChangesetTags:Object;
  67
  68         override public function createChangeset(tags:Object):void {
  69             lastUploadedChangesetTags = tags;
  70
  71                 var changesetXML:XML = <osm version="0.6"><changeset /></osm>;
  72                 var changeset:XML = <changeset />;
  73                 for (var tagKey:Object in tags) {
  74               var tagXML:XML = <tag/>;
  75               tagXML.@k = tagKey;
  76               tagXML.@v = tags[tagKey];
  77               changesetXML.changeset.appendChild(tagXML);
  78             }
  79
  80             // make an OAuth query
  81             var sig:IOAuthSignatureMethod = new OAuthSignatureMethod_HMAC_SHA1();
  82             var url:String = Connection.apiBaseURL+"changeset/create";
  83             //var params:Object = { _method: "PUT" };
  84             var oauthRequest:OAuthRequest = new OAuthRequest("PUT", url, null, appID, authToken);
  85             var urlStr:Object = oauthRequest.buildRequest(sig, OAuthRequest.RESULT_TYPE_URL_STRING)
  86
  87             // build the actual request
  88             var urlReq:URLRequest = new URLRequest(String(urlStr));
  89             urlReq.method = "POST";
  90             urlReq.data = changesetXML.toXMLString();
  91             urlReq.contentType = "application/xml";
  92             urlReq.requestHeaders = new Array(new URLRequestHeader("X_HTTP_METHOD_OVERRIDE", "PUT"));
  93             var loader:URLLoader = new URLLoader();
  94             loader.addEventListener(Event.COMPLETE, changesetCreateComplete);
  95             loader.addEventListener(IOErrorEvent.IO_ERROR, changesetCreateError);
  96             loader.addEventListener(HTTPStatusEvent.HTTP_STATUS, recordStatus);
  97                 loader.load(urlReq);
  98             }
  99
 100         private function changesetCreateComplete(event:Event):void {
 101             // response should be a Number changeset id
 102             var id:Number = Number(URLLoader(event.target).data);
 103
 104             // which means we now have a new changeset!
 105             setActiveChangeset(new Changeset(id, lastUploadedChangesetTags));
 106         }
 107
 108         private function changesetCreateError(event:IOErrorEvent):void {
 109             dispatchEvent(new Event(NEW_CHANGESET_ERROR));
 110         }
 111
 112         override public function uploadChanges():void {
 113             var changeset:Changeset = getActiveChangeset();
 114             var upload:XML = <osmChange version="0.6"/>
 115             upload.appendChild(addCreated(changeset, getAllNodeIDs, getNode, serialiseNode));
 116             upload.appendChild(addCreated(changeset, getAllWayIDs, getWay, serialiseWay));
 117             upload.appendChild(addCreated(changeset, getAllRelationIDs, getRelation, serialiseRelation));
 118             upload.appendChild(addModified(changeset, getAllNodeIDs, getNode, serialiseNode));
 119             upload.appendChild(addModified(changeset, getAllWayIDs, getWay, serialiseWay));
 120             upload.appendChild(addModified(changeset, getAllRelationIDs, getRelation, serialiseRelation));
 121             upload.appendChild(addDeleted(changeset, getAllRelationIDs, getRelation, serialiseEntityRoot));
 122             upload.appendChild(addDeleted(changeset, getAllWayIDs, getWay, serialiseEntityRoot));
 123             upload.appendChild(addDeleted(changeset, getAllNodeIDs, getNode, serialiseEntityRoot));
 124
 125                         trace(upload);
 126
 127             // now actually upload them
 128             // make an OAuth query
 129             var sig:IOAuthSignatureMethod = new OAuthSignatureMethod_HMAC_SHA1();
 130             var url:String = Connection.apiBaseURL+"changeset/" + changeset.id + "/upload";
 131             var oauthRequest:OAuthRequest = new OAuthRequest("POST", url, null, appID, authToken);
 132             var urlStr:Object = oauthRequest.buildRequest(sig, OAuthRequest.RESULT_TYPE_URL_STRING)
 133
 134             // build the actual request
 135             var urlReq:URLRequest = new URLRequest(String(urlStr));
 136             urlReq.method = "POST";
 137             urlReq.data = upload.toXMLString();
 138             urlReq.contentType = "text/xml";
 139             var loader:URLLoader = new URLLoader();
 140             loader.addEventListener(Event.COMPLETE, diffUploadComplete);
 141             loader.addEventListener(IOErrorEvent.IO_ERROR, diffUploadError);
 142             loader.addEventListener(HTTPStatusEvent.HTTP_STATUS, recordStatus);
 143                 loader.load(urlReq);
 144
 145                 dispatchEvent(new Event(SAVE_STARTED));
 146         }
 147
 148         private function diffUploadComplete(event:Event):void {
 149             // response should be XML describing the progress
 150             var results:XML = new XML((URLLoader(event.target).data));
 151
 152             for each( var update:XML in results.child("*") ) {
 153                 var oldID:Number = Number(update.@old_id);
 154                 var newID:Number = Number(update.@new_id);
 155                 var version:uint = uint(update.@new_version);
 156                 var type:String = update.name();
 157
 158                                 if (newID==0) {
 159                                         // delete
 160                         if ( type == "node" ) killNode(oldID);
 161                         else if ( type == "way" ) killWay(oldID);
 162                         else if ( type == "relation" ) killRelation(oldID);
 163
 164                                 } else {
 165                                         // create/update
 166                         var entity:Entity;
 167                         if ( type == "node" ) entity = getNode(oldID);
 168                         else if ( type == "way" ) entity = getWay(oldID);
 169                         else if ( type == "relation" ) entity = getRelation(oldID);
 170                         entity.markClean(newID, version);
 171
 172                         if ( oldID != newID ) {
 173                             if ( type == "node" ) renumberNode(oldID, entity as Node, false);
 174                             else if ( type == "way" ) renumberWay(oldID, entity as Way, false);
 175                             else if ( type == "relation" ) renumberRelation(oldID, entity as Relation, false);
 176                         }
 177                                 }
 178             }
 179
 180                 dispatchEvent(new SaveCompleteEvent(SAVE_COMPLETED, true));
 181                 dispatchEvent(new Event(DATA_CLEAN, true));
 182         }
 183
 184         private function diffUploadError(event:IOErrorEvent):void {
 185             trace("error "+URLLoader(event.target).data + " "+httpStatus+ " " + event.text);
 186
 187                 dispatchEvent(new SaveCompleteEvent(SAVE_COMPLETED, false));
 188         }
 189
 190         private function addCreated(changeset:Changeset, getIDs:Function, get:Function, serialise:Function):XML {
 191             var create:XML = <create version="0.6"/>
 192             for each( var id:Number in getIDs() ) {
 193                 var entity:Entity = get(id);
 194                 if ( id >= 0 || entity.deleted )
 195                     continue;
 196
 197                 var xml:XML = serialise(entity);
 198                 xml.@changeset = changeset.id;
 199                 create.appendChild(xml);
 200             }
 201             return create.hasComplexContent() ? create : <!-- blank create section -->;
 202         }
 203
 204                 private function addDeleted(changeset:Changeset, getIDs:Function, get:Function, serialise:Function):XML {
 205             var del:XML = <delete version="0.6"/>
 206             for each( var id:Number in getIDs() ) {
 207                 var entity:Entity = get(id);
 208                 // creates are already included
 209                 if ( id < 0 || !entity.deleted )
 210                     continue;
 211
 212                 var xml:XML = serialise(entity);
 213                 xml.@changeset = changeset.id;
 214                 del.appendChild(xml);
 215             }
 216             return del.hasComplexContent() ? del : <!-- blank delete section -->;
 217                 }
 218
 219         private function addModified(changeset:Changeset, getIDs:Function, get:Function, serialise:Function):XML {
 220             var modify:XML = <modify version="0.6"/>
 221             for each( var id:Number in getIDs() ) {
 222                 var entity:Entity = get(id);
 223                 // creates and deletes are already included
 224                 if ( id < 0 || entity.deleted || !entity.isDirty )
 225                     continue;
 226
 227                 var xml:XML = serialise(entity);
 228                 xml.@changeset = changeset.id;
 229                 modify.appendChild(xml);
 230             }
 231             return modify.hasComplexContent() ? modify : <!-- blank modify section -->;
 232         }
 233
 234         private function serialiseNode(node:Node):XML {
 235             var xml:XML = serialiseEntityRoot(node); //<node/>
 236             serialiseEntityTags(node, xml);
 237             xml.@lat = node.lat;
 238             xml.@lon = node.lon;
 239             return xml;
 240         }
 241
 242         private function serialiseWay(way:Way):XML {
 243             var xml:XML = serialiseEntityRoot(way); //<node/>
 244             serialiseEntityTags(way, xml);
 245             for ( var i:uint = 0; i < way.length; i++ ) {
 246                 var nd:XML = <nd/>
 247                 nd.@ref = way.getNode(i).id;
 248                 xml.appendChild(nd);
 249             }
 250             return xml;
 251         }
 252
 253         private function serialiseRelation(relation:Relation):XML {
 254             var xml:XML = serialiseEntityRoot(relation); //<node/>
 255             serialiseEntityTags(relation, xml);
 256             for ( var i:uint = 0; i < relation.length; i++ ) {
 257                 var relMember:RelationMember = relation.getMember(i);
 258                 var member:XML = <member/>
 259                 member.@ref = relMember.entity.id;
 260                 member.@type = relMember.entity.getType();
 261                 member.@role = relMember.role;
 262                 xml.appendChild(member);
 263             }
 264             return xml;
 265         }
 266
 267                 private function serialiseEntityRoot(entity:Object):XML {
 268                         var xml:XML;
 269                         if      (entity is Way     ) { xml = <way/> }
 270                         else if (entity is Node    ) { xml = <node/> }
 271                         else if (entity is Relation) { xml = <relation/> }
 272                         xml.@id = entity.id;
 273                         xml.@version = entity.version;
 274                         return xml;
 275                 }
 276
 277         private function serialiseEntityTags(entity:Entity, xml:XML):void {
 278             xml.@id = entity.id;
 279             xml.@version = entity.version;
 280             for each( var tag:Tag in entity.getTagArray() ) {
 281               var tagXML:XML = <tag/>
 282               tagXML.@k = tag.key;
 283               tagXML.@v = tag.value;
 284               xml.appendChild(tagXML);
 285             }
 286         }
 287
 288         }
 289 }