add node drawing + dragging & highlight selected way using stylesheet
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19
20 //      for experimental export function:
21 //      import flash.net.FileReference;
22 //      import com.adobe.images.JPGEncoder;
23
24     public class Map extends Sprite {
25
26                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
27                                                                                                                 // (for Landsat, 5120)
28                 public const MINSCALE:uint=13;                                  // don't zoom out past this
29                 public const MAXSCALE:uint=19;                                  // don't zoom in past this
30
31                 public var ruleset:RuleSet=new RuleSet(redrawPOIs);     // rules
32                 
33                 public var ways:Object=new Object();                    // geodata
34                 public var nodes:Object=new Object();                   //  |
35                 public var pois:Object=new Object();                    //  |
36                 public var relations:Object=new Object();               //  |
37
38                 public var scale:uint=14;                                               // map scale
39                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
40                 public var bigedge_l:Number= 999999;                    // area of largest whichways
41                 public var bigedge_r:Number=-999999;                    //  |
42                 public var bigedge_b:Number= 999999;                    //  |
43                 public var bigedge_t:Number=-999999;                    //  |
44
45                 public var waycount:uint=0;                                             // ways:                number currently loaded
46                 public var waysrequested:uint=0;                                //                              total number requested
47                 public var waysreceived:uint=0;                                 //                              total number received
48                 public var relcount:uint=0;                                             // relations:   number currently loaded
49                 public var relsrequested:uint=0;                                //                              total number requested
50                 public var relsreceived:uint=0;                                 //                              total number received
51                 public var poicount:uint=0;                                             // POIs:                number currently loaded
52                 public var whichrequested:uint=0;                               // whichways:   total number requested
53                 public var whichreceived:uint=0;                                //                              total number received
54
55                 public var edge_l:Number;                                               // current bounding box
56                 public var edge_r:Number;                                               //  |
57                 public var edge_t:Number;                                               //  |
58                 public var edge_b:Number;                                               //  |
59
60                 public var baselon:Number;                                              // urllon-xradius/masterscale;
61                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
62                 public var mapwidth:uint;                                               // width (Flash pixels)
63                 public var mapheight:uint;                                              // height (Flash pixels)
64
65                 private var dragging:Boolean=false;                             // dragging map?
66                 private var lastxmouse:Number;                                  //  |
67                 private var lastymouse:Number;                                  //  |
68                 
69                 public var initparams:Object;                                   // object containing 
70
71                 public var backdrop:Object;                                             // reference to backdrop sprite
72                 
73                 public var connection:Connection;                               // server connection
74
75                 // ------------------------------------------------------------------------------------------
76                 // Map constructor function
77
78         public function Map(initparams:Object) {
79
80                         // Set up layering
81                         // [layer][2]                   - names
82                         // [layer][1][sublayer] - stroke
83                         // [layer][0]                   - fill
84
85                         for (var l:int=0; l<13; l++) {                          // 11 layers (10 is +5, 0 is -5)
86                                 var s:Sprite = getHitSprite();          //  |
87                                 s.addChild(getPaintSprite());                   //      | 0 fill
88                                 var t:Sprite = getPaintSprite();                //  | 1 stroke
89                                 for (var j:int=0; j<11; j++) {                  //      |  | ten sublayers
90                                         t.addChild(getPaintSprite());           //  |  |  |
91                                 }                                                                               //  |  |  |
92                                 s.addChild(t);                                                  //  |  |
93                                 s.addChild(getPaintSprite());                   //      | 2 names
94                                 s.addChild(getHitSprite());                         //  | 3 entity hit tests
95                                 addChild(s);                                                    //  |
96                         }
97                         addChild(getPaintSprite());                             // 11 - POIs
98                         addChild(getPaintSprite());                             // 12 - shields and POI names
99
100                         this.initparams=initparams;
101                         connection = Connection.getConnection(initparams);
102             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
103             connection.addEventListener(Connection.NEW_POI, newPOICreated);
104                         gotEnvironment(null);
105         }
106
107         private function getPaintSprite():Sprite {
108             var s:Sprite = new Sprite();
109             s.mouseEnabled = false;
110             s.mouseChildren = false;
111             return s;
112         }
113
114         private function getHitSprite():Sprite {
115             var s:Sprite = new Sprite();
116             return s;
117         }
118
119                 public function gotEnvironment(r:Object):void {
120                         var loader:Loader = new Loader();
121                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
122                         loader.load(new URLRequest("FontLibrary.swf"));
123                 }
124                 
125                 public function gotFont(r:Event):void {
126                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
127                         Font.registerFont(FontLibrary.DejaVu);
128
129                         if (initparams['lat'] != null) {
130                                 // parameters sent from HTML
131                                 init(initparams['lat'],
132                                          initparams['lon'],
133                                          initparams['zoom'],
134                                          initparams['style']);
135
136                         } else {
137                                 // somewhere innocuous
138                                 init(53.09465,-2.56495,17,"test.yaml?d="+Math.random());
139                         }
140                 }
141
142                 // ------------------------------------------------------------------------------------------
143                 // Initialise map at a given lat/lon
144
145         public function init(startlat:Number,startlon:Number,startscale:uint,style:String):void {
146
147                         ruleset.load(style);
148 //                      rules.initExample();            // initialise dummy rules
149
150                         //updateSize();
151
152                         scale=startscale;
153                         scalefactor=MASTERSCALE/Math.pow(2,14-scale);
154                         baselon    =startlon          -(mapwidth /2)/scalefactor;
155                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
156                         addDebug("Baselon "+baselon+", basey "+basey);
157                         updateCoords(0,0);
158                         download();
159                         
160         }
161
162                 // ------------------------------------------------------------------------------------------
163                 // Recalculate co-ordinates from new Flash origin
164
165                 public function updateCoords(tx:Number,ty:Number):void {
166                         x=tx; y=ty;
167
168                         // ** calculate tile_l etc.
169                         edge_t=coord2lat(-y          );
170                         edge_b=coord2lat(-y+mapheight);
171                         edge_l=coord2lon(-x          );
172                         edge_r=coord2lon(-x+mapwidth );
173                         addDebug("Lon "+edge_l+"-"+edge_r);
174                         addDebug("Lat "+edge_b+"-"+edge_t);
175                 }
176                 
177                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
178                         var cy:Number=-(lat2coord(lat)-mapheight/2);
179                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
180                         updateCoords(cx,cy);
181                 }
182
183
184                 // Co-ordinate conversion functions
185
186                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
187                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
188                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
189                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
190
191                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
192                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
193
194                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
195                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
196
197 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
198 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
199
200
201                 // ------------------------------------------------------------------------------------------
202                 // Resize map size based on current stage and height
203
204                 public function updateSize(w:uint, h:uint):void {
205                         mapwidth = w;
206                         mapheight= h;
207             if ( backdrop != null ) {
208                 backdrop.width=mapwidth;
209                 backdrop.height=mapheight;
210             }
211             if ( mask != null ) {
212                 mask.width=mapwidth;
213                 mask.height=mapheight;
214             }
215                 }
216
217                 // ------------------------------------------------------------------------------------------
218                 // Download map data
219                 // (typically from whichways, but will want to add more connections)
220
221                 public function download():void {
222                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD,edge_l,edge_r,edge_t,edge_b));
223                         
224                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
225                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
226                         bigedge_l=edge_l; bigedge_r=edge_r;
227                         bigedge_b=edge_b; bigedge_t=edge_t;
228                         addDebug("Calling with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
229                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
230                 }
231
232
233
234         private function newWayCreated(event:EntityEvent):void {
235             var way:Way = event.entity as Way;
236             ways[way.id] = new WayUI(way, this);
237         }
238
239         private function newPOICreated(event:EntityEvent):void {
240             var node:Node = event.entity as Node;
241             pois[node.id] = new POI(node, this);
242         }
243
244         public function setHighlight(entity:Entity, stateType:String, isOn:Boolean):void {
245             if ( entity is Way ) {
246                 var wayUI:WayUI = ways[entity.id];
247                 if ( wayUI != null )
248                     wayUI.setHighlight(stateType, isOn);
249             }
250         }
251
252         // Handle mouse events on ways/nodes
253         private var mapController:MapController = null;
254
255         public function setController(controller:MapController):void {
256             this.mapController = controller;
257         }
258
259         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
260             if ( mapController != null )
261                 mapController.entityMouseEvent(event, entity);
262                                 
263         }
264
265                 // ------------------------------------------------------------------------------------------
266                 // Redraw all items, zoom in and out
267                 
268                 public function redraw():void {
269                         for each (var w:WayUI in ways) { w.recalculate(); w.redraw(); }
270                         for each (var p:POI in pois) { p.redraw(); }
271                 }
272
273                 public function redrawPOIs():void {
274                         for each (var p:POI in pois) { p.redraw(); }
275                 }
276
277                 public function zoomIn():void {
278                         if (scale==MAXSCALE) { return; }
279                         changeScale(scale+1);
280                 }
281
282                 public function zoomOut():void {
283                         if (scale==MINSCALE) { return; }
284                         changeScale(scale-1);
285                 }
286
287                 private function changeScale(newscale:uint):void {
288                         addDebug("new scale "+newscale);
289                         scale=newscale;
290                         scalefactor=MASTERSCALE/Math.pow(2,14-scale);
291                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
292                         download();
293                         redraw();
294                 }
295
296                 private function reportPosition():void {
297                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
298                 }
299
300                 // ------------------------------------------------------------------------------------------
301                 // Export (experimental)
302                 // ** just a bit of fun for now!
303                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
304                 // to that area (will probably require creating a new DisplayObject with a different origin
305                 // and mask)
306 /*              
307                 public function export():void {
308                         addDebug("size is "+this.width+","+this.height);
309                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
310                         jpgSource.draw(this);
311                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
312                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
313                         var fileRef:FileReference = new FileReference();
314 //                      fileRef.save(jpgStream,'map.jpeg');
315                 }
316
317 */
318
319                 // ==========================================================================================
320                 // Events
321                 
322                 // ------------------------------------------------------------------------------------------
323                 // Mouse events
324                 
325                 public function mouseDownHandler(event:MouseEvent):void {
326                         dragging=true;
327                         lastxmouse=mouseX; lastymouse=mouseY;
328                 }
329         
330                 public function mouseUpHandler(event:MouseEvent):void {
331                         if (!dragging) { return; }
332                         dragging=false;
333                         updateCoords(x,y);
334                         download();
335                 }
336         
337                 public function mouseMoveHandler(event:MouseEvent):void {
338                         if (!dragging) { return; }
339                         x+=mouseX-lastxmouse;
340                         y+=mouseY-lastymouse;
341                         lastxmouse=mouseX; lastymouse=mouseY;
342                 }
343         
344                 // ------------------------------------------------------------------------------------------
345                 // Miscellaneous events
346                 
347                 public function keyUpHandler(event:KeyboardEvent):void {
348 // addDebug("pressed "+event.keyCode);
349             if ( !event.ctrlKey ) return;
350                         if (event.keyCode==82) { this.redraw(); }                       // R - redraw
351                         if (event.keyCode==73) { this.zoomIn(); }                       // I - zoom in
352                         if (event.keyCode==79) { this.zoomOut(); }                      // O - zoom out
353                         if (event.keyCode==76) { this.reportPosition(); }       // L - report lat/long
354 //                      if (event.keyCode==69) { this.export(); }                       // E - export
355                 }
356
357                 public function connectionError(err:Object=null): void {
358                         addDebug("got error"); 
359                 }
360
361                 // ------------------------------------------------------------------------------------------
362                 // Debugging
363                 
364                 public function addDebug(text:String):void {
365                         if (!Globals.vars.hasOwnProperty('debug')) return;
366                         if (!Globals.vars.debug.visible) return;
367                         Globals.vars.debug.appendText(text+"\n");
368                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
369                 }
370                 
371         }
372 }