delete ways, too
[potlatch2.git] / net / systemeD / halcyon / connection / Way.as
1 package net.systemeD.halcyon.connection {
2     import flash.geom.Point;
3         import net.systemeD.halcyon.Globals;
4
5     public class Way extends Entity {
6         private var nodes:Array;
7                 public static var entity_type:String = 'way';
8
9         public function Way(id:Number, version:uint, tags:Object, loaded:Boolean, nodes:Array) {
10             super(id, version, tags, loaded);
11             this.nodes = nodes;
12                         for each (var node:Node in nodes) { node.addParent(this); }
13         }
14
15                 public function update(version:uint, tags:Object, loaded:Boolean, nodes:Array):void {
16                         var node:Node;
17                         for each (node in this.nodes) { node.removeParent(this); }
18                         updateEntityProperties(version,tags,loaded); this.nodes=nodes;
19                         for each (node in nodes) { node.addParent(this); }
20                 }
21                 
22         public function get length():uint {
23             return nodes.length;
24         }
25         
26         public function getNode(index:uint):Node {
27             return nodes[index];
28         }
29
30                 public function getLastNode():Node {
31                         return nodes[nodes.length-1];
32                 }
33
34         public function insertNode(index:uint, node:Node):void {
35                         node.addParent(this);
36             nodes.splice(index, 0, node);
37             markDirty();
38             dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_ADDED, node, this, index));
39         }
40
41         public function appendNode(node:Node):uint {
42                         node.addParent(this);
43             nodes.push(node);
44             markDirty();
45             dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_ADDED, node, this, nodes.length - 1));
46             return nodes.length;
47         }
48         
49         public function prependNode(node:Node):uint {
50                         node.addParent(this);
51             nodes.unshift(node);
52             markDirty();
53             dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_ADDED, node, this, 0));
54             return nodes.length;
55         }
56         
57         public function indexOfNode(node:Node):uint {
58             return nodes.indexOf(node);
59         }
60
61                 public function removeNode(node:Node):void {
62                         var i:int;
63                         while ((i=nodes.indexOf(node))>-1) {
64                                 nodes.splice(i,1);
65                 dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_REMOVED, node, this, i));
66                         }
67                         node.removeParent(this);
68                         markDirty();
69                 }
70
71         public function removeNodeByIndex(index:uint):void {
72             var removed:Array=nodes.splice(index, 1);
73                         if (nodes.indexOf(removed[0])==-1) { removed[0].removeParent(this); }
74                         markDirty();
75             dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_REMOVED, removed[0], this, index));
76         }
77
78                 public function sliceNodes(start:int,end:int):Array {
79                         return nodes.slice(start,end);
80                 }
81
82                 public function deleteNodesFrom(start:int):void {
83                         nodes.splice(start);
84                 }
85
86                 public function mergeWith(way:Way,topos:int,frompos:int):void {
87                         var i:int;
88
89                         // merge relations
90                         for each (var r:Relation in way.parentRelations) {
91                                 // ** needs to copy roles as well
92                                 if (r.findEntityMemberIndex(this)==-1) {
93                                         r.appendMember(new RelationMember(this, ''));
94                                 }
95                         }
96
97                         // merge tags
98                         var t:Object=way.getTagsHash();
99                         for (var k:String in t) {
100                                 if (getTag(k) && getTag(k)!=t[k]) {
101                                         setTag(k,getTag(k)+"; "+t[k]);
102                                         // ** send a warning about tags not matching
103                                 } else {
104                                         setTag(k,t[k]);
105                                 }
106                         }
107
108                         // merge nodes
109                         if (frompos==0) { for (i=0; i<way.length;    i++) { addToEnd(topos,way.getNode(i)); } }
110                                            else { for (i=way.length-1; i>=0; i--) { addToEnd(topos,way.getNode(i)); } }
111
112                         // delete way
113                         way.remove();
114                 }
115                 
116                 private function addToEnd(topos:int,node:Node):void {
117                         if (topos==0) {
118                                 if (nodes[0]==node) { return; }
119                                 prependNode(node);
120                         } else {
121                                 if (nodes[nodes.length-1]==node) { return; }
122                                 appendNode(node);
123                         }
124                 }
125
126
127
128         /**
129          * Finds the 1st way segment which intersects the projected
130          * coordinate and adds the node to that segment. If snap is
131          * specified then the node is moved to exactly bisect the
132          * segment.
133          */
134         public function insertNodeAtClosestPosition(newNode:Node, isSnap:Boolean):int {
135             var closestProportion:Number = 1;
136             var newIndex:uint = 0;
137             var nP:Point = new Point(newNode.lon, newNode.latp);
138             var snapped:Point = null;
139             
140             for ( var i:uint; i < length - 1; i++ ) {
141                 var node1:Node = getNode(i);
142                 var node2:Node = getNode(i+1);
143                 var p1:Point = new Point(node1.lon, node1.latp);
144                 var p2:Point = new Point(node2.lon, node2.latp);
145                 
146                 var directDist:Number = Point.distance(p1, p2);
147                 var viaNewDist:Number = Point.distance(p1, nP) + Point.distance(nP, p2);
148                         
149                 var proportion:Number = Math.abs(viaNewDist/directDist - 1);
150                 if ( proportion < closestProportion ) {
151                     newIndex = i+1;
152                     closestProportion = proportion;
153                     snapped = calculateSnappedPoint(p1, p2, nP);
154                 }
155             }
156             
157             // splice in new node
158             if ( isSnap ) {
159                 newNode.latp = snapped.y;
160                 newNode.lon = snapped.x;
161             }
162             insertNode(newIndex, newNode);
163             return newIndex;
164         }
165         
166         private function calculateSnappedPoint(p1:Point, p2:Point, nP:Point):Point {
167             var w:Number = p2.x - p1.x;
168             var h:Number = p2.y - p1.y;
169             var u:Number = ((nP.x-p1.x) * w + (nP.y-p1.y) * h) / (w*w + h*h);
170             return new Point(p1.x + u*w, p1.y+u*h);
171         }
172         
173         public override function toString():String {
174             return "Way("+id+"@"+version+"): "+getTagList()+
175                      " "+nodes.map(function(item:Node,index:int, arr:Array):String {return item.id.toString();}).join(",");
176         }
177
178                 public function isArea():Boolean {
179                         return (nodes[0].id==nodes[nodes.length-1].id && nodes.length>2);
180                 }
181                 
182                 public override function remove():void {
183                         var node:Node;
184                         removeFromParents();
185                         while (nodes.length) { 
186                                 node=nodes.pop();
187                                 dispatchEvent(new WayNodeEvent(Connection.WAY_NODE_REMOVED, node, this, 0));
188                                 // ** the event mechanism calls redraw once per wayNodeRemoved, which isn't too efficient
189                                 //    so we should probably add a 'redraw' flag to WayNodeEvent
190                                 node.removeParent(this);
191                                 if (!node.hasParents) { node.remove(); }
192                         }
193                         deleted=true;
194             dispatchEvent(new EntityEvent(Connection.WAY_DELETED, this));
195                 }
196
197                 internal override function isEmpty():Boolean {
198                         return (deleted || (nodes.length==0));
199                 }
200
201                 public override function getType():String {
202                         return 'way';
203                 }
204     }
205
206 }