Merge branch 'master' into snapshotserver
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.display.Loader;
4         import flash.display.Sprite;
5         import flash.events.*;
6         import flash.external.ExternalInterface;
7         import flash.geom.Rectangle;
8         import flash.net.*;
9         import flash.text.Font;
10         import flash.text.TextField;
11         import flash.ui.Keyboard;
12         
13         import net.systemeD.halcyon.connection.*;
14         import net.systemeD.halcyon.styleparser.*;
15
16 //      for experimental export function:
17 //      import flash.net.FileReference;
18 //      import com.adobe.images.JPGEncoder;
19
20     /** The representation of part of the map on the screen, including information about coordinates, background imagery, paint properties etc. */
21     public class Map extends Sprite {
22
23                 /** master map scale - how many Flash pixels in 1 degree longitude (for Landsat, 5120) */
24                 public const MASTERSCALE:Number=5825.4222222222; 
25                                                                                                 
26                 /** don't zoom out past this */
27                 public const MINSCALE:uint=13; 
28                 /** don't zoom in past this */
29                 public const MAXSCALE:uint=23; 
30
31                 // Container for MapPaint objects
32                 private var paintContainer:Sprite;
33
34                 /** map scale */
35                 public var scale:uint=14;                                                
36                 /** current scaling factor for lon/latp */
37                 public var scalefactor:Number=MASTERSCALE;
38
39                 public var edge_l:Number;                                               // current bounding box
40                 public var edge_r:Number;                                               //  |
41                 public var edge_t:Number;                                               //  |
42                 public var edge_b:Number;                                               //  |
43                 public var centre_lat:Number;                                   // centre lat/lon
44                 public var centre_lon:Number;                                   //  |
45
46                 /** urllon-xradius/masterscale; */ 
47                 public var baselon:Number;
48                 /** lat2lat2p(urllat)+yradius/masterscale; */
49                 public var basey:Number; 
50                 /** width (Flash pixels) */
51                 public var mapwidth:uint; 
52                 /** height (Flash pixels) */
53                 public var mapheight:uint; 
54
55                 /** Is the map being panned */
56                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map (panning)
57                 /** Can the map be panned */
58                 private var _draggable:Boolean=true;                    //  |
59                 private var lastxmouse:Number;                                  //  |
60                 private var lastymouse:Number;                                  //  |
61                 private var downX:Number;                                               //  |
62                 private var downY:Number;                                               //  |
63                 private var downTime:Number;                                    //  |
64                 public const NOT_DRAGGING:uint=0;                               //  |
65                 public const NOT_MOVED:uint=1;                                  //  |
66                 public const DRAGGING:uint=2;                                   //  |
67                 /** How far the map can be dragged without actually triggering a pan. */
68                 public const TOLERANCE:uint=7;                                  //  |
69                 
70                 /** object containing HTML page parameters: lat, lon, zoom, background_dim, background_sharpen, tileblocks */
71                 public var initparams:Object; 
72
73                 /** reference to backdrop sprite */
74                 public var backdrop:Object; 
75                 /** background tile object */
76                 public var tileset:TileSet; 
77                 /** show all objects, even if unstyled? */
78                 public var showall:Boolean=true; 
79                 
80                 // ------------------------------------------------------------------------------------------
81                 /** Map constructor function */
82         public function Map() {
83                         // Remove any existing sprites
84                         while (numChildren) { removeChildAt(0); }
85
86                         // 900913 background
87                         tileset=new TileSet(this);
88                         addChild(tileset);
89
90                         // Container for all MapPaint objects
91                         paintContainer = new Sprite();
92                         addChild(paintContainer);
93
94                         addEventListener(Event.ENTER_FRAME, everyFrame);
95                         scrollRect=new Rectangle(0,0,800,600);
96
97                         if (ExternalInterface.available) {
98                                 ExternalInterface.addCallback("setPosition", function (lat:Number,lon:Number,zoom:uint):void {
99                                         updateCoordsFromLatLon(lat, lon);
100                                         changeScale(zoom);
101                                 });
102                         }
103                 }
104
105                 // ------------------------------------------------------------------------------------------
106                 /** Initialise map at a given lat/lon */
107         public function init(startlat:Number, startlon:Number, startscale:uint=0):void {
108                         if (startscale>0) {
109                                 scale=startscale;
110                                 this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
111                         }
112                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
113                         baselon    =startlon          -(mapwidth /2)/scalefactor;
114                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
115                         updateCoords(0,0);
116             this.dispatchEvent(new Event(MapEvent.INITIALISED));
117                         download();
118         }
119
120                 // ------------------------------------------------------------------------------------------
121                 /** Recalculate co-ordinates from new Flash origin */
122
123                 public function updateCoords(tx:Number,ty:Number):void {
124                         setScrollRectXY(tx,ty);
125
126                         edge_t=coord2lat(-ty          );
127                         edge_b=coord2lat(-ty+mapheight);
128                         edge_l=coord2lon(-tx          );
129                         edge_r=coord2lon(-tx+mapwidth );
130                         setCentre();
131
132                         tileset.update();
133                 }
134                 
135                 /** Move the map to centre on a given latitude/longitude. */
136                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
137                         var cy:Number=-(lat2coord(lat)-mapheight/2);
138                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
139                         updateCoords(cx,cy);
140                 }
141                 
142                 private function setScrollRectXY(tx:Number,ty:Number):void {
143                         var w:Number=scrollRect.width;
144                         var h:Number=scrollRect.height;
145                         scrollRect=new Rectangle(-tx,-ty,w,h);
146                 }
147                 private function setScrollRectSize(width:Number,height:Number):void {
148                         var sx:Number=scrollRect.x ? scrollRect.x : 0;
149                         var sy:Number=scrollRect.y ? scrollRect.y : 0;
150                         scrollRect=new Rectangle(sx,sy,width,height);
151                 }
152                 
153                 private function getX():Number { return -scrollRect.x; }
154                 private function getY():Number { return -scrollRect.y; }
155                 
156                 private function setCentre():void {
157                         centre_lat=coord2lat(-getY()+mapheight/2);
158                         centre_lon=coord2lon(-getX()+mapwidth/2);
159                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale, minlon:edge_l, maxlon:edge_r, minlat:edge_b, maxlat:edge_t}));
160                 }
161                 
162                 /** Sets the offset between the background imagery and the map. */
163                 public function nudgeBackground(x:Number,y:Number):void {
164                         this.dispatchEvent(new MapEvent(MapEvent.NUDGE_BACKGROUND, { x: x, y: y }));
165                 }
166
167                 private function moveMap(dx:Number,dy:Number):void {
168                         updateCoords(getX()+dx,getY()+dy);
169                         updateAllEntityUIs(false, false);
170                         download();
171                 }
172                 
173                 /** Recentre map at given lat/lon, updating the UI and downloading entities. */
174                 public function moveMapFromLatLon(lat:Number,lon:Number):void {
175                         updateCoordsFromLatLon(lat,lon);
176                         updateAllEntityUIs(false,false);
177                         download();
178                 }
179                 
180                 /** Recentre map at given lat/lon, if that point is currently outside the visible area. */
181                 public function scrollIfNeeded(lat:Number,lon:Number): void{
182             if (lat> edge_t || lat < edge_b || lon < edge_l || lon > edge_r) {
183                 moveMapFromLatLon(lat, lon);
184             }
185                 }
186
187                 // Co-ordinate conversion functions
188
189                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
190                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
191                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
192                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
193
194                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
195                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
196
197                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
198                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
199
200
201                 // ------------------------------------------------------------------------------------------
202                 /** Resize map size based on current stage and height */
203
204                 public function updateSize(w:uint, h:uint):void {
205                         mapwidth = w; centre_lon=coord2lon(-getX()+w/2);
206                         mapheight= h; centre_lat=coord2lat(-getY()+h/2);
207                         setScrollRectSize(w,h);
208
209                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
210                         
211             if ( backdrop != null ) {
212                 backdrop.width=mapwidth;
213                 backdrop.height=mapheight;
214             }
215             if ( mask != null ) {
216                 mask.width=mapwidth;
217                 mask.height=mapheight;
218             }
219                 }
220
221         /** Download map data. Data is downloaded for the currently visible layers
222         * The bounding box for the download is taken from the current map edges.
223         */
224                 public function download():void {
225                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
226                         for (var i:uint=0; i<paintContainer.numChildren; i++)
227                                 if(getLayerAt(i).visible == true) {
228                     getLayerAt(i).connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
229                 }
230                 }
231
232         // Handle mouse events on ways/nodes
233         private var mapController:MapController = null;
234
235         /** Assign map controller. */
236         public function setController(controller:MapController):void {
237             this.mapController = controller;
238         }
239
240         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
241             if ( mapController != null )
242                 mapController.entityMouseEvent(event, entity);
243         }
244
245                 // ------------------------------------------------------------------------------------------
246                 // Add layers
247                 
248                 public function addLayer(connection:Connection, styleurl:String, backgroundlayer:Boolean=true, interactive:Boolean=false):MapPaint {
249                         var paint:MapPaint=new MapPaint(this, connection, styleurl, -5, 5);
250                         paintContainer.addChildAt(paint,0);
251                         paint.isBackground=backgroundlayer;
252                         paint.interactive=interactive;
253                         return paint;
254                 }
255
256                 public function removeLayerByName(name:String):void {
257                         for (var i:uint=0; i<paintContainer.numChildren; i++) {
258                                 if (getLayerAt(i).connection.name==name)
259                                         paintContainer.removeChildAt(i);
260                                         // >>>> REFACTOR: needs to do the equivalent of VectorLayer.blank()
261                         }
262                 }
263                 
264                 public function findLayer(name:String):MapPaint {
265                         for (var i:uint=0; i<paintContainer.numChildren; i++)
266                                 if (getLayerAt(i).connection.name==name) return getLayerAt(i);
267                         return null;
268                 }
269
270                 private function getLayerAt(i:uint):MapPaint {
271                         return MapPaint(paintContainer.getChildAt(i));
272                 }
273
274         /** Get all the layers available for this Map object
275         *   @return An array of MapPaint objects */
276         public function getLayers():Array {
277             var a:Array = [];
278             for (var i:uint=0; i<paintContainer.numChildren; i++) {
279                 a.push(getLayerAt(i));
280             }
281             return a;
282         }
283                 
284                 /* Find which layer is editable */
285                 public function get editableLayer():MapPaint {
286                         var editableLayer:MapPaint;
287                         for (var i:uint=0; i<paintContainer.numChildren; i++) {
288                                 if (!getLayerAt(i).isBackground) {
289                                         if (editableLayer) trace("Multiple editable layers found");
290                                         editableLayer=getLayerAt(i);
291                                 }
292                         }
293                         return editableLayer;
294                 }
295
296                 /** Find which paint object an entity will be displayed on. */
297                 public function getLayerForEntity(entity:Entity):MapPaint {
298                         for (var i:uint=0; i<paintContainer.numChildren; i++) {
299                                 if (getLayerAt(i).sameConnection(entity)) return getLayerAt(i);
300                         }
301                         return null;
302                 }
303
304                 // ------------------------------------------------------------------------------------------
305                 // Redraw all items, zoom in and out
306                 
307                 private function updateAllEntityUIs(redraw:Boolean,remove:Boolean):void {
308                         for (var i:uint=0; i<paintContainer.numChildren; i++)
309                                 getLayerAt(i).updateEntityUIs(redraw, remove);
310                 }
311                 public function redraw():void {
312                         for (var i:uint=0; i<paintContainer.numChildren; i++)
313                                 getLayerAt(i).redraw();
314                 }
315                 public function redrawPOIs():void { 
316                         for (var i:uint=0; i<paintContainer.numChildren; i++)
317                                 getLayerAt(i).redrawPOIs();
318                 }
319                 
320                 public function zoomIn():void {
321                         if (scale!=MAXSCALE) changeScale(scale+1);
322                 }
323
324                 public function zoomOut():void {
325                         if (scale!=MINSCALE) changeScale(scale-1);
326                 }
327
328                 private function changeScale(newscale:uint):void {
329                         scale=newscale;
330                         this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
331                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
332                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
333                         tileset.changeScale(scale);
334                         updateAllEntityUIs(true,true);
335                         download();
336                 }
337
338                 /** Set background dimming on/off. */
339                 public function setDimming(dim:Boolean):void {
340                         if (tileset) { tileset.setDimming(dim); }
341                 }
342                 
343                 /** Return background dimming. */
344                 public function getDimming():Boolean {
345                         if (tileset) { return tileset.getDimming(); }
346                         return true;
347                 }
348
349                 /** Set background sharpening on/off. */
350                 public function setSharpen(sharpen:Boolean):void {
351                         if (tileset) { tileset.setSharpen(sharpen); }
352                 }
353                 /** Return background sharpening. */
354                 public function getSharpen():Boolean {
355                         if (tileset) { return tileset.getSharpen(); }
356                         return false;
357                 }
358
359                 // ------------------------------------------------------------------------------------------
360                 // Export (experimental)
361                 // ** just a bit of fun for now!
362                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
363                 // to that area (will probably require creating a new DisplayObject with a different origin
364                 // and mask)
365 /*              
366                 public function export():void {
367                         trace("size is "+this.width+","+this.height);
368                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
369                         jpgSource.draw(this);
370                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
371                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
372                         var fileRef:FileReference = new FileReference();
373 //                      fileRef.save(jpgStream,'map.jpeg');
374                 }
375
376 */
377
378                 // ==========================================================================================
379                 // Events
380                 
381                 // ------------------------------------------------------------------------------------------
382                 // Mouse events
383                 
384                 /** Should map be allowed to pan? */
385                 public function set draggable(draggable:Boolean):void {
386                         _draggable=draggable;
387                         dragstate=NOT_DRAGGING;
388                 }
389
390                 /** Prepare for being dragged by recording start time and location of mouse. */
391                 public function mouseDownHandler(event:MouseEvent):void {
392                         if (!_draggable) { return; }
393                         dragstate=NOT_MOVED;
394                         lastxmouse=stage.mouseX; downX=stage.mouseX;
395                         lastymouse=stage.mouseY; downY=stage.mouseY;
396                         downTime=new Date().getTime();
397                 }
398         
399                 /** Respond to mouse up by possibly moving map. */
400                 public function mouseUpHandler(event:MouseEvent=null):void {
401                         if (dragstate==DRAGGING) { moveMap(x,y); }
402                         dragstate=NOT_DRAGGING;
403                 }
404         
405                 /** Respond to mouse movement, dragging the map if tolerance threshold met. */
406                 public function mouseMoveHandler(event:MouseEvent):void {
407                         if (!_draggable) { return; }
408                         if (dragstate==NOT_DRAGGING) { 
409                            this.dispatchEvent(new MapEvent(MapEvent.MOUSE_MOVE, { x: coord2lon(mouseX), y: coord2lat(mouseY) }));
410                return; 
411             }
412                         
413                         if (dragstate==NOT_MOVED) {
414                                 if (new Date().getTime()-downTime<300) {
415                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE   && Math.abs(downY-stage.mouseY)<=TOLERANCE  ) return;
416                                 } else {
417                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE/2 && Math.abs(downY-stage.mouseY)<=TOLERANCE/2) return;
418                                 }
419                                 dragstate=DRAGGING;
420                         }
421                         
422                         setScrollRectXY(getX()+stage.mouseX-lastxmouse,getY()+stage.mouseY-lastymouse);
423                         lastxmouse=stage.mouseX; lastymouse=stage.mouseY;
424                         setCentre();
425                 }
426         
427                 // ------------------------------------------------------------------------------------------
428                 // Do every frame
429
430                 private function everyFrame(event:Event):void {
431                         if (tileset) { tileset.serviceQueue(); }
432                 }
433
434                 // ------------------------------------------------------------------------------------------
435                 // Miscellaneous events
436                 
437                 /** Respond to cursor movements and zoom in/out.*/
438                 public function keyUpHandler(event:KeyboardEvent):void {
439                         if (event.target is TextField) return;                          // not meant for us
440                         switch (event.keyCode) {
441                                 case Keyboard.PAGE_UP:  zoomIn(); break;                 // Page Up - zoom in
442                                 case Keyboard.PAGE_DOWN:        zoomOut(); break;            // Page Down - zoom out
443                                 case Keyboard.LEFT:     moveMap(mapwidth/2,0); break;        // left cursor
444                                 case Keyboard.UP:       moveMap(0,mapheight/2); break;           // up cursor
445                                 case Keyboard.RIGHT:    moveMap(-mapwidth/2,0); break;   // right cursor
446                                 case Keyboard.DOWN:     moveMap(0,-mapheight/2); break;      // down cursor
447                         }
448                 }
449
450                 // ------------------------------------------------------------------------------------------
451                 // Debugging
452                 
453                 public function clearDebug():void {
454                         if (!Globals.vars.hasOwnProperty('debug')) return;
455                         Globals.vars.debug.text='';
456                 }
457                         
458                 public function addDebug(text:String):void {
459                         trace(text);
460                         if (!Globals.vars.hasOwnProperty('debug')) return;
461                         if (!Globals.vars.debug.visible) return;
462                         Globals.vars.debug.appendText(text+"\n");
463                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
464                 }
465
466         }
467 }