net/systemeD/halcyon/Map.as

   1 package net.systemeD.halcyon {
   2
   3         import flash.text.TextField;
   4         import flash.display.DisplayObjectContainer;
   5         import flash.display.Sprite;
   6         import flash.display.Shape;
   7         import flash.display.Stage;
   8         import flash.events.*;
   9         import flash.net.*;
  10
  11     import net.systemeD.halcyon.connection.*;
  12     import net.systemeD.halcyon.connection.EntityEvent;
  13         import net.systemeD.halcyon.styleparser.*;
  14
  15     public class Map extends Sprite {
  16
  17                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
  18                                                                                                                 // (for Landsat, 5120)
  19                 public const MINSCALE:uint=13;                                  // don't zoom out past this
  20                 public const MAXSCALE:uint=19;                                  // don't zoom in past this
  21
  22                 public var ruleset:RuleSet=new RuleSet(redrawPOIs);     // rules
  23
  24                 public var ways:Object=new Object();                    // geodata
  25                 public var nodes:Object=new Object();                   //  |
  26                 public var pois:Object=new Object();                    //  |
  27                 public var relations:Object=new Object();               //  |
  28
  29                 public var scale:uint=14;                                               // map scale
  30                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
  31                 public var bigedge_l:Number= 999999;                    // area of largest whichways
  32                 public var bigedge_r:Number=-999999;                    //  |
  33                 public var bigedge_b:Number= 999999;                    //  |
  34                 public var bigedge_t:Number=-999999;                    //  |
  35
  36                 public var waycount:uint=0;                                             // ways:                number currently loaded
  37                 public var waysrequested:uint=0;                                //                              total number requested
  38                 public var waysreceived:uint=0;                                 //                              total number received
  39                 public var relcount:uint=0;                                             // relations:   number currently loaded
  40                 public var relsrequested:uint=0;                                //                              total number requested
  41                 public var relsreceived:uint=0;                                 //                              total number received
  42                 public var poicount:uint=0;                                             // POIs:                number currently loaded
  43                 public var whichrequested:uint=0;                               // whichways:   total number requested
  44                 public var whichreceived:uint=0;                                //                              total number received
  45
  46                 public var edge_l:Number;                                               // current bounding box
  47                 public var edge_r:Number;                                               //  |
  48                 public var edge_t:Number;                                               //  |
  49                 public var edge_b:Number;                                               //  |
  50
  51                 public var baselon:Number;                                              // urllon-xradius/masterscale;
  52                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
  53                 public var mapwidth:uint;                                               // width (Flash pixels)
  54                 public var mapheight:uint;                                              // height (Flash pixels)
  55
  56                 private var dragging:Boolean=false;                             // dragging map?
  57                 private var lastxmouse:Number;                                  //  |
  58                 private var lastymouse:Number;                                  //  |
  59
  60                 public var backdrop:Object;                                             // reference to backdrop sprite
  61
  62                 public var connection:Connection;                       // server connection
  63
  64                 // ------------------------------------------------------------------------------------------
  65                 // Map constructor function
  66
  67         public function Map() {
  68
  69                         // Set up layering
  70                         // [layer][2]                   - names
  71                         // [layer][1][sublayer] - stroke
  72                         // [layer][0]                   - fill
  73
  74                         for (var l:int=0; l<13; l++) {                          // 11 layers (10 is +5, 0 is -5)
  75                                 var s:Sprite=new Sprite();                              //  |
  76                                 s.addChild(new Sprite());                               //      | 0 fill
  77                                 var t:Sprite=new Sprite();                              //  | 1 stroke
  78                                 for (var j:int=0; j<11; j++) {                  //      |  | ten sublayers
  79                                         t.addChild(new Sprite());                       //  |  |  |
  80                                 }                                                                               //  |  |  |
  81                                 s.addChild(t);                                                  //  |  |
  82                                 s.addChild(new Sprite());                               //      | 2 names
  83                                 addChild(s);                                                    //  |
  84                         }
  85                         s=new Sprite(); addChild(s);                            // 11 - POIs
  86                         s=new Sprite(); addChild(s);                            // 12 - shields and POI names
  87
  88                         connection= Connection.getConnection();
  89             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
  90             connection.addEventListener(Connection.NEW_POI, newPOICreated);
  91                         connection.getEnvironment(new Responder(gotEnvironment,connectionError));
  92
  93         }
  94
  95                 public function gotEnvironment(r:Object):void {
  96                         init(53.09465,-2.56495,17);
  97                 }
  98
  99                 // ------------------------------------------------------------------------------------------
 100                 // Initialise map at a given lat/lon
 101
 102         public function init(startlat:Number,startlon:Number,startscale:uint):void {
 103
 104                         ruleset.load("test.yaml?d="+Math.random());
 105 //                      rules.initExample();            // initialise dummy rules
 106
 107                         updateSize();
 108
 109                         scale=startscale;
 110                         scalefactor=MASTERSCALE/Math.pow(2,14-scale);
 111                         baselon    =startlon          -(mapwidth /2)/scalefactor;
 112                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
 113                         addDebug("Baselon "+baselon+", basey "+basey);
 114                         updateCoords(0,0);
 115                         download();
 116
 117         }
 118
 119                 // ------------------------------------------------------------------------------------------
 120                 // Recalculate co-ordinates from new Flash origin
 121
 122                 public function updateCoords(tx:Number,ty:Number):void {
 123                         x=tx; y=ty;
 124
 125                         // ** calculate tile_l etc.
 126                         edge_t=coord2lat(-y          );
 127                         edge_b=coord2lat(-y+mapheight);
 128                         edge_l=coord2lon(-x          );
 129                         edge_r=coord2lon(-x+mapwidth );
 130                         addDebug("Lon "+edge_l+"-"+edge_r);
 131                         addDebug("Lat "+edge_b+"-"+edge_t);
 132                 }
 133
 134                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
 135                         var cy:Number=-(lat2coord(lat)-mapheight/2);
 136                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
 137                         updateCoords(cx,cy);
 138                 }
 139
 140
 141                 // Co-ordinate conversion functions
 142
 143                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
 144                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
 145                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
 146                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
 147
 148                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
 149                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
 150
 151                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
 152                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
 153
 154 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
 155 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
 156
 157
 158                 // ------------------------------------------------------------------------------------------
 159                 // Resize map size based on current stage and height
 160
 161                 public function updateSize():void {
 162                         mapwidth =stage.stageWidth; backdrop.width=mapwidth; mask.width=mapwidth;
 163                         mapheight=stage.stageHeight; backdrop.height=mapheight; mask.height=mapheight;
 164                 }
 165
 166                 // ------------------------------------------------------------------------------------------
 167                 // Download map data
 168                 // (typically from whichways, but will want to add more connections)
 169
 170                 public function download():void {
 171                         var e:MapEvent = new MapEvent("download",edge_l,edge_r,edge_t,edge_b);
 172                         this.dispatchEvent(e);
 173
 174                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
 175                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
 176                         bigedge_l=edge_l; bigedge_r=edge_r;
 177                         bigedge_b=edge_b; bigedge_t=edge_t;
 178                         addDebug("Calling with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
 179                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
 180                 }
 181
 182 /*
 183                 public function gotBbox(r:Object):void {
 184                         addDebug("got whichways");
 185                         var code:uint         =r.shift(); if (code) { connectionError(); return; }
 186                         var message:String    =r.shift();
 187                         var waylist:Array     =r[0];
 188                         var pointlist:Array   =r[1];
 189                         var relationlist:Array=r[2];
 190                         var i:uint, v:uint;
 191
 192                         for each (var w:Array in waylist) {
 193                                 i=w[0]; v=w[1];
 194                                 if (ways[i] && ways[i].version==v) { continue; }
 195                                 ways[i]=new Way(i,v,this);
 196                                 ways[i].load(connection);
 197                         }
 198
 199                         for each (var p:Array in pointlist) {
 200                                 i=p[0]; v=p[4];
 201                                 if (pois[i] && pois[i].version==v) { continue; }
 202                                 pois[i]=new POI(i,v,p[1],p[2],p[3],this);
 203                         }
 204
 205                         addDebug("waylist is "+waylist);
 206                 }
 207 */
 208
 209         private function newWayCreated(event:EntityEvent):void {
 210             var way:Way = event.entity as Way;
 211             ways[way.id] = new WayUI(way, this);
 212         }
 213
 214         private function newPOICreated(event:EntityEvent):void {
 215             var node:Node = event.entity as Node;
 216             pois[node.id] = new POI(node, this);
 217         }
 218
 219                 // ------------------------------------------------------------------------------------------
 220                 // Redraw all items, zoom in and out
 221
 222                 public function redraw():void {
 223                         for each (var w:WayUI in ways) { w.recalculate(); w.redraw(); }
 224                         for each (var p:POI in pois) { p.redraw(); }
 225                 }
 226
 227                 public function redrawPOIs():void {
 228                         for each (var p:POI in pois) { p.redraw(); }
 229                 }
 230
 231                 public function zoomIn():void {
 232                         if (scale==MAXSCALE) { return; }
 233                         changeScale(scale+1);
 234                 }
 235
 236                 public function zoomOut():void {
 237                         if (scale==MINSCALE) { return; }
 238                         changeScale(scale-1);
 239                 }
 240
 241                 private function changeScale(newscale:uint):void {
 242                         addDebug("new scale "+newscale);
 243                         scale=newscale;
 244                         scalefactor=MASTERSCALE/Math.pow(2,14-scale);
 245                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
 246                         download();
 247                         redraw();
 248                 }
 249
 250                 private function reportPosition():void {
 251                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
 252                 }
 253
 254
 255                 // ==========================================================================================
 256                 // Events
 257
 258                 // ------------------------------------------------------------------------------------------
 259                 // Mouse events
 260
 261                 public function mouseDownHandler(event:MouseEvent):void {
 262                         dragging=true;
 263                         lastxmouse=mouseX; lastymouse=mouseY;
 264                 }
 265
 266                 public function mouseUpHandler(event:MouseEvent):void {
 267                         if (!dragging) { return; }
 268                         dragging=false;
 269                         updateCoords(x,y);
 270                         download();
 271                 }
 272
 273                 public function mouseMoveHandler(event:MouseEvent):void {
 274                         if (!dragging) { return; }
 275                         x+=mouseX-lastxmouse;
 276                         y+=mouseY-lastymouse;
 277                         lastxmouse=mouseX; lastymouse=mouseY;
 278                 }
 279
 280                 // ------------------------------------------------------------------------------------------
 281                 // Miscellaneous events
 282
 283                 public function keyUpHandler(event:KeyboardEvent):void {
 284 // addDebug("pressed "+event.keyCode);
 285                         if (event.keyCode==82) { this.redraw(); }                       // R - redraw
 286                         if (event.keyCode==73) { this.zoomIn(); }                       // I - zoom in
 287                         if (event.keyCode==79) { this.zoomOut(); }                      // O - zoom out
 288                         if (event.keyCode==76) { this.reportPosition(); }       // L - report lat/long
 289                 }
 290
 291                 public function connectionError(err:Object=null): void {
 292                         addDebug("got error");
 293                 }
 294
 295                 // ------------------------------------------------------------------------------------------
 296                 // Debugging
 297
 298                 public function addDebug(text:String):void {
 299                         Globals.vars.debug.appendText(text+"\n");
 300                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
 301                 }
 302
 303         }
 304 }