Refactoring in progress
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.display.Loader;
4         import flash.display.Sprite;
5         import flash.events.*;
6         import flash.external.ExternalInterface;
7         import flash.geom.Rectangle;
8         import flash.net.*;
9         import flash.text.Font;
10         import flash.text.TextField;
11         import flash.ui.Keyboard;
12         
13         import net.systemeD.halcyon.connection.*;
14         import net.systemeD.halcyon.styleparser.*;
15
16 //      for experimental export function:
17 //      import flash.net.FileReference;
18 //      import com.adobe.images.JPGEncoder;
19
20     /** The representation of part of the map on the screen, including information about coordinates, background imagery, paint properties etc. */
21     public class Map extends Sprite {
22
23                 /** master map scale - how many Flash pixels in 1 degree longitude (for Landsat, 5120) */
24                 public const MASTERSCALE:Number=5825.4222222222; 
25                                                                                                 
26                 /** don't zoom out past this */
27                 public const MINSCALE:uint=13; 
28                 /** don't zoom in past this */
29                 public const MAXSCALE:uint=23; 
30
31                 // Container for MapPaint objects
32                 public var paintContainer:Sprite;
33
34                 /** map scale */
35                 public var scale:uint=14;                                                
36                 /** current scaling factor for lon/latp */
37                 public var scalefactor:Number=MASTERSCALE;
38
39                 public var edge_l:Number;                                               // current bounding box
40                 public var edge_r:Number;                                               //  |
41                 public var edge_t:Number;                                               //  |
42                 public var edge_b:Number;                                               //  |
43                 public var centre_lat:Number;                                   // centre lat/lon
44                 public var centre_lon:Number;                                   //  |
45
46                 /** urllon-xradius/masterscale; */ 
47                 public var baselon:Number;
48                 /** lat2lat2p(urllat)+yradius/masterscale; */
49                 public var basey:Number; 
50                 /** width (Flash pixels) */
51                 public var mapwidth:uint; 
52                 /** height (Flash pixels) */
53                 public var mapheight:uint; 
54
55                 /** Is the map being panned */
56                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map (panning)
57                 /** Can the map be panned */
58                 private var _draggable:Boolean=true;                    //  |
59                 private var lastxmouse:Number;                                  //  |
60                 private var lastymouse:Number;                                  //  |
61                 private var downX:Number;                                               //  |
62                 private var downY:Number;                                               //  |
63                 private var downTime:Number;                                    //  |
64                 public const NOT_DRAGGING:uint=0;                               //  |
65                 public const NOT_MOVED:uint=1;                                  //  |
66                 public const DRAGGING:uint=2;                                   //  |
67                 /** How far the map can be dragged without actually triggering a pan. */
68                 public const TOLERANCE:uint=7;                                  //  |
69                 
70                 /** object containing HTML page parameters: lat, lon, zoom, background_dim, background_sharpen, tileblocks */
71                 public var initparams:Object; 
72
73                 /** reference to backdrop sprite */
74                 public var backdrop:Object; 
75                 /** background tile object */
76                 public var tileset:TileSet; 
77                 /** background tile URL, name and scheme */
78                 private var tileparams:Object={ url:'' }; 
79                 /** internal style URL */
80                 private var styleurl:String=''; 
81                 /** show all objects, even if unstyled? */
82                 public var showall:Boolean=true; 
83                 
84                 // ------------------------------------------------------------------------------------------
85                 /** Map constructor function */
86         public function Map() {
87                         // Remove any existing sprites
88                         while (numChildren) { removeChildAt(0); }
89
90                         // 900913 background
91                         tileset=new TileSet(this);
92                         addChild(tileset);
93
94                         // Container for all MapPaint objects
95                         paintContainer = new Sprite();
96                         addChild(paintContainer);
97
98                         addEventListener(Event.ENTER_FRAME, everyFrame);
99                         scrollRect=new Rectangle(0,0,800,600);
100
101                         if (ExternalInterface.available) {
102                                 ExternalInterface.addCallback("setPosition", function (lat:Number,lon:Number,zoom:uint):void {
103                                         updateCoordsFromLatLon(lat, lon);
104                                         changeScale(zoom);
105                                 });
106                         }
107                 }
108
109                 // ------------------------------------------------------------------------------------------
110                 /** Initialise map at a given lat/lon */
111         public function init(startlat:Number, startlon:Number, startscale:uint=0):void {
112                         if (startscale>0) {
113                                 scale=startscale;
114                                 this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
115                         }
116                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
117                         baselon    =startlon          -(mapwidth /2)/scalefactor;
118                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
119                         updateCoords(0,0);
120             this.dispatchEvent(new Event(MapEvent.INITIALISED));
121                         download();
122         }
123
124                 // ------------------------------------------------------------------------------------------
125                 /** Recalculate co-ordinates from new Flash origin */
126
127                 public function updateCoords(tx:Number,ty:Number):void {
128                         setScrollRectXY(tx,ty);
129
130                         edge_t=coord2lat(-ty          );
131                         edge_b=coord2lat(-ty+mapheight);
132                         edge_l=coord2lon(-tx          );
133                         edge_r=coord2lon(-tx+mapwidth );
134                         setCentre();
135
136                         tileset.update();
137                 }
138                 
139                 /** Move the map to centre on a given latitude/longitude. */
140                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
141                         var cy:Number=-(lat2coord(lat)-mapheight/2);
142                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
143                         updateCoords(cx,cy);
144                 }
145                 
146                 private function setScrollRectXY(tx:Number,ty:Number):void {
147                         var w:Number=scrollRect.width;
148                         var h:Number=scrollRect.height;
149                         scrollRect=new Rectangle(-tx,-ty,w,h);
150                 }
151                 private function setScrollRectSize(width:Number,height:Number):void {
152                         var sx:Number=scrollRect.x ? scrollRect.x : 0;
153                         var sy:Number=scrollRect.y ? scrollRect.y : 0;
154                         scrollRect=new Rectangle(sx,sy,width,height);
155                 }
156                 
157                 private function getX():Number { return -scrollRect.x; }
158                 private function getY():Number { return -scrollRect.y; }
159                 
160                 private function setCentre():void {
161                         centre_lat=coord2lat(-getY()+mapheight/2);
162                         centre_lon=coord2lon(-getX()+mapwidth/2);
163                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale, minlon:edge_l, maxlon:edge_r, minlat:edge_b, maxlat:edge_t}));
164                 }
165                 
166                 /** Sets the offset between the background imagery and the map. */
167                 public function nudgeBackground(x:Number,y:Number):void {
168                         this.dispatchEvent(new MapEvent(MapEvent.NUDGE_BACKGROUND, { x: x, y: y }));
169                 }
170
171                 private function moveMap(dx:Number,dy:Number):void {
172                         updateCoords(getX()+dx,getY()+dy);
173                         updateAllEntityUIs(false, false);
174                         download();
175                 }
176                 
177                 /** Recentre map at given lat/lon, updating the UI and downloading entities. */
178                 public function moveMapFromLatLon(lat:Number,lon:Number):void {
179                         updateCoordsFromLatLon(lat,lon);
180                         updateAllEntityUIs(false,false);
181                         download();
182                 }
183                 
184                 /** Recentre map at given lat/lon, if that point is currently outside the visible area. */
185                 public function scrollIfNeeded(lat:Number,lon:Number): void{
186             if (lat> edge_t || lat < edge_b || lon < edge_l || lon > edge_r) {
187                 moveMapFromLatLon(lat, lon);
188             }
189
190                 }
191
192                 // Co-ordinate conversion functions
193
194                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
195                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
196                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
197                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
198
199                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
200                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
201
202                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
203                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
204
205
206                 // ------------------------------------------------------------------------------------------
207                 /** Resize map size based on current stage and height */
208
209                 public function updateSize(w:uint, h:uint):void {
210                         mapwidth = w; centre_lon=coord2lon(-getX()+w/2);
211                         mapheight= h; centre_lat=coord2lat(-getY()+h/2);
212                         setScrollRectSize(w,h);
213
214                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
215                         
216             if ( backdrop != null ) {
217                 backdrop.width=mapwidth;
218                 backdrop.height=mapheight;
219             }
220             if ( mask != null ) {
221                 mask.width=mapwidth;
222                 mask.height=mapheight;
223             }
224                 }
225
226         /** Download map data. Data is downloaded for the connection and the vector layers, where supported.
227         * The bounding box for the download is taken from the current map edges.
228         */
229                 public function download():void {
230                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
231                         for (var i:uint=0; i<paintContainer.numChildren; i++) {
232                                 paintContainer.getChildAt(i).connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
233                         }
234                 }
235
236                 // >>>> REFACTOR: moved to MapPaint:
237         // public function setHighlight(entity:Entity, settings:Object):void {
238         // public function setHighlightOnNodes(way:Way, settings:Object):void {
239                 // public function protectWay(way:Way):void {
240                 // public function unprotectWay(way:Way):void {
241                 // public function limitWayDrawing(way:Way,except:Number=NaN,only:Number=NaN):void {
242                 // public function setPurgable(entities:Array, purgable:Boolean):void {
243
244
245         // Handle mouse events on ways/nodes
246         private var mapController:MapController = null;
247
248         /** Assign map controller. */
249         public function setController(controller:MapController):void {
250             this.mapController = controller;
251         }
252
253         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
254             if ( mapController != null )
255                 mapController.entityMouseEvent(event, entity);
256         }
257
258                 // ------------------------------------------------------------------------------------------
259                 // Add layers
260                 
261                 public function addLayer(connection:Connection, styleurl:String, backgroundlayer:Boolean=true):void {
262                         var paint:MapPaint=new MapPaint(this,connection,-5,5);
263                         paintContainer.addChild(paint);
264                         paint.isBackground=backgroundlayer;
265                         if (styleurl) {
266                                 // if we've only just set up paint, then setStyle won't have created the RuleSet
267                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
268                                 paint.ruleset.loadFromCSS(styleurl);
269                         }
270                 }
271
272                 public function removeLayerByName(name:String):void {
273                         for (var i:uint=0; i<paintContainer.numChildren; i++)
274                                 if (paintContainer.getChildAt(i).connection.name==name) {
275                                         paintContainer.removeChildAt(i);
276                                         // >>>> REFACTOR: needs to do the equivalent of VectorLayer.blank()
277                                 }
278                         }
279                 }
280                 
281                 public function findLayer(name:String):MapPaint {
282                         for (var i:uint=0; i<paintContainer.numChildren; i++)
283                                 if (paintContainer.getChildAt(i).connection.name==name) return paintContainer.getChildAt(i);
284                         return null;
285                 }
286
287                 // ------------------------------------------------------------------------------------------
288                 // Redraw all items, zoom in and out
289                 
290                 private function updateAllEntityUIs(redraw:Boolean,remove:Boolean):void {
291                         for (var i:uint=0; i<paintContainer.numChildren; i++)
292                                 paintContainer.getChildAt(i).updateEntityUIs(redraw, remove);
293                 }
294                 public function redraw():void {
295                         for (var i:uint=0; i<paintContainer.numChildren; i++)
296                                 paintContainer.getChildAt(i).redraw();
297                 }
298                 public function redrawPOIs():void { 
299                         for (var i:uint=0; i<paintContainer.numChildren; i++)
300                                 paintContainer.getChildAt(i).redrawPOIs();
301                 }
302                 
303                 public function zoomIn():void {
304                         if (scale!=MAXSCALE) changeScale(scale+1);
305                 }
306
307                 public function zoomOut():void {
308                         if (scale!=MINSCALE) changeScale(scale-1);
309                 }
310
311                 private function changeScale(newscale:uint):void {
312                         scale=newscale;
313                         this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
314                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
315                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
316                         tileset.changeScale(scale);
317                         updateAllEntityUIs(true,true);
318                         download();
319                 }
320
321                 /** Switch to new MapCSS. */
322                 public function setStyle(url:String):void {
323                         styleurl=url;
324                         if (paint) { 
325                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
326                                 paint.ruleset.loadFromCSS(url);
327                         }
328         }
329
330                 /** Select a new background imagery. */
331                 public function setBackground(bg:Object):void {
332                         tileparams=bg;
333                         if (tileset) { tileset.init(bg, bg.url!=''); }
334                 }
335
336                 /** Set background dimming on/off. */
337                 public function setDimming(dim:Boolean):void {
338                         if (tileset) { tileset.setDimming(dim); }
339                 }
340                 
341                 /** Return background dimming. */
342                 public function getDimming():Boolean {
343                         if (tileset) { return tileset.getDimming(); }
344                         return true;
345                 }
346
347                 /** Set background sharpening on/off. */
348                 public function setSharpen(sharpen:Boolean):void {
349                         if (tileset) { tileset.setSharpen(sharpen); }
350                 }
351                 /** Return background sharpening. */
352                 public function getSharpen():Boolean {
353                         if (tileset) { return tileset.getSharpen(); }
354                         return false;
355                 }
356
357                 // ------------------------------------------------------------------------------------------
358                 // Export (experimental)
359                 // ** just a bit of fun for now!
360                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
361                 // to that area (will probably require creating a new DisplayObject with a different origin
362                 // and mask)
363 /*              
364                 public function export():void {
365                         trace("size is "+this.width+","+this.height);
366                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
367                         jpgSource.draw(this);
368                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
369                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
370                         var fileRef:FileReference = new FileReference();
371 //                      fileRef.save(jpgStream,'map.jpeg');
372                 }
373
374 */
375
376                 // ==========================================================================================
377                 // Events
378                 
379                 // ------------------------------------------------------------------------------------------
380                 // Mouse events
381                 
382                 /** Should map be allowed to pan? */
383                 public function set draggable(draggable:Boolean):void {
384                         _draggable=draggable;
385                         dragstate=NOT_DRAGGING;
386                 }
387
388                 /** Prepare for being dragged by recording start time and location of mouse. */
389                 public function mouseDownHandler(event:MouseEvent):void {
390                         if (!_draggable) { return; }
391                         dragstate=NOT_MOVED;
392                         lastxmouse=stage.mouseX; downX=stage.mouseX;
393                         lastymouse=stage.mouseY; downY=stage.mouseY;
394                         downTime=new Date().getTime();
395                 }
396         
397                 /** Respond to mouse up by possibly moving map. */
398                 public function mouseUpHandler(event:MouseEvent=null):void {
399                         if (dragstate==DRAGGING) { moveMap(x,y); }
400                         dragstate=NOT_DRAGGING;
401                 }
402         
403                 /** Respond to mouse movement, dragging the map if tolerance threshold met. */
404                 public function mouseMoveHandler(event:MouseEvent):void {
405                         if (!_draggable) { return; }
406                         if (dragstate==NOT_DRAGGING) { 
407                            this.dispatchEvent(new MapEvent(MapEvent.MOUSE_MOVE, { x: coord2lon(mouseX), y: coord2lat(mouseY) }));
408                return; 
409             }
410                         
411                         if (dragstate==NOT_MOVED) {
412                                 if (new Date().getTime()-downTime<300) {
413                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE   && Math.abs(downY-stage.mouseY)<=TOLERANCE  ) return;
414                                 } else {
415                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE/2 && Math.abs(downY-stage.mouseY)<=TOLERANCE/2) return;
416                                 }
417                                 dragstate=DRAGGING;
418                         }
419                         
420                         setScrollRectXY(getX()+stage.mouseX-lastxmouse,getY()+stage.mouseY-lastymouse);
421                         lastxmouse=stage.mouseX; lastymouse=stage.mouseY;
422                         setCentre();
423                 }
424         
425                 // ------------------------------------------------------------------------------------------
426                 // Do every frame
427
428                 private function everyFrame(event:Event):void {
429                         if (tileset) { tileset.serviceQueue(); }
430                 }
431
432                 // ------------------------------------------------------------------------------------------
433                 // Miscellaneous events
434                 
435                 /** Respond to cursor movements and zoom in/out.*/
436                 public function keyUpHandler(event:KeyboardEvent):void {
437                         if (event.target is TextField) return;                          // not meant for us
438                         switch (event.keyCode) {
439                                 case Keyboard.PAGE_UP:  zoomIn(); break;                 // Page Up - zoom in
440                                 case Keyboard.PAGE_DOWN:        zoomOut(); break;            // Page Down - zoom out
441                                 case Keyboard.LEFT:     moveMap(mapwidth/2,0); break;        // left cursor
442                                 case Keyboard.UP:       moveMap(0,mapheight/2); break;           // up cursor
443                                 case Keyboard.RIGHT:    moveMap(-mapwidth/2,0); break;   // right cursor
444                                 case Keyboard.DOWN:     moveMap(0,-mapheight/2); break;      // down cursor
445                         }
446                 }
447
448                 // ------------------------------------------------------------------------------------------
449                 // Debugging
450                 
451                 public function clearDebug():void {
452                         if (!Globals.vars.hasOwnProperty('debug')) return;
453                         Globals.vars.debug.text='';
454                 }
455                         
456                 public function addDebug(text:String):void {
457                         trace(text);
458                         if (!Globals.vars.hasOwnProperty('debug')) return;
459                         if (!Globals.vars.debug.visible) return;
460                         Globals.vars.debug.appendText(text+"\n");
461                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
462                 }
463
464         }
465 }