net/systemeD/potlatch2/controller/ControllerState.as

   1 package net.systemeD.potlatch2.controller {
   2         import flash.events.*;
   3         import flash.display.*;
   4     import net.systemeD.halcyon.Map;
   5     import net.systemeD.halcyon.MapPaint;
   6     import net.systemeD.halcyon.connection.*;
   7     import net.systemeD.potlatch2.collections.Imagery;
   8     import net.systemeD.potlatch2.EditController;
   9         import net.systemeD.potlatch2.save.SaveManager;
  10         import net.systemeD.potlatch2.utils.SnapshotConnection;
  11         import flash.ui.Keyboard;
  12         import mx.controls.Alert;
  13         import mx.events.CloseEvent;
  14
  15     /** Represents a particular state of the controller, such as "dragging a way" or "nothing selected". Key methods are
  16     * processKeyboardEvent and processMouseEvent which take some action, and return a new state for the controller.
  17     *
  18     * This abstract class has some behaviour that applies in most states, and lots of 'null' behaviour.
  19     * */
  20     public class ControllerState {
  21
  22         protected var controller:EditController;
  23                 public var layer:MapPaint;
  24         protected var previousState:ControllerState;
  25
  26                 protected var _selection:Array=[];
  27
  28         public function ControllerState() {}
  29
  30         public function setController(controller:EditController):void {
  31             this.controller=controller;
  32             if (!layer) layer=controller.map.editableLayer;
  33         }
  34
  35         public function setPreviousState(previousState:ControllerState):void {
  36             if ( this.previousState == null )
  37                 this.previousState = previousState;
  38         }
  39
  40                 public function isSelectionState():Boolean {
  41                         return true;
  42                 }
  43
  44         /** When triggered by a mouse action such as a click, perform an action on the given entity, then move to a new state. */
  45         public function processMouseEvent(event:MouseEvent, entity:Entity):ControllerState {
  46             return this;
  47         }
  48
  49                 /** When triggered by a keypress, perform an action on the given entity, then move to a new state. */
  50         public function processKeyboardEvent(event:KeyboardEvent):ControllerState {
  51             return this;
  52         }
  53
  54         /** Retrieves the map associated with the current EditController */
  55                 public function get map():Map {
  56                         return controller.map;
  57                 }
  58
  59         /** This is called when the EditController sets this ControllerState as the active state.
  60         * Override this with whatever is needed, such as adding highlights to entities
  61         */
  62         public function enterState():void {}
  63
  64         /** This is called by the EditController as the current controllerstate is exiting.
  65         * Override this with whatever cleanup is needed, such as removing highlights from entities
  66         */
  67         public function exitState(newState:ControllerState):void {}
  68
  69                 /** Represent the state in text for debugging. */
  70                 public function toString():String {
  71                         return "(No state)";
  72                 }
  73                 /** Default behaviour for the current state that should be called if state-specific action has been taken care of or ruled out. */
  74                 protected function sharedKeyboardEvents(event:KeyboardEvent):ControllerState {
  75                         var editableLayer:MapPaint=controller.map.editableLayer;                                                                // shorthand for this method
  76                         switch (event.keyCode) {
  77                                 case 66:        setSourceTag(); break;                                                                                                  // B - set source tag for current object
  78                                 case 67:        editableLayer.connection.closeChangeset(); break;                                               // C - close changeset
  79                                 case 68:        editableLayer.alpha=1.3-editableLayer.alpha; return null;                               // D - dim
  80                                 case 83:        SaveManager.saveChanges(editableLayer.connection); break;                               // S - save
  81                                 case 84:        controller.tagViewer.togglePanel(); return null;                                                // T - toggle tags panel
  82                                 case 90:        if (!event.shiftKey) { MainUndoStack.getGlobalStack().undo(); return null;}// Z - undo
  83                                             else { MainUndoStack.getGlobalStack().redo(); return null;  }           // Shift-Z - redo
  84                                 case Keyboard.ESCAPE:   revertSelection(); break;                                                                       // ESC - revert to server version
  85                                 case Keyboard.NUMPAD_ADD:                                                                                                                       // + - add tag
  86                                 case 187:       controller.tagViewer.selectAdvancedPanel();                                                             //   |
  87                                                         controller.tagViewer.addNewTag(); return null;                                                  //   |
  88                         }
  89                         return null;
  90                 }
  91
  92                 /** Default behaviour for the current state that should be called if state-specific action has been taken care of or ruled out. */
  93                 protected function sharedMouseEvents(event:MouseEvent, entity:Entity):ControllerState {
  94                         var paint:MapPaint = getMapPaint(DisplayObject(event.target));
  95             var focus:Entity = getTopLevelFocusEntity(entity);
  96
  97                         if ( event.type == MouseEvent.MOUSE_UP && focus && map.dragstate!=map.NOT_DRAGGING) {
  98                                 map.mouseUpHandler();   // in case the end-drag is over an EntityUI
  99                         } else if ( event.type == MouseEvent.ROLL_OVER && paint && paint.interactive ) {
 100                                 paint.setHighlight(focus, { hover: true });
 101                         } else if ( event.type == MouseEvent.MOUSE_OUT && paint && paint.interactive ) {
 102                                 paint.setHighlight(focus, { hover: false });
 103                         } else if ( event.type == MouseEvent.MOUSE_WHEEL ) {
 104                                 if      (event.delta > 0) { map.zoomIn(); }
 105                                 else if (event.delta < 0) { map.zoomOut(); }
 106                         }
 107
 108                         if ( paint && paint.isBackground ) {
 109                                 if (event.type == MouseEvent.MOUSE_DOWN && ((event.shiftKey && event.ctrlKey) || event.altKey) ) {
 110                                         // alt-click to pull data out of vector background layer
 111                                         var newSelection:Array=[];
 112                                         if (selection.indexOf(entity)==-1) { selection=[entity]; }
 113                                         for each (var entity:Entity in selection) {
 114                                                 paint.setHighlight(entity, { hover:false, selected: false });
 115                                                 if (entity is Way) paint.setHighlightOnNodes(Way(entity), { selectedway: false });
 116                                                 newSelection.push(paint.pullThrough(entity,controller.map.editableLayer));
 117                                         }
 118                                         return controller.findStateForSelection(newSelection);
 119                                 } else if (!paint.interactive) {
 120                                         return null;
 121                                 } else if (event.type == MouseEvent.MOUSE_DOWN && paint.interactive) {
 122                                         if      (entity is Way   ) { return new SelectedWay(entity as Way, paint); }
 123                                         else if (entity is Node  ) { if (!entity.hasParentWays) return new SelectedPOINode(entity as Node, paint); }
 124                                         else if (entity is Marker) { return new SelectedMarker(entity as Marker, paint); }
 125                                 } else if ( event.type == MouseEvent.MOUSE_UP && !event.ctrlKey) {
 126                                         return (this is NoSelection) ? null : new NoSelection();
 127                                 } else if ( event.type == MouseEvent.CLICK && focus == null && map.dragstate!=map.DRAGGING && !event.ctrlKey) {
 128                                         return (this is NoSelection) ? null : new NoSelection();
 129                                 }
 130
 131                         } else if ( event.type == MouseEvent.MOUSE_DOWN ) {
 132                                 if ( entity is Node && selectedWay && entity.hasParent(selectedWay) ) {
 133                                         // select node within this way
 134                         return new DragWayNode(selectedWay,  getNodeIndex(selectedWay,entity as Node),  event, false);
 135                                 } else if ( entity is Node && focus is Way ) {
 136                                         // select way node
 137                                         return new DragWayNode(focus as Way, getNodeIndex(focus as Way,entity as Node), event, false);
 138                                 } else if ( controller.keyDown(Keyboard.SPACE) ) {
 139                                         // drag the background imagery to compensate for poor alignment
 140                                         return new DragBackground(event);
 141                                 } else if (entity && selection.indexOf(entity)>-1) {
 142                                         return new DragSelection(selection, event);
 143                                 } else if (entity) {
 144                                         return new DragSelection([entity], event);
 145                                 } else if (event.ctrlKey && !layer.isBackground) {
 146                                         return new SelectArea(event.localX,event.localY,selection);
 147                                 }
 148
 149             } else if ( (event.type==MouseEvent.CLICK || event.type==MouseEvent.MOUSE_UP) && focus == null && map.dragstate!=map.DRAGGING && !event.ctrlKey) {
 150                 return (this is NoSelection) ? null : new NoSelection();
 151             }
 152                         return null;
 153                 }
 154
 155                 /** Gets the way that the selected node is part of, if that makes sense. If not, return the node, or the way, or nothing. */
 156                 public static function getTopLevelFocusEntity(entity:Entity):Entity {
 157                         if ( entity is Node ) {
 158                                 for each (var parent:Entity in entity.parentWays) {
 159                                         return parent;
 160                                 }
 161                                 return entity;
 162                         } else if ( entity is Way ) {
 163                                 return entity;
 164                         } else {
 165                                 return null;
 166                         }
 167                 }
 168
 169                 /** Find the MapPaint object that this DisplayObject belongs to. */
 170                 protected function getMapPaint(d:DisplayObject):MapPaint {
 171                         while (d) {
 172                                 if (d is MapPaint) { return MapPaint(d); }
 173                                 d=d.parent;
 174                         }
 175                         return null;
 176                 }
 177
 178                 protected function getNodeIndex(way:Way,node:Node):uint {
 179                         for (var i:uint=0; i<way.length; i++) {
 180                                 if (way.getNode(i)==node) { return i; }
 181                         }
 182                         return null;
 183                 }
 184
 185                 /** Create a "repeat tags" action on the current entity, if possible. */
 186                 protected function repeatTags(object:Entity):void {
 187                         if (!controller.clipboards[object.getType()]) { return; }
 188                         object.suspend();
 189
 190                     var undo:CompositeUndoableAction = new CompositeUndoableAction("Repeat tags");
 191                         for (var k:String in controller.clipboards[object.getType()]) {
 192                                 object.setTag(k, controller.clipboards[object.getType()][k], undo.push)
 193                         }
 194                         MainUndoStack.getGlobalStack().addAction(undo);
 195                         controller.updateSelectionUI();
 196                         object.resume();
 197
 198
 199                 }
 200
 201                 /** Create an action to add "source=*" tag to current entity based on background imagery. This is a convenient shorthand for users. */
 202                 protected function setSourceTag():void {
 203                         if (selectCount!=1) { return; }
 204                         if (Imagery.instance().selected && Imagery.instance().selected.sourcetag) {
 205                                 if ("sourcekey" in Imagery.instance().selected)
 206                                     firstSelected.setTag(Imagery.instance().selected.sourcekey,Imagery.instance().selected.sourcetag, MainUndoStack.getGlobalStack().addAction);
 207                                 else
 208                                     firstSelected.setTag('source',Imagery.instance().selected.sourcetag, MainUndoStack.getGlobalStack().addAction);
 209                         }
 210                         controller.updateSelectionUI();
 211                 }
 212
 213                 /** Revert all selected items to previously saved state, via a dialog box. */
 214                 protected function revertSelection():void {
 215                         if (selectCount==0) return;
 216                         Alert.show("Revert selected items to the last saved version, discarding your changes?","Are you sure?",Alert.YES | Alert.CANCEL,null,revertHandler);
 217                 }
 218                 protected function revertHandler(event:CloseEvent):void {
 219                         if (event.detail==Alert.CANCEL) return;
 220                         for each (var item:Entity in _selection) {
 221                                 item.connection.loadEntity(item);
 222                         }
 223                 }
 224
 225                 // Selection getters
 226
 227                 public function get selectCount():uint {
 228                         return _selection.length;
 229                 }
 230
 231                 public function get selection():Array {
 232                         return _selection;
 233                 }
 234
 235                 public function get firstSelected():Entity {
 236                         if (_selection.length==0) { return null; }
 237                         return _selection[0];
 238                 }
 239
 240                 public function get selectedWay():Way {
 241                         if (firstSelected is Way) { return firstSelected as Way; }
 242                         return null;
 243                 }
 244
 245                 public function get selectedWays():Array {
 246                         var selectedWays:Array=[];
 247                         for each (var item:Entity in _selection) {
 248                                 if (item is Way) { selectedWays.push(item); }
 249                         }
 250                         return selectedWays;
 251                 }
 252
 253         public function get selectedNodes():Array {
 254             var selectedNodes:Array=[];
 255             for each (var item:Entity in _selection) {
 256                 if (item is Node) { selectedNodes.push(item); }
 257             }
 258             return selectedNodes;
 259         }
 260
 261                 public function hasSelectedWays():Boolean {
 262                         for each (var item:Entity in _selection) {
 263                                 if (item is Way) { return true; }
 264                         }
 265                         return false;
 266                 }
 267
 268                 public function hasSelectedAreas():Boolean {
 269                         for each (var item:Entity in _selection) {
 270                                 if (item is Way && Way(item).isArea()) { return true; }
 271                         }
 272                         return false;
 273                 }
 274
 275                 public function hasSelectedUnclosedWays():Boolean {
 276                         for each (var item:Entity in _selection) {
 277                                 if (item is Way && !Way(item).isArea()) { return true; }
 278                         }
 279                         return false;
 280                 }
 281
 282         /** Determine whether or not any nodes are selected, and if so whether any of them belong to areas. */
 283         public function hasSelectedWayNodesInAreas():Boolean {
 284             for each (var item:Entity in _selection) {
 285                 if (item is Node) {
 286                     var parentWays:Array = Node(item).parentWays;
 287                     for each (var way:Entity in parentWays) {
 288                         if (Way(way).isArea()) { return true; }
 289                     }
 290                 }
 291             }
 292             return false;
 293         }
 294
 295                 public function hasAdjoiningWays():Boolean {
 296                         if (_selection.length<2) { return false; }
 297                         var endNodes:Object={};
 298                         for each (var item:Entity in _selection) {
 299                                 if (item is Way && !Way(item).isArea()) {
 300                                         if (endNodes[Way(item).getNode(0).id]) return true;
 301                                         if (endNodes[Way(item).getLastNode().id]) return true;
 302                                         endNodes[Way(item).getNode(0).id]=true;
 303                                         endNodes[Way(item).getLastNode().id]=true;
 304                                 }
 305                         }
 306                         return false;
 307                 }
 308
 309                 // Selection setters
 310
 311                 public function set selection(items:Array):void {
 312                         _selection=items;
 313                 }
 314
 315                 public function addToSelection(items:Array):void {
 316                         for each (var item:Entity in items) {
 317                                 if (_selection.indexOf(item)==-1) { _selection.push(item); }
 318                         }
 319                 }
 320
 321                 public function removeFromSelection(items:Array):void {
 322                         for each (var item:Entity in items) {
 323                                 if (_selection.indexOf(item)>-1) {
 324                                         _selection.splice(_selection.indexOf(item),1);
 325                                 }
 326                         }
 327                 }
 328
 329                 public function toggleSelection(item:Entity):Boolean {
 330                         if (_selection.indexOf(item)==-1) {
 331                                 _selection.push(item); return true;
 332                         }
 333                         _selection.splice(_selection.indexOf(item),1); return false;
 334                 }
 335     }
 336 }