]> git.openstreetmap.org Git - potlatch2.git/blob - net/systemeD/halcyon/Map.as
900913 zoom support. Just needs some UI now to select a tileset!
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19
20 //      for experimental export function:
21 //      import flash.net.FileReference;
22 //      import com.adobe.images.JPGEncoder;
23
24     public class Map extends Sprite {
25
26                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
27                                                                                                                 // (for Landsat, 5120)
28                 public const MINSCALE:uint=13;                                  // don't zoom out past this
29                 public const MAXSCALE:uint=19;                                  // don't zoom in past this
30
31                 public var ruleset:RuleSet;                                             // rules
32                 
33                 public var ways:Object=new Object();                    // geodata
34                 public var nodes:Object=new Object();                   //  |
35                 public var pois:Object=new Object();                    //  |
36                 public var relations:Object=new Object();               //  |
37
38                 public var scale:uint=14;                                               // map scale
39                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
40                 public var bigedge_l:Number= 999999;                    // area of largest whichways
41                 public var bigedge_r:Number=-999999;                    //  |
42                 public var bigedge_b:Number= 999999;                    //  |
43                 public var bigedge_t:Number=-999999;                    //  |
44
45                 public var waycount:uint=0;                                             // ways:                number currently loaded
46                 public var waysrequested:uint=0;                                //                              total number requested
47                 public var waysreceived:uint=0;                                 //                              total number received
48                 public var relcount:uint=0;                                             // relations:   number currently loaded
49                 public var relsrequested:uint=0;                                //                              total number requested
50                 public var relsreceived:uint=0;                                 //                              total number received
51                 public var poicount:uint=0;                                             // POIs:                number currently loaded
52                 public var whichrequested:uint=0;                               // whichways:   total number requested
53                 public var whichreceived:uint=0;                                //                              total number received
54
55                 public var edge_l:Number;                                               // current bounding box
56                 public var edge_r:Number;                                               //  |
57                 public var edge_t:Number;                                               //  |
58                 public var edge_b:Number;                                               //  |
59
60                 public var baselon:Number;                                              // urllon-xradius/masterscale;
61                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
62                 public var mapwidth:uint;                                               // width (Flash pixels)
63                 public var mapheight:uint;                                              // height (Flash pixels)
64
65                 private var dragging:Boolean=false;                             // dragging map?
66                 private var lastxmouse:Number;                                  //  |
67                 private var lastymouse:Number;                                  //  |
68                 
69                 public var initparams:Object;                                   // object containing 
70
71                 public var backdrop:Object;                                             // reference to backdrop sprite
72                 public var tileset:TileSet;                                             // 900913 tile background
73                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
74                 
75                 public var connection:Connection;                               // server connection
76
77                 public const TILESPRITE:uint=0;
78                 public const GPSSPRITE:uint=1;
79                 public const WAYSPRITE:uint=2;
80                 public const POISPRITE:uint=13;
81                 public const NAMESPRITE:uint=14;
82
83                 // ------------------------------------------------------------------------------------------
84                 // Map constructor function
85
86         public function Map(initparams:Object) {
87
88                         // Add 900913 tile background
89                         tileset=new TileSet(this);
90                         addChild(tileset);
91                         tileset.init("http://npe.openstreetmap.org/$z/$x/$y.png");
92
93                         // Set up layering
94                         // [layer][3]                   - names
95                         // [layer][2][sublayer] - stroke
96                         // [layer][1]                   - casing
97                         // [layer][0]                   - fill
98
99                         for (var l:int=0; l<13; l++) {                          // 11 layers (11 is +5, 1 is -5)
100                                 var s:Sprite = getHitSprite();          //  |
101                                 s.addChild(getPaintSprite());                   //      | 0 fill
102                                 s.addChild(getPaintSprite());                   //      | 1 casing
103                                 var t:Sprite = getPaintSprite();                //  | 2 stroke
104                                 for (var j:int=0; j<11; j++) {                  //      |  | ten sublayers
105                                         t.addChild(getPaintSprite());           //  |  |  |
106                                 }                                                                               //  |  |  |
107                                 s.addChild(t);                                                  //  |  |
108                                 s.addChild(getPaintSprite());                   //      | 3 names
109                                 s.addChild(getPaintSprite());                   //      | 4 nodes
110                                 s.addChild(getHitSprite());                         //  | 5 entity hit tests
111                                 addChild(s);                                                    //  |
112                         }
113                         addChild(getPaintSprite());                             // 12 - POIs
114                         addChild(getPaintSprite());                             // 13 - shields and POI names
115
116                         this.initparams=initparams;
117                         connection = Connection.getConnection(initparams);
118             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
119             connection.addEventListener(Connection.NEW_POI, newPOICreated);
120                         gotEnvironment(null);
121
122                         addEventListener(Event.ENTER_FRAME, everyFrame);
123         }
124
125         private function getPaintSprite():Sprite {
126             var s:Sprite = new Sprite();
127             s.mouseEnabled = false;
128             s.mouseChildren = false;
129             return s;
130         }
131
132         private function getHitSprite():Sprite {
133             var s:Sprite = new Sprite();
134             return s;
135         }
136
137                 public function gotEnvironment(r:Object):void {
138                         var loader:Loader = new Loader();
139                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
140                         loader.load(new URLRequest("FontLibrary.swf"));
141                 }
142                 
143                 public function gotFont(r:Event):void {
144                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
145                         Font.registerFont(FontLibrary.DejaVu);
146
147                         if (initparams['lat'] != null) {
148                                 // parameters sent from HTML
149                                 init(initparams['lat'],
150                                          initparams['lon'],
151                                          initparams['zoom'],
152                                          initparams['style']);
153
154                         } else {
155                                 // somewhere innocuous
156                                 init(53.09465,-2.56495,17,"test.css?d="+Math.random());
157                         }
158                 }
159
160                 // ------------------------------------------------------------------------------------------
161                 // Initialise map at a given lat/lon
162
163         public function init(startlat:Number,startlon:Number,startscale:uint,style:String):void {
164                         ruleset=new RuleSet(this,redrawPOIs);
165                         ruleset.loadFromCSS(style);
166                         //updateSize();
167
168                         scale=startscale;
169                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
170                         baselon    =startlon          -(mapwidth /2)/scalefactor;
171                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
172                         addDebug("Baselon "+baselon+", basey "+basey);
173                         updateCoords(0,0);
174                         download();
175                         
176         }
177
178                 // ------------------------------------------------------------------------------------------
179                 // Recalculate co-ordinates from new Flash origin
180
181                 public function updateCoords(tx:Number,ty:Number):void {
182                         x=tx; y=ty;
183
184                         edge_t=coord2lat(-y          );
185                         edge_b=coord2lat(-y+mapheight);
186                         edge_l=coord2lon(-x          );
187                         edge_r=coord2lon(-x+mapwidth );
188                         addDebug("Lon "+edge_l+"-"+edge_r);
189                         addDebug("Lat "+edge_b+"-"+edge_t);
190
191                         tileset.update();
192                 }
193                 
194                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
195                         var cy:Number=-(lat2coord(lat)-mapheight/2);
196                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
197                         updateCoords(cx,cy);
198                 }
199
200
201                 // Co-ordinate conversion functions
202
203                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
204                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
205                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
206                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
207
208                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
209                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
210
211                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
212                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
213
214 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
215 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
216
217
218                 // ------------------------------------------------------------------------------------------
219                 // Resize map size based on current stage and height
220
221                 public function updateSize(w:uint, h:uint):void {
222                         mapwidth = w;
223                         mapheight= h;
224             if ( backdrop != null ) {
225                 backdrop.width=mapwidth;
226                 backdrop.height=mapheight;
227             }
228             if ( mask != null ) {
229                 mask.width=mapwidth;
230                 mask.height=mapheight;
231             }
232                 }
233
234                 // ------------------------------------------------------------------------------------------
235                 // Download map data
236                 // (typically from whichways, but will want to add more connections)
237
238                 public function download():void {
239                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD,edge_l,edge_r,edge_t,edge_b));
240                         
241                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
242                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
243                         bigedge_l=edge_l; bigedge_r=edge_r;
244                         bigedge_b=edge_b; bigedge_t=edge_t;
245                         addDebug("Calling with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
246                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
247                 }
248
249
250
251         private function newWayCreated(event:EntityEvent):void {
252             var way:Way = event.entity as Way;
253                         if (!way.loaded) { return; }
254             ways[way.id] = new WayUI(way, this);
255         }
256
257         private function newPOICreated(event:EntityEvent):void {
258             var node:Node = event.entity as Node;
259             pois[node.id] = new POI(node, this);
260         }
261
262         public function setHighlight(entity:Entity, stateType:String, isOn:Boolean):void {
263             if ( entity is Way ) {
264                 var wayUI:WayUI = ways[entity.id];
265                 if ( wayUI != null )
266                     wayUI.setHighlight(stateType, isOn);
267             }
268         }
269
270         // Handle mouse events on ways/nodes
271         private var mapController:MapController = null;
272
273         public function setController(controller:MapController):void {
274             this.mapController = controller;
275         }
276
277         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
278             if ( mapController != null )
279                 mapController.entityMouseEvent(event, entity);
280                                 
281         }
282
283                 // ------------------------------------------------------------------------------------------
284                 // Redraw all items, zoom in and out
285                 
286                 public function redraw():void {
287                         for each (var w:WayUI in ways) { w.recalculate(); w.redraw(); }
288                         for each (var p:POI in pois) { p.redraw(); }
289                 }
290
291                 public function redrawPOIs():void {
292                         for each (var p:POI in pois) { p.redraw(); }
293                 }
294
295                 public function zoomIn():void {
296                         if (scale==MAXSCALE) { return; }
297                         changeScale(scale+1);
298                 }
299
300                 public function zoomOut():void {
301                         if (scale==MINSCALE) { return; }
302                         changeScale(scale-1);
303                 }
304
305                 private function changeScale(newscale:uint):void {
306                         addDebug("new scale "+newscale);
307                         scale=newscale;
308                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
309                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
310                         tileset.changeScale(scale);
311                         download();
312                         redraw();
313                 }
314
315                 private function reportPosition():void {
316                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
317                 }
318
319                 // ------------------------------------------------------------------------------------------
320                 // Export (experimental)
321                 // ** just a bit of fun for now!
322                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
323                 // to that area (will probably require creating a new DisplayObject with a different origin
324                 // and mask)
325 /*              
326                 public function export():void {
327                         addDebug("size is "+this.width+","+this.height);
328                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
329                         jpgSource.draw(this);
330                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
331                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
332                         var fileRef:FileReference = new FileReference();
333 //                      fileRef.save(jpgStream,'map.jpeg');
334                 }
335
336 */
337
338                 // ==========================================================================================
339                 // Events
340                 
341                 // ------------------------------------------------------------------------------------------
342                 // Mouse events
343                 
344                 public function mouseDownHandler(event:MouseEvent):void {
345                         dragging=true;
346                         lastxmouse=mouseX; lastymouse=mouseY;
347                 }
348         
349                 public function mouseUpHandler(event:MouseEvent):void {
350                         if (!dragging) { return; }
351                         dragging=false;
352                         updateCoords(x,y);
353                         download();
354                 }
355         
356                 public function mouseMoveHandler(event:MouseEvent):void {
357                         if (!dragging) { return; }
358                         x+=mouseX-lastxmouse;
359                         y+=mouseY-lastymouse;
360                         lastxmouse=mouseX; lastymouse=mouseY;
361                 }
362         
363                 // ------------------------------------------------------------------------------------------
364                 // Do every frame
365
366                 private function everyFrame(event:Event):void {
367                         tileset.serviceQueue();
368                 }
369
370                 // ------------------------------------------------------------------------------------------
371                 // Miscellaneous events
372                 
373                 public function keyUpHandler(event:KeyboardEvent):void {
374 // addDebug("pressed "+event.keyCode);
375             if ( !event.ctrlKey ) return;
376                         if (event.keyCode==82) { this.redraw(); }                       // R - redraw
377                         if (event.keyCode==73) { this.zoomIn(); }                       // I - zoom in
378                         if (event.keyCode==79) { this.zoomOut(); }                      // O - zoom out
379                         if (event.keyCode==76) { this.reportPosition(); }       // L - report lat/long
380 //                      if (event.keyCode==69) { this.export(); }                       // E - export
381                 }
382
383                 public function connectionError(err:Object=null): void {
384                         addDebug("got error"); 
385                 }
386
387                 // ------------------------------------------------------------------------------------------
388                 // Debugging
389                 
390                 public function addDebug(text:String):void {
391                         if (!Globals.vars.hasOwnProperty('debug')) return;
392                         if (!Globals.vars.debug.visible) return;
393                         Globals.vars.debug.appendText(text+"\n");
394                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
395                 }
396                 
397         }
398 }