various click-handling improvements/fixes
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19
20 //      for experimental export function:
21 //      import flash.net.FileReference;
22 //      import com.adobe.images.JPGEncoder;
23
24     public class Map extends Sprite {
25
26                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
27                                                                                                                 // (for Landsat, 5120)
28                 public const MINSCALE:uint=13;                                  // don't zoom out past this
29                 public const MAXSCALE:uint=19;                                  // don't zoom in past this
30
31                 public var ruleset:RuleSet;                                             // rules
32                 
33                 public var ways:Object=new Object();                    // geodata
34                 public var nodes:Object=new Object();                   //  |
35                 public var pois:Object=new Object();                    //  |
36                 public var relations:Object=new Object();               //  |
37
38                 public var scale:uint=14;                                               // map scale
39                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
40                 public var bigedge_l:Number= 999999;                    // area of largest whichways
41                 public var bigedge_r:Number=-999999;                    //  |
42                 public var bigedge_b:Number= 999999;                    //  |
43                 public var bigedge_t:Number=-999999;                    //  |
44
45                 public var waycount:uint=0;                                             // ways:                number currently loaded
46                 public var waysrequested:uint=0;                                //                              total number requested
47                 public var waysreceived:uint=0;                                 //                              total number received
48                 public var relcount:uint=0;                                             // relations:   number currently loaded
49                 public var relsrequested:uint=0;                                //                              total number requested
50                 public var relsreceived:uint=0;                                 //                              total number received
51                 public var poicount:uint=0;                                             // POIs:                number currently loaded
52                 public var whichrequested:uint=0;                               // whichways:   total number requested
53                 public var whichreceived:uint=0;                                //                              total number received
54
55                 public var edge_l:Number;                                               // current bounding box
56                 public var edge_r:Number;                                               //  |
57                 public var edge_t:Number;                                               //  |
58                 public var edge_b:Number;                                               //  |
59                 public var centre_lat:Number;                                   // centre lat/lon
60                 public var centre_lon:Number;                                   //  |
61
62                 public var baselon:Number;                                              // urllon-xradius/masterscale;
63                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
64                 public var mapwidth:uint;                                               // width (Flash pixels)
65                 public var mapheight:uint;                                              // height (Flash pixels)
66
67                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map
68                 private var lastxmouse:Number;                                  //  |
69                 private var lastymouse:Number;                                  //  |
70                 private var downX:Number;                                               //  |
71                 private var downY:Number;                                               //  |
72                 public const NOT_DRAGGING:uint=0;                               //  |
73                 public const NOT_MOVED:uint=1;                                  //  |
74                 public const DRAGGING:uint=2;                                   //  |
75                 
76                 public var initparams:Object;                                   // object containing 
77
78                 public var backdrop:Object;                                             // reference to backdrop sprite
79                 public var tileset:TileSet;                                             // 900913 tile background
80                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
81                 
82                 public var connection:Connection;                               // server connection
83
84                 public const TILESPRITE:uint=0;
85                 public const GPSSPRITE:uint=1;
86                 public const WAYSPRITE:uint=2;
87                 public const POISPRITE:uint=13;
88                 public const NAMESPRITE:uint=14;
89                 
90                 // ------------------------------------------------------------------------------------------
91                 // Map constructor function
92
93         public function Map(initparams:Object) {
94                         this.initparams=initparams;
95                         connection = Connection.getConnection(initparams);
96             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
97             connection.addEventListener(Connection.NEW_POI, newPOICreated);
98                         gotEnvironment(null);
99
100                         addEventListener(Event.ENTER_FRAME, everyFrame);
101         }
102
103                 // Set up layering
104                 // [layer][3]                   - names
105                 // [layer][2][sublayer] - stroke
106                 // [layer][1]                   - casing
107                 // [layer][0]                   - fill
108
109                 private function createSprites():void {
110                         tileset=new TileSet(this);                                      // 900913 background
111                         addChild(tileset);                                                      //  |
112                         addChild(new Sprite());                                         // GPS
113
114                         for (var l:int=0; l<13; l++) {                          // 11 layers (11 is +5, 1 is -5)
115                                 var s:Sprite = getHitSprite();          //  |
116                                 s.addChild(getPaintSprite());                   //      | 0 fill
117                                 s.addChild(getPaintSprite());                   //      | 1 casing
118                                 var t:Sprite = getPaintSprite();                //  | 2 stroke
119                                 for (var j:int=0; j<11; j++) {                  //      |  | ten sublayers
120                                         t.addChild(getPaintSprite());           //  |  |  |
121                                 }                                                                               //  |  |  |
122                                 s.addChild(t);                                                  //  |  |
123                                 s.addChild(getPaintSprite());                   //      | 3 names
124                                 s.addChild(getPaintSprite());                   //      | 4 nodes
125                                 s.addChild(getHitSprite());                         //  | 5 entity hit tests
126                                 addChild(s);                                                    //  |
127                         }
128                         addChild(getPaintSprite());                             // 12 - POIs
129                         addChild(getPaintSprite());                             // 13 - shields and POI names
130                 }
131                 
132                 private function removeSprites():void {
133                         while (numChildren) { removeChildAt(0); }
134                 }
135
136         private function getPaintSprite():Sprite {
137             var s:Sprite = new Sprite();
138             s.mouseEnabled = false;
139             s.mouseChildren = false;
140             return s;
141         }
142
143         private function getHitSprite():Sprite {
144             var s:Sprite = new Sprite();
145             return s;
146         }
147
148                 public function gotEnvironment(r:Object):void {
149                         var loader:Loader = new Loader();
150                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
151                         loader.load(new URLRequest("FontLibrary.swf"));
152                 }
153                 
154                 public function gotFont(r:Event):void {
155                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
156                         Font.registerFont(FontLibrary.DejaVu);
157
158                         if (initparams['lat'] != null) {
159                                 // parameters sent from HTML
160                                 init(initparams['lat'],
161                                          initparams['lon'],
162                                          initparams['zoom'],
163                                          initparams['style'],
164                                          initparams['tileurl']);
165
166                         } else {
167                                 // somewhere innocuous
168                                 init(53.09465,-2.56495,17,"test.css?d="+Math.random(),"");
169                         }
170                 }
171
172                 // ------------------------------------------------------------------------------------------
173                 // Initialise map at a given lat/lon
174
175         public function init(startlat:Number,startlon:Number,startscale:uint=0,style:String=null,tileurl:String=''):void {
176                         removeSprites();
177                         createSprites();
178                         tileset.init(tileurl);
179
180                         if (style) {
181                                 ruleset=new RuleSet(this,redrawPOIs);
182                                 ruleset.loadFromCSS(style);
183                         }
184                         if (startscale>0) { scale=startscale; }
185
186                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
187                         baselon    =startlon          -(mapwidth /2)/scalefactor;
188                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
189                         addDebug("Baselon "+baselon+", basey "+basey);
190                         updateCoords(0,0);
191                         download();
192                         
193         }
194
195                 // ------------------------------------------------------------------------------------------
196                 // Recalculate co-ordinates from new Flash origin
197
198                 public function updateCoords(tx:Number,ty:Number):void {
199                         x=tx; y=ty;
200
201                         edge_t=coord2lat(-y          );
202                         edge_b=coord2lat(-y+mapheight);
203                         edge_l=coord2lon(-x          );
204                         edge_r=coord2lon(-x+mapwidth );
205                         setCentre();
206 //                      addDebug("Lon "+edge_l+"-"+edge_r);
207 //                      addDebug("Lat "+edge_b+"-"+edge_t);
208
209                         tileset.update();
210                 }
211                 
212                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
213                         var cy:Number=-(lat2coord(lat)-mapheight/2);
214                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
215                         updateCoords(cx,cy);
216                 }
217                 
218                 private function setCentre():void {
219                         centre_lat=coord2lat(-y+mapheight/2);
220                         centre_lon=coord2lon(-x+mapwidth/2);
221                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale}));
222                 }
223
224                 // Co-ordinate conversion functions
225
226                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
227                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
228                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
229                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
230
231                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
232                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
233
234                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
235                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
236
237 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
238 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
239
240
241                 // ------------------------------------------------------------------------------------------
242                 // Resize map size based on current stage and height
243
244                 public function updateSize(w:uint, h:uint):void {
245                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
246                         
247                         mapwidth = w;
248                         mapheight= h;
249             if ( backdrop != null ) {
250                 backdrop.width=mapwidth;
251                 backdrop.height=mapheight;
252             }
253             if ( mask != null ) {
254                 mask.width=mapwidth;
255                 mask.height=mapheight;
256             }
257                 }
258
259                 // ------------------------------------------------------------------------------------------
260                 // Download map data
261                 // (typically from whichways, but will want to add more connections)
262
263                 public function download():void {
264                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
265                         
266                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
267                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
268                         bigedge_l=edge_l; bigedge_r=edge_r;
269                         bigedge_b=edge_b; bigedge_t=edge_t;
270                         addDebug("Calling download with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
271                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
272                 }
273
274
275
276         private function newWayCreated(event:EntityEvent):void {
277             var way:Way = event.entity as Way;
278                         if (!way.loaded) { return; }
279             ways[way.id] = new WayUI(way, this);
280         }
281
282         private function newPOICreated(event:EntityEvent):void {
283             var node:Node = event.entity as Node;
284             pois[node.id] = new NodeUI(node, this);
285                         pois[node.id].redraw();
286         }
287
288         public function setHighlight(entity:Entity, stateType:String, isOn:Boolean):void {
289             if ( entity is Way ) {
290                 var wayUI:WayUI = ways[entity.id];
291                 if ( wayUI != null )
292                     wayUI.setHighlight(stateType, isOn);
293             }
294         }
295
296         // Handle mouse events on ways/nodes
297         private var mapController:MapController = null;
298
299         public function setController(controller:MapController):void {
300             this.mapController = controller;
301         }
302
303         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
304             if ( mapController != null )
305                 mapController.entityMouseEvent(event, entity);
306                                 
307         }
308
309                 // ------------------------------------------------------------------------------------------
310                 // Redraw all items, zoom in and out
311                 
312                 public function redraw():void {
313                         for each (var w:WayUI in ways) { w.recalculate(); w.redraw(); }
314                         for each (var p:NodeUI in pois) { p.redraw(); }
315                 }
316
317                 public function redrawPOIs():void {
318                         for each (var p:NodeUI in pois) { p.redraw(); }
319                 }
320
321                 public function zoomIn():void {
322                         if (scale==MAXSCALE) { return; }
323                         changeScale(scale+1);
324                 }
325
326                 public function zoomOut():void {
327                         if (scale==MINSCALE) { return; }
328                         changeScale(scale-1);
329                 }
330
331                 private function changeScale(newscale:uint):void {
332                         addDebug("new scale "+newscale);
333                         scale=newscale;
334                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
335                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
336                         tileset.changeScale(scale);
337                         download();
338                         redraw();
339                 }
340
341                 private function reportPosition():void {
342                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
343                 }
344
345                 // ------------------------------------------------------------------------------------------
346                 // Export (experimental)
347                 // ** just a bit of fun for now!
348                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
349                 // to that area (will probably require creating a new DisplayObject with a different origin
350                 // and mask)
351 /*              
352                 public function export():void {
353                         addDebug("size is "+this.width+","+this.height);
354                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
355                         jpgSource.draw(this);
356                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
357                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
358                         var fileRef:FileReference = new FileReference();
359 //                      fileRef.save(jpgStream,'map.jpeg');
360                 }
361
362 */
363
364                 // ==========================================================================================
365                 // Events
366                 
367                 // ------------------------------------------------------------------------------------------
368                 // Mouse events
369                 
370                 public function mouseDownHandler(event:MouseEvent):void {
371                         dragstate=NOT_MOVED;
372                         lastxmouse=downX=mouseX;
373                         lastymouse=downY=mouseY;
374                 }
375         
376                 public function mouseUpHandler(event:MouseEvent):void {
377                         if (dragstate==DRAGGING) {
378                                 updateCoords(x,y);
379                                 download();
380                         }
381                         dragstate=NOT_DRAGGING;
382                 }
383         
384                 public function mouseMoveHandler(event:MouseEvent):void {
385                         if (dragstate==NOT_DRAGGING) {
386                                 return;
387                         }
388                         
389                         if (dragstate==NOT_MOVED && Math.abs(downX - mouseX) < 3 && Math.abs(downY - mouseY) < 3) {
390                                 return;
391                         }
392                         
393                         dragstate=DRAGGING;
394                         x+=mouseX-lastxmouse;
395                         y+=mouseY-lastymouse;
396                         lastxmouse=mouseX; lastymouse=mouseY;
397                         setCentre();
398                 }
399         
400                 // ------------------------------------------------------------------------------------------
401                 // Do every frame
402
403                 private function everyFrame(event:Event):void {
404                         if (tileset) { tileset.serviceQueue(); }
405                 }
406
407                 // ------------------------------------------------------------------------------------------
408                 // Miscellaneous events
409                 
410                 public function keyUpHandler(event:KeyboardEvent):void {
411 // addDebug("pressed "+event.keyCode);
412             if ( !event.ctrlKey ) return;
413                         if (event.keyCode==82) { this.redraw(); }                       // R - redraw
414                         if (event.keyCode==73) { this.zoomIn(); }                       // I - zoom in
415                         if (event.keyCode==79) { this.zoomOut(); }                      // O - zoom out
416                         if (event.keyCode==76) { this.reportPosition(); }       // L - report lat/long
417 //                      if (event.keyCode==69) { this.export(); }                       // E - export
418                 }
419
420                 public function connectionError(err:Object=null): void {
421                         addDebug("got error"); 
422                 }
423
424                 // ------------------------------------------------------------------------------------------
425                 // Debugging
426                 
427                 public function addDebug(text:String):void {
428                         if (!Globals.vars.hasOwnProperty('debug')) return;
429                         if (!Globals.vars.debug.visible) return;
430                         Globals.vars.debug.appendText(text+"\n");
431                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
432                 }
433                 
434         }
435 }