Add an (optional) dnd property to icon elements to override the standard image in...
[potlatch2.git] / net / systemeD / potlatch2 / mapfeatures / Feature.as
1 package net.systemeD.potlatch2.mapfeatures {
2
3     import flash.events.Event;
4     import flash.events.EventDispatcher;
5     import flash.net.*;
6     import flash.utils.ByteArray;
7     
8     import mx.core.BitmapAsset;
9     import mx.graphics.codec.PNGEncoder;
10     
11     import net.systemeD.halcyon.connection.Entity;
12     import net.systemeD.potlatch2.utils.CachedDataLoader;
13
14         /** A "map feature" is sort of a template for a map entity. It consists of a few crucial key/value pairs that define the feature, so that
15          * entities can be recognised. It also contains optional keys, with associated editing controls, that are defined as being appropriate
16          * for the feature. */
17         public class Feature extends EventDispatcher {
18         private var mapFeatures:MapFeatures;
19         private var _xml:XML;
20         private static var variablesPattern:RegExp = /[$][{]([^}]+)[}]/g;
21         private var _tags:Array;
22         private var _withins:Array;
23         private var _editors:Array;
24
25         [Embed(source="../../../../embedded/missing_icon.png")]
26         [Bindable]
27         public var missingIconCls:Class;
28
29
30         /** Create this Feature from an XML subtree. */
31         public function Feature(mapFeatures:MapFeatures, _xml:XML) {
32             this.mapFeatures = mapFeatures;
33             this._xml = _xml;
34             parseConditions();
35             parseEditors();
36         }
37
38         private function parseConditions():void {
39             _tags = [];
40            _withins = [];
41
42                         // parse tags
43             for each(var tag:XML in definition.tag) {
44                 _tags.push( { k:String(tag.@k), v:String(tag.@v), vmatch:String(tag.@vmatch)} );
45             }
46
47                         // parse 'within'
48             for each(var within:XML in definition.within) {
49                                 var obj:Object= { entity:within.@entity, k:within.@k };
50                                 if (within.attribute('v'      ).length()>0) { obj['v'      ]=within.@v;       }
51                                 if (within.attribute('minimum').length()>0) { obj['minimum']=within.@minimum; }
52                                 if (within.attribute('role'   ).length()>0) { obj['role'   ]=within.@role;    }
53                 _withins.push(obj);
54             }
55         }
56
57         private function parseEditors():void {
58             _editors = new Array();
59
60             addEditors(definition);
61
62             _editors.sortOn(["sortOrder", "name"], [Array.DESCENDING | Array.NUMERIC, Array.CASEINSENSITIVE]);
63         }
64
65         private function addEditors(xml:XML):void {
66             var inputXML:XML;
67
68             for each(var inputSetRef:XML in xml.inputSet) {
69                 var setName:String = String(inputSetRef.@ref);
70                 for each (inputXML in mapFeatures.definition.inputSet.(@id==setName)) {
71                     addEditors(inputXML);
72                 }
73             }
74
75             for each(inputXML in xml.input) {
76                 addEditor(inputXML);
77             }
78         }
79
80         private function addEditor(inputXML:XML):void {
81             var inputType:String = inputXML.@type;
82             var presenceStr:String = inputXML.@presence;
83             var sortOrderStr:String = inputXML.@priority;
84 //          _tags.push( { k:String(inputXML.@key) } ); /* add the key to tags so that e.g. addr:housenumber shows up on autocomplete */
85             var editor:EditorFactory = EditorFactory.createFactory(inputType, inputXML);
86             if ( editor != null ) {
87                 editor.presence = Presence.getPresence(presenceStr);
88                 editor.sortOrder = EditorFactory.getPriority(sortOrderStr);
89                 _editors.push(editor);
90             }
91         }
92
93         /** List of editing controls associated with this feature. */
94         public function get editors():Array {
95             return _editors;
96         }
97
98         /** The XML subtree that this feature was loaded from. */
99         public function get definition():XML {
100             return _xml;
101         }
102
103         [Bindable(event="nameChanged")]
104         /** The human-readable name of the feature (@name), or null if none. */
105         public function get name():String {
106                         if (_xml.attribute('name').length()>0) { return _xml.@name; }
107                         return null;
108         }
109
110         /** Returns the icon defined for the feature.
111         * This uses the "image" property of the feature's icon element. If no image property is defined, returns a default "missing icon".
112         */
113         [Bindable(event="imageChanged")]
114         public function get image():ByteArray {
115             return getImage();
116         }
117
118         /** Returns the drag+drop override-icon defined for the feature.
119         * This uses the "dnd" property of the feature's icon element, or if there is no override-icon it falls back to the standard image.
120         */
121         [Bindable(event="imageChanged")]
122         public function get dndimage():ByteArray {
123             return getImage(true);
124         }
125
126         /** Fetches the feature's image, as defined by the icon element in the feature definition.
127         * @param dnd if true, overrides the normal image and returns the one defined by the dnd property instead. */
128         private function getImage(dnd:Boolean = false):ByteArray {
129             var icon:XMLList = _xml.icon;
130             var imageURL:String = null;
131             var img:ByteArray;
132
133             if ( dnd && icon.length() > 0 && icon[0].hasOwnProperty("@dnd") ) {
134                 imageURL = icon[0].@dnd;
135             } else if ( icon.length() > 0 && icon[0].hasOwnProperty("@image") ) {
136                 imageURL = icon[0].@image;
137             }
138
139             if ( imageURL != null ) {
140                 img = CachedDataLoader.loadData(imageURL, imageLoaded);
141             }
142             if (img) {
143               return img;
144             }
145             var bitmap:BitmapAsset = new missingIconCls() as BitmapAsset;
146             return new PNGEncoder().encode(bitmap.bitmapData);
147         }
148         
149         /** Can this feature be drag-and-dropped from the side panel? By default, any "point" feature can,
150         *   unless it has <point draganddrop="no"/> 
151         * */
152         public function canDND():Boolean {
153                 var point:XMLList = _xml.elements("point");
154                 return point.length() > 0 && !(XML(point[0]).attribute("draganddrop")[0] == "no");
155         }
156
157         private function imageLoaded(url:String, data:ByteArray):void {
158             dispatchEvent(new Event("imageChanged"));
159         }
160
161         public function htmlDetails(entity:Entity):String {
162             var icon:XMLList = _xml.icon;
163             return makeHTMLIcon(icon, entity);
164         }
165
166         /** Convert the contents of the "icon" tag as an HTML string, with variable substitution. */
167         public static function makeHTMLIcon(icon:XMLList, entity:Entity):String {
168             if ( icon == null )
169                 return "";
170
171             var txt:String = icon.children().toXMLString();
172             var replaceTag:Function = function():String {
173                 var value:String = entity.getTag(arguments[1]);
174                 return value == null ? "" : htmlEscape(value);
175             };
176             txt = txt.replace(variablesPattern, replaceTag);
177             return txt;
178         }
179
180         /** Basic HTML escaping. */
181         public static function htmlEscape(str:String):String {
182             var newStr:String = str.replace(/&/g, "&amp;");
183             newStr = newStr.replace(/</g, "&lt;");
184             newStr = newStr.replace(/>/g, "&gt;");
185             newStr = newStr.replace(/"/g, "&quot;");    // "
186             newStr = newStr.replace(/'/g, "&apos;");    // '
187             return newStr;
188         }
189
190         /** Whether this feature belongs to the given category or not, as defined by its definition in the XML file. */
191         public function isInCategory(category:String):Boolean {
192             var cats:XMLList = _xml.category;
193             if ( cats.length() == 0 )
194                 return false;
195
196             for each( var cat:XML in cats )
197                 if ( cat.text()[0] == category )
198                     return true;
199             return false;
200         }
201
202
203         /** List of {k, v} pairs that define the feature. */
204         public function get tags():Array {
205             return _tags;
206         }
207
208         /** List of "withins" which further restrict the applicability of the feature. Each within is a {entity, k, ?v, ?minimum, ?role} object. */
209         public function get withins():Array {
210             return _withins;
211         }
212
213         /** The first category that the feature belongs to, as defined by the order of the map features XML file. */
214         public function findFirstCategory():Category {
215             for each( var cat:Category in mapFeatures.categories ) {
216                 if ( isInCategory(cat.id) )
217                     return cat;
218             }
219             return null;
220         }
221
222         /** Whether the feature is of the given type (point, line/area, relation). */
223         public function isType(type:String):Boolean {
224             if (type=='area') {
225                             return (_xml.elements(type).length() > 0) || (_xml.elements('line').length() > 0);
226             } else {
227                             return _xml.elements(type).length() > 0;
228                         }
229         }
230
231         /** Whether there is a help string defined or one can be derived from tags. */
232         public function hasHelpURL():Boolean {
233             return _xml.help.length() > 0 || _tags.length > 0;
234         }
235
236         /** The defined help string, if any. If none, generate one from tags on the feature, pointing to the OSM wiki. */
237         public function get helpURL():String {
238                 if (_xml.help.length() > 0)
239                 return _xml.help;
240             else if (_tags.length > 0) {
241                 if (_tags[0].v == "*")
242                     return "http://www.openstreetmap.org/wiki/Key:" + _tags[0].k;
243                 else
244                     return "http://www.openstreetmap.org/wiki/Tag:" + _tags[0].k + "=" + _tags[0].v;                
245             } else
246                 return "";
247
248         }
249     }
250 }
251