net/systemeD/potlatch2/controller/ControllerState.as

   1 package net.systemeD.potlatch2.controller {
   2         import flash.events.*;
   3         import flash.display.*;
   4     import net.systemeD.halcyon.Map;
   5     import net.systemeD.halcyon.MapPaint;
   6     import net.systemeD.halcyon.connection.*;
   7     import net.systemeD.potlatch2.collections.Imagery;
   8     import net.systemeD.potlatch2.EditController;
   9         import net.systemeD.potlatch2.save.SaveManager;
  10         import net.systemeD.potlatch2.utils.SnapshotConnection;
  11         import flash.ui.Keyboard;
  12         import mx.controls.Alert;
  13         import mx.events.CloseEvent;
  14
  15     /** Represents a particular state of the controller, such as "dragging a way" or "nothing selected". Key methods are
  16     * processKeyboardEvent and processMouseEvent which take some action, and return a new state for the controller.
  17     *
  18     * This abstract class has some behaviour that applies in most states, and lots of 'null' behaviour.
  19     * */
  20     public class ControllerState {
  21
  22         protected var controller:EditController;
  23                 protected var editableLayer:MapPaint;
  24         protected var previousState:ControllerState;
  25
  26                 protected var _selection:Array=[];
  27
  28         public function ControllerState() {}
  29
  30         public function setController(controller:EditController):void {
  31             this.controller = controller;
  32                         editableLayer = controller.map.editableLayer;
  33         }
  34
  35         public function setPreviousState(previousState:ControllerState):void {
  36             if ( this.previousState == null )
  37                 this.previousState = previousState;
  38         }
  39
  40                 public function isSelectionState():Boolean {
  41                         return true;
  42                 }
  43
  44         /** When triggered by a mouse action such as a click, perform an action on the given entity, then move to a new state. */
  45         public function processMouseEvent(event:MouseEvent, entity:Entity):ControllerState {
  46             return this;
  47         }
  48
  49                 /** When triggered by a keypress, perform an action on the given entity, then move to a new state. */
  50         public function processKeyboardEvent(event:KeyboardEvent):ControllerState {
  51             return this;
  52         }
  53
  54         /** Retrieves the map associated with the current EditController */
  55                 public function get map():Map {
  56                         return controller.map;
  57                 }
  58
  59         /** This is called when the EditController sets this ControllerState as the active state.
  60         * Override this with whatever is needed, such as adding highlights to entities
  61         */
  62         public function enterState():void {}
  63
  64         /** This is called by the EditController as the current controllerstate is exiting.
  65         * Override this with whatever cleanup is needed, such as removing highlights from entities
  66         */
  67         public function exitState(newState:ControllerState):void {}
  68
  69                 /** Represent the state in text for debugging. */
  70                 public function toString():String {
  71                         return "(No state)";
  72                 }
  73                 /** Default behaviour for the current state that should be called if state-specific action has been taken care of or ruled out. */
  74                 protected function sharedKeyboardEvents(event:KeyboardEvent):ControllerState {
  75                         switch (event.keyCode) {
  76                                 case 66:        setSourceTag(); break;                                                                                                  // B - set source tag for current object
  77                                 case 67:        editableLayer.connection.closeChangeset(); break;                                               // C - close changeset
  78                                 case 68:        editableLayer.alpha=1.3-editableLayer.alpha; return null;                               // D - dim
  79                                 case 83:        SaveManager.saveChanges(editableLayer.connection); break;                               // S - save
  80                                 case 84:        controller.tagViewer.togglePanel(); return null;                                                // T - toggle tags panel
  81                                 case 90:        if (!event.shiftKey) { MainUndoStack.getGlobalStack().undo(); return null;}// Z - undo
  82                                             else { MainUndoStack.getGlobalStack().redo(); return null;  }           // Shift-Z - redo
  83                                 case Keyboard.ESCAPE:   revertSelection(); break;                                                                       // ESC - revert to server version
  84                                 case Keyboard.NUMPAD_ADD:                                                                                                                       // + - add tag
  85                                 case 187:       controller.tagViewer.selectAdvancedPanel();                                                             //   |
  86                                                         controller.tagViewer.addNewTag(); return null;                                                  //   |
  87                         }
  88                         return null;
  89                 }
  90
  91                 /** Default behaviour for the current state that should be called if state-specific action has been taken care of or ruled out. */
  92                 protected function sharedMouseEvents(event:MouseEvent, entity:Entity):ControllerState {
  93                         var paint:MapPaint = getMapPaint(DisplayObject(event.target));
  94             var focus:Entity = getTopLevelFocusEntity(entity);
  95
  96                         if ( paint && paint.isBackground ) {
  97                                 if (event.type == MouseEvent.MOUSE_DOWN && ((event.shiftKey && event.ctrlKey) || event.altKey) ) {
  98                                         // alt-click to pull data out of vector background layer
  99                                         var newEntity:Entity=paint.pullThrough(entity,editableLayer);
 100                                         if      (entity is Way ) { return new SelectedWay(newEntity as Way); }
 101                                         else if (entity is Node) { return new SelectedPOINode(newEntity as Node); }
 102                 } else if (event.type == MouseEvent.MOUSE_DOWN) {
 103                     if      (entity is Way ) { return new SelectedBackgroundWay(entity as Way); }
 104                     else if (entity is Node) { return new SelectedBackgroundNode(entity as Node, paint); }
 105                 } else if (event.type == MouseEvent.MOUSE_DOWN && entity is Marker) {
 106                     return new SelectedMarker(entity as Marker, paint);
 107                                 } else if ( event.type == MouseEvent.MOUSE_UP ) {
 108                                         return (this is NoSelection) ? null : new NoSelection();
 109                                 } else { return null; }
 110                         }
 111
 112                         if ( event.type == MouseEvent.MOUSE_DOWN ) {
 113                                 if ( entity is Node && selectedWay && entity.hasParent(selectedWay) ) {
 114                                         // select node within this way
 115                         return new DragWayNode(selectedWay,  getNodeIndex(selectedWay,entity as Node),  event, false);
 116                                 } else if ( entity is Node && focus is Way ) {
 117                                         // select way node
 118                                         return new DragWayNode(focus as Way, getNodeIndex(focus as Way,entity as Node), event, false);
 119                                 } else if ( controller.keyDown(Keyboard.SPACE) ) {
 120                                         // drag the background imagery to compensate for poor alignment
 121                                         return new DragBackground(event);
 122                                 } else if (entity && selection.indexOf(entity)>-1) {
 123                                         return new DragSelection(selection, event);
 124                                 } else if (entity) {
 125                                         return new DragSelection([entity], event);
 126                                 } else if (event.ctrlKey) {
 127                                         return new SelectArea(event.localX,event.localY);
 128                                 }
 129             } else if ( event.type == MouseEvent.CLICK && focus == null && map.dragstate!=map.DRAGGING && this is SelectedMarker) {
 130                 // this is identical to the below, but needed for unselecting markers on vector background layers.
 131                 // Deselecting a POI or way on the main layer emits both CLICK and MOUSE_UP, but markers only CLICK
 132                 // I'll leave it to someone who understands to decide whether they are the same thing and should be
 133                 // combined with a (CLICK || MOUSE_UP)
 134
 135                 // "&& this is SelectedMarker" added by Steve Bennett. The CLICK event being processed for SelectedWay state
 136                 // causes way to get unselected...so restrict the double processing as much as possible.
 137
 138                 return (this is NoSelection) ? null : new NoSelection();
 139                         } else if ( event.type == MouseEvent.MOUSE_UP && focus == null && map.dragstate!=map.DRAGGING) {
 140                                 return (this is NoSelection) ? null : new NoSelection();
 141                         } else if ( event.type == MouseEvent.MOUSE_UP && focus && map.dragstate!=map.NOT_DRAGGING) {
 142                                 map.mouseUpHandler();   // in case the end-drag is over an EntityUI
 143                         } else if ( event.type == MouseEvent.ROLL_OVER ) {
 144                                 editableLayer.setHighlight(focus, { hover: true });
 145                         } else if ( event.type == MouseEvent.MOUSE_OUT ) {
 146                                 editableLayer.setHighlight(focus, { hover: false });
 147             } else if ( event.type == MouseEvent.MOUSE_WHEEL ) {
 148                 if (event.delta > 0) {
 149                   map.zoomIn();
 150                 } else if (event.delta < 0) {
 151                   map.zoomOut();
 152                 }
 153             }
 154                         return null;
 155                 }
 156
 157                 /** Gets the way that the selected node is part of, if that makes sense. If not, return the node, or the way, or nothing. */
 158                 public static function getTopLevelFocusEntity(entity:Entity):Entity {
 159                         if ( entity is Node ) {
 160                                 for each (var parent:Entity in entity.parentWays) {
 161                                         return parent;
 162                                 }
 163                                 return entity;
 164                         } else if ( entity is Way ) {
 165                                 return entity;
 166                         } else {
 167                                 return null;
 168                         }
 169                 }
 170
 171                 /** Find the MapPaint object that this DisplayObject belongs to. */
 172                 protected function getMapPaint(d:DisplayObject):MapPaint {
 173                         while (d) {
 174                                 if (d is MapPaint) { return MapPaint(d); }
 175                                 d=d.parent;
 176                         }
 177                         return null;
 178                 }
 179
 180                 protected function getNodeIndex(way:Way,node:Node):uint {
 181                         for (var i:uint=0; i<way.length; i++) {
 182                                 if (way.getNode(i)==node) { return i; }
 183                         }
 184                         return null;
 185                 }
 186
 187                 /** Create a "repeat tags" action on the current entity, if possible. */
 188                 protected function repeatTags(object:Entity):void {
 189                         if (!controller.clipboards[object.getType()]) { return; }
 190                         object.suspend();
 191
 192                     var undo:CompositeUndoableAction = new CompositeUndoableAction("Repeat tags");
 193                         for (var k:String in controller.clipboards[object.getType()]) {
 194                                 object.setTag(k, controller.clipboards[object.getType()][k], undo.push)
 195                         }
 196                         MainUndoStack.getGlobalStack().addAction(undo);
 197                         controller.updateSelectionUI();
 198                         object.resume();
 199
 200
 201                 }
 202
 203                 /** Create an action to add "source=*" tag to current entity based on background imagery. This is a convenient shorthand for users. */
 204                 protected function setSourceTag():void {
 205                         if (selectCount!=1) { return; }
 206                         if (Imagery.instance().selected && Imagery.instance().selected.sourcetag) {
 207                                 if ("sourcekey" in Imagery.instance().selected)
 208                                     firstSelected.setTag(Imagery.instance().selected.sourcekey,Imagery.instance().selected.sourcetag, MainUndoStack.getGlobalStack().addAction);
 209                                 else
 210                                     firstSelected.setTag('source',Imagery.instance().selected.sourcetag, MainUndoStack.getGlobalStack().addAction);
 211                         }
 212                         controller.updateSelectionUI();
 213                 }
 214
 215                 /** Revert all selected items to previously saved state, via a dialog box. */
 216                 protected function revertSelection():void {
 217                         if (selectCount==0) return;
 218                         Alert.show("Revert selected items to the last saved version, discarding your changes?","Are you sure?",Alert.YES | Alert.CANCEL,null,revertHandler);
 219                 }
 220                 protected function revertHandler(event:CloseEvent):void {
 221                         if (event.detail==Alert.CANCEL) return;
 222                         for each (var item:Entity in _selection) {
 223                                 item.connection.loadEntity(item);
 224                         }
 225                 }
 226
 227                 // Selection getters
 228
 229                 public function get selectCount():uint {
 230                         return _selection.length;
 231                 }
 232
 233                 public function get selection():Array {
 234                         return _selection;
 235                 }
 236
 237                 public function get firstSelected():Entity {
 238                         if (_selection.length==0) { return null; }
 239                         return _selection[0];
 240                 }
 241
 242                 public function get selectedWay():Way {
 243                         if (firstSelected is Way) { return firstSelected as Way; }
 244                         return null;
 245                 }
 246
 247                 public function get selectedWays():Array {
 248                         var selectedWays:Array=[];
 249                         for each (var item:Entity in _selection) {
 250                                 if (item is Way) { selectedWays.push(item); }
 251                         }
 252                         return selectedWays;
 253                 }
 254
 255         public function get selectedNodes():Array {
 256             var selectedNodes:Array=[];
 257             for each (var item:Entity in _selection) {
 258                 if (item is Node) { selectedNodes.push(item); }
 259             }
 260             return selectedNodes;
 261         }
 262
 263                 public function hasSelectedWays():Boolean {
 264                         for each (var item:Entity in _selection) {
 265                                 if (item is Way) { return true; }
 266                         }
 267                         return false;
 268                 }
 269
 270                 public function hasSelectedAreas():Boolean {
 271                         for each (var item:Entity in _selection) {
 272                                 if (item is Way && Way(item).isArea()) { return true; }
 273                         }
 274                         return false;
 275                 }
 276
 277                 public function hasSelectedUnclosedWays():Boolean {
 278                         for each (var item:Entity in _selection) {
 279                                 if (item is Way && !Way(item).isArea()) { return true; }
 280                         }
 281                         return false;
 282                 }
 283
 284         /** Determine whether or not any nodes are selected, and if so whether any of them belong to areas. */
 285         public function hasSelectedWayNodesInAreas():Boolean {
 286             for each (var item:Entity in _selection) {
 287                 if (item is Node) {
 288                     var parentWays:Array = Node(item).parentWays;
 289                     for each (var way:Entity in parentWays) {
 290                         if (Way(way).isArea()) { return true; }
 291                     }
 292                 }
 293             }
 294             return false;
 295         }
 296
 297                 public function hasAdjoiningWays():Boolean {
 298                         if (_selection.length<2) { return false; }
 299                         var endNodes:Object={};
 300                         for each (var item:Entity in _selection) {
 301                                 if (item is Way && !Way(item).isArea()) {
 302                                         if (endNodes[Way(item).getNode(0).id]) return true;
 303                                         if (endNodes[Way(item).getLastNode().id]) return true;
 304                                         endNodes[Way(item).getNode(0).id]=true;
 305                                         endNodes[Way(item).getLastNode().id]=true;
 306                                 }
 307                         }
 308                         return false;
 309                 }
 310
 311                 // Selection setters
 312
 313                 public function set selection(items:Array):void {
 314                         _selection=items;
 315                 }
 316
 317                 public function addToSelection(items:Array):void {
 318                         for each (var item:Entity in items) {
 319                                 if (_selection.indexOf(item)==-1) { _selection.push(item); }
 320                         }
 321                 }
 322
 323                 public function removeFromSelection(items:Array):void {
 324                         for each (var item:Entity in items) {
 325                                 if (_selection.indexOf(item)>-1) {
 326                                         _selection.splice(_selection.indexOf(item),1);
 327                                 }
 328                         }
 329                 }
 330
 331                 public function toggleSelection(item:Entity):Boolean {
 332                         if (_selection.indexOf(item)==-1) {
 333                                 _selection.push(item); return true;
 334                         }
 335                         _selection.splice(_selection.indexOf(item),1); return false;
 336                 }
 337     }
 338 }