net/systemeD/halcyon/Map.as

   1 package net.systemeD.halcyon {
   2
   3         import flash.text.TextField;
   4         import flash.display.DisplayObjectContainer;
   5         import flash.display.Loader;
   6         import flash.display.Sprite;
   7         import flash.display.Shape;
   8         import flash.display.Stage;
   9         import flash.display.BitmapData;
  10         import flash.display.LoaderInfo;
  11         import flash.text.Font;
  12         import flash.utils.ByteArray;
  13         import flash.events.*;
  14         import flash.net.*;
  15
  16     import net.systemeD.halcyon.connection.*;
  17     import net.systemeD.halcyon.connection.EntityEvent;
  18         import net.systemeD.halcyon.styleparser.*;
  19         import net.systemeD.halcyon.Globals;
  20
  21 //      for experimental export function:
  22 //      import flash.net.FileReference;
  23 //      import com.adobe.images.JPGEncoder;
  24
  25     public class Map extends Sprite {
  26
  27                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
  28                                                                                                                 // (for Landsat, 5120)
  29                 public const MINSCALE:uint=13;                                  // don't zoom out past this
  30                 public const MAXSCALE:uint=23;                                  // don't zoom in past this
  31
  32                 public var paint:MapPaint;                                              // sprite for ways and (POI/tagged) nodes in core layer
  33                 public var vectorbg:Sprite;                                             // sprite for vector background layers
  34
  35                 public var scale:uint=14;                                               // map scale
  36                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
  37                 public var bigedge_l:Number= 999999;                    // area of largest whichways
  38                 public var bigedge_r:Number=-999999;                    //  |
  39                 public var bigedge_b:Number= 999999;                    //  |
  40                 public var bigedge_t:Number=-999999;                    //  |
  41
  42                 public var edge_l:Number;                                               // current bounding box
  43                 public var edge_r:Number;                                               //  |
  44                 public var edge_t:Number;                                               //  |
  45                 public var edge_b:Number;                                               //  |
  46                 public var centre_lat:Number;                                   // centre lat/lon
  47                 public var centre_lon:Number;                                   //  |
  48
  49                 public var baselon:Number;                                              // urllon-xradius/masterscale;
  50                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
  51                 public var mapwidth:uint;                                               // width (Flash pixels)
  52                 public var mapheight:uint;                                              // height (Flash pixels)
  53
  54                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map
  55                 private var _draggable:Boolean=true;                    //  |
  56                 private var lastxmouse:Number;                                  //  |
  57                 private var lastymouse:Number;                                  //  |
  58                 private var downX:Number;                                               //  |
  59                 private var downY:Number;                                               //  |
  60                 private var downTime:Number;                                    //  |
  61                 public const NOT_DRAGGING:uint=0;                               //  |
  62                 public const NOT_MOVED:uint=1;                                  //  |
  63                 public const DRAGGING:uint=2;                                   //  |
  64                 public const TOLERANCE:uint=7;                                  //  |
  65
  66                 public var initparams:Object;                                   // object containing HTML page parameters
  67
  68                 public var backdrop:Object;                                             // reference to backdrop sprite
  69                 public var tileset:TileSet;                                             // 900913 tile background
  70                 private var tileurl:String='';                                  // internal tile URL
  71                 private var styleurl:String='';                                 // internal style URL
  72                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
  73
  74                 public var connection:Connection;                               // server connection
  75                 public var vectorlayers:Object={};                              // VectorLayer objects
  76
  77                 // ------------------------------------------------------------------------------------------
  78                 // Map constructor function
  79
  80         public function Map(initparams:Object) {
  81
  82                         this.initparams=initparams;
  83                         connection = Connection.getConnection(initparams);
  84             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
  85             connection.addEventListener(Connection.NEW_POI, newPOICreated);
  86             connection.addEventListener(Connection.WAY_RENUMBERED, wayRenumbered);
  87             connection.addEventListener(Connection.NODE_RENUMBERED, nodeRenumbered);
  88                         gotEnvironment(null);
  89
  90                         addEventListener(Event.ENTER_FRAME, everyFrame);
  91         }
  92
  93                 public function gotEnvironment(r:Object):void {
  94                         var loader:Loader = new Loader();
  95                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
  96                         loader.load(new URLRequest("FontLibrary.swf"));
  97                 }
  98
  99                 public function gotFont(r:Event):void {
 100                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
 101                         Font.registerFont(FontLibrary.DejaVu);
 102
 103                         if (initparams['lat'] != null) {
 104                                 // parameters sent from HTML
 105                                 init(initparams['lat'],
 106                                          initparams['lon'],
 107                                          initparams['zoom']);
 108
 109                         } else {
 110                                 // somewhere innocuous
 111                                 init(53.09465,-2.56495,17);
 112                         }
 113                 }
 114
 115                 // ------------------------------------------------------------------------------------------
 116                 // Initialise map at a given lat/lon
 117
 118         public function init(startlat:Number,startlon:Number,startscale:uint=0):void {
 119                         while (numChildren) { removeChildAt(0); }
 120
 121                         tileset=new TileSet(this);                                      // 0 - 900913 background
 122                         addChild(tileset);                                                      //   |
 123                         tileset.init(tileurl);                                          //   |
 124
 125                         vectorbg = new Sprite();                                        // 1 - vector background layers
 126                         addChild(vectorbg);                                                     //   |
 127
 128                         paint = new MapPaint(this,-5,5);                        // 2 - core paint object
 129                         addChild(paint);                                                        //   |
 130                         paint.isBackground=false;                                       //   |
 131
 132                         if (styleurl) {                                                         // if we've only just set up paint, then setStyle won't have created the RuleSet
 133                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
 134                                 paint.ruleset.loadFromCSS(styleurl);
 135                         }
 136                         if (startscale>0) {
 137                                 scale=startscale;
 138                                 this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
 139                         }
 140
 141                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
 142                         baselon    =startlon          -(mapwidth /2)/scalefactor;
 143                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
 144                         addDebug("Baselon "+baselon+", basey "+basey);
 145                         updateCoords(0,0);
 146                         download();
 147
 148         }
 149
 150                 // ------------------------------------------------------------------------------------------
 151                 // Recalculate co-ordinates from new Flash origin
 152
 153                 public function updateCoords(tx:Number,ty:Number):void {
 154                         x=tx; y=ty;
 155
 156                         edge_t=coord2lat(-y          );
 157                         edge_b=coord2lat(-y+mapheight);
 158                         edge_l=coord2lon(-x          );
 159                         edge_r=coord2lon(-x+mapwidth );
 160                         setCentre();
 161
 162                         tileset.update();
 163                 }
 164
 165                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
 166                         var cy:Number=-(lat2coord(lat)-mapheight/2);
 167                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
 168                         updateCoords(cx,cy);
 169                 }
 170
 171                 private function setCentre():void {
 172                         centre_lat=coord2lat(-y+mapheight/2);
 173                         centre_lon=coord2lon(-x+mapwidth/2);
 174                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale}));
 175                 }
 176
 177                 public function nudgeBackground(x:Number,y:Number):void {
 178                         this.dispatchEvent(new MapEvent(MapEvent.NUDGE_BACKGROUND, { x: x, y: y }));
 179                 }
 180
 181                 private function moveMap(dx:Number,dy:Number):void {
 182                         updateCoords(x+dx,y+dy);
 183                         updateEntityUIs(false, false);
 184                         download();
 185                 }
 186
 187                 // Co-ordinate conversion functions
 188
 189                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
 190                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
 191                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
 192                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
 193
 194                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
 195                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
 196
 197                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
 198                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
 199
 200 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
 201 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
 202
 203
 204                 // ------------------------------------------------------------------------------------------
 205                 // Resize map size based on current stage and height
 206
 207                 public function updateSize(w:uint, h:uint):void {
 208                         mapwidth = w; centre_lon=coord2lon(-x+w/2);
 209                         mapheight= h; centre_lat=coord2lat(-y+h/2);
 210
 211                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
 212
 213             if ( backdrop != null ) {
 214                 backdrop.width=mapwidth;
 215                 backdrop.height=mapheight;
 216             }
 217             if ( mask != null ) {
 218                 mask.width=mapwidth;
 219                 mask.height=mapheight;
 220             }
 221                 }
 222
 223                 // ------------------------------------------------------------------------------------------
 224                 // Download map data
 225                 // (typically from whichways, but will want to add more connections)
 226
 227                 public function download():void {
 228                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
 229
 230                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
 231                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
 232                         bigedge_l=edge_l; bigedge_r=edge_r;
 233                         bigedge_b=edge_b; bigedge_t=edge_t;
 234                         if (connection.waycount>1000) {
 235                                 connection.purgeOutside(edge_l,edge_r,edge_t,edge_b);
 236                         }
 237                         addDebug("Calling download with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
 238                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
 239                 }
 240
 241         private function newWayCreated(event:EntityEvent):void {
 242             var way:Way = event.entity as Way;
 243                         if (!way.loaded || !way.within(edge_l,edge_r,edge_t,edge_b)) { return; }
 244                         paint.createWayUI(way);
 245         }
 246
 247         private function newPOICreated(event:EntityEvent):void {
 248             var node:Node = event.entity as Node;
 249                         if (!node.within(edge_l,edge_r,edge_t,edge_b)) { return; }
 250                         paint.createNodeUI(node);
 251         }
 252
 253                 private function wayRenumbered(event:EntityRenumberedEvent):void {
 254             var way:Way = event.entity as Way;
 255                         paint.renumberWayUI(way,event.oldID);
 256                 }
 257
 258                 private function nodeRenumbered(event:EntityRenumberedEvent):void {
 259             var node:Node = event.entity as Node;
 260                         paint.renumberNodeUI(node,event.oldID);
 261                 }
 262
 263         public function setHighlight(entity:Entity, settings:Object):void {
 264                         if      ( entity is Way  && paint.wayuis[entity.id] ) { paint.wayuis[entity.id].setHighlight(settings);  }
 265                         else if ( entity is Node && paint.nodeuis[entity.id]) { paint.nodeuis[entity.id].setHighlight(settings); }
 266         }
 267
 268         public function setHighlightOnNodes(way:Way, settings:Object):void {
 269                         if (paint.wayuis[way.id]) paint.wayuis[way.id].setHighlightOnNodes(settings);
 270         }
 271
 272                 public function setPurgable(entity:Entity, purgable:Boolean):void {
 273                         if ( entity is Way  ) {
 274                                 var way:Way=entity as Way;
 275                                 if (paint.wayuis[way.id]) { paint.wayuis[way.id].purgable=purgable; }
 276                                 for (var i:uint=0; i<way.length; i++) {
 277                                         if (paint.nodeuis[way.getNode(i).id]) {
 278                                                 paint.nodeuis[way.getNode(i).id].purgable=purgable;
 279                                         }
 280                                 }
 281                         } else if ( entity is Node && paint.nodeuis[entity.id]) {
 282                                 paint.nodeuis[entity.id].purgable=purgable;
 283                         }
 284                 }
 285
 286         // Handle mouse events on ways/nodes
 287         private var mapController:MapController = null;
 288
 289         public function setController(controller:MapController):void {
 290             this.mapController = controller;
 291         }
 292
 293         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
 294             if ( mapController != null )
 295                 mapController.entityMouseEvent(event, entity);
 296
 297         }
 298
 299                 // ------------------------------------------------------------------------------------------
 300                 // Add vector layer
 301
 302                 public function addVectorLayer(layer:VectorLayer):void {
 303                         vectorlayers[layer.name]=layer;
 304                         vectorbg.addChild(layer.paint);
 305                 }
 306
 307                 // ------------------------------------------------------------------------------------------
 308                 // Redraw all items, zoom in and out
 309
 310                 public function updateEntityUIs(redraw:Boolean,remove:Boolean):void {
 311                         paint.updateEntityUIs(connection.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
 312                         for each (var v:VectorLayer in vectorlayers) {
 313                                 v.paint.updateEntityUIs(v.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
 314                         }
 315                 }
 316                 public function redraw():void {
 317                         paint.redraw();
 318                         for each (var v:VectorLayer in vectorlayers) { v.paint.redraw(); }
 319                 }
 320                 public function redrawPOIs():void {
 321                         paint.redrawPOIs();
 322                         for each (var v:VectorLayer in vectorlayers) { v.paint.redrawPOIs(); }
 323                 }
 324
 325                 public function zoomIn():void {
 326                         if (scale==MAXSCALE) { return; }
 327                         changeScale(scale+1);
 328                 }
 329
 330                 public function zoomOut():void {
 331                         if (scale==MINSCALE) { return; }
 332                         changeScale(scale-1);
 333                 }
 334
 335                 private function changeScale(newscale:uint):void {
 336                         addDebug("new scale "+newscale);
 337                         scale=newscale;
 338                         this.dispatchEvent(new MapEvent(MapEvent.SCALE, {scale:scale}));
 339                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
 340                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
 341                         tileset.changeScale(scale);
 342                         updateEntityUIs(true,true);
 343                         download();
 344                 }
 345
 346                 private function reportPosition():void {
 347                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
 348                 }
 349
 350                 public function setStyle(url:String):void {
 351                         styleurl=url;
 352                         if (paint) {
 353                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
 354                                 paint.ruleset.loadFromCSS(url);
 355                         }
 356         }
 357
 358                 public function setBackground(url:String):void {
 359                         tileurl=url;
 360                         if (tileset) { tileset.init(url, url!=''); }
 361                 }
 362
 363                 public function setDimming(dim:Boolean):void {
 364                         if (tileset) { tileset.setDimming(dim); }
 365                 }
 366
 367                 // ------------------------------------------------------------------------------------------
 368                 // Export (experimental)
 369                 // ** just a bit of fun for now!
 370                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized
 371                 // to that area (will probably require creating a new DisplayObject with a different origin
 372                 // and mask)
 373 /*
 374                 public function export():void {
 375                         addDebug("size is "+this.width+","+this.height);
 376                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
 377                         jpgSource.draw(this);
 378                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
 379                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
 380                         var fileRef:FileReference = new FileReference();
 381 //                      fileRef.save(jpgStream,'map.jpeg');
 382                 }
 383
 384 */
 385
 386                 // ==========================================================================================
 387                 // Events
 388
 389                 // ------------------------------------------------------------------------------------------
 390                 // Mouse events
 391
 392                 public function set draggable(draggable:Boolean):void {
 393                         _draggable=draggable;
 394                         dragstate=NOT_DRAGGING;
 395                 }
 396
 397                 public function mouseDownHandler(event:MouseEvent):void {
 398                         if (!_draggable) { return; }
 399                         dragstate=NOT_MOVED;
 400                         lastxmouse=mouseX; downX=stage.mouseX;
 401                         lastymouse=mouseY; downY=stage.mouseY;
 402                         downTime=new Date().getTime();
 403                 }
 404
 405                 public function mouseUpHandler(event:MouseEvent=null):void {
 406                         if (dragstate==DRAGGING) { moveMap(0,0); }
 407                         dragstate=NOT_DRAGGING;
 408                 }
 409
 410                 public function mouseMoveHandler(event:MouseEvent):void {
 411                         if (!_draggable) { return; }
 412                         if (dragstate==NOT_DRAGGING) { return; }
 413
 414                         if (dragstate==NOT_MOVED) {
 415                                 if (new Date().getTime()-downTime<300) {
 416                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE   && Math.abs(downY-stage.mouseY)<=TOLERANCE  ) return;
 417                                 } else {
 418                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE/2 && Math.abs(downY-stage.mouseY)<=TOLERANCE/2) return;
 419                                 }
 420                                 dragstate=DRAGGING;
 421                         }
 422
 423                         x+=mouseX-lastxmouse;
 424                         y+=mouseY-lastymouse;
 425                         lastxmouse=mouseX; lastymouse=mouseY;
 426                         setCentre();
 427                 }
 428
 429                 // ------------------------------------------------------------------------------------------
 430                 // Do every frame
 431
 432                 private function everyFrame(event:Event):void {
 433                         if (tileset) { tileset.serviceQueue(); }
 434                 }
 435
 436                 // ------------------------------------------------------------------------------------------
 437                 // Miscellaneous events
 438
 439                 public function keyUpHandler(event:KeyboardEvent):void {
 440                         if (event.target is TextField) return;                          // not meant for us
 441                         switch (event.keyCode) {
 442                                 case 33:        zoomIn(); break;                                        // Page Up - zoom in
 443                                 case 34:        zoomOut(); break;                                       // Page Down - zoom out
 444                                 case 37:        moveMap(mapwidth/2,0); break;           // left cursor
 445                                 case 38:        moveMap(0,mapheight/2); break;          // up cursor
 446                                 case 39:        moveMap(-mapwidth/2,0); break;          // right cursor
 447                                 case 40:        moveMap(0,-mapheight/2); break;         // down cursor
 448 //                              case 76:        reportPosition(); break;                        // L - report lat/long
 449                         }
 450                 }
 451
 452                 public function connectionError(err:Object=null): void {
 453                         addDebug("got error");
 454                 }
 455
 456                 // ------------------------------------------------------------------------------------------
 457                 // Debugging
 458
 459                 public function clearDebug():void {
 460                         if (!Globals.vars.hasOwnProperty('debug')) return;
 461                         Globals.vars.debug.text='';
 462                 }
 463
 464                 public function addDebug(text:String):void {
 465                         if (!Globals.vars.hasOwnProperty('debug')) return;
 466                         if (!Globals.vars.debug.visible) return;
 467                         Globals.vars.debug.appendText(text+"\n");
 468                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
 469                 }
 470
 471         }
 472 }