cursor-key panning, and fix "infinite drag" bug
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19         import net.systemeD.halcyon.Globals;
20
21 //      for experimental export function:
22 //      import flash.net.FileReference;
23 //      import com.adobe.images.JPGEncoder;
24
25     public class Map extends Sprite {
26
27                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
28                                                                                                                 // (for Landsat, 5120)
29                 public const MINSCALE:uint=13;                                  // don't zoom out past this
30                 public const MAXSCALE:uint=23;                                  // don't zoom in past this
31
32                 public var paint:MapPaint;                                              // sprite for ways and (POI/tagged) nodes in core layer
33                 public var vectorbg:Sprite;                                             // sprite for vector background layers
34
35                 public var scale:uint=14;                                               // map scale
36                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
37                 public var bigedge_l:Number= 999999;                    // area of largest whichways
38                 public var bigedge_r:Number=-999999;                    //  |
39                 public var bigedge_b:Number= 999999;                    //  |
40                 public var bigedge_t:Number=-999999;                    //  |
41
42                 public var edge_l:Number;                                               // current bounding box
43                 public var edge_r:Number;                                               //  |
44                 public var edge_t:Number;                                               //  |
45                 public var edge_b:Number;                                               //  |
46                 public var centre_lat:Number;                                   // centre lat/lon
47                 public var centre_lon:Number;                                   //  |
48
49                 public var baselon:Number;                                              // urllon-xradius/masterscale;
50                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
51                 public var mapwidth:uint;                                               // width (Flash pixels)
52                 public var mapheight:uint;                                              // height (Flash pixels)
53
54                 public var dragstate:uint=NOT_DRAGGING;                 // dragging map
55                 private var _draggable:Boolean=true;                    //  |
56                 private var lastxmouse:Number;                                  //  |
57                 private var lastymouse:Number;                                  //  |
58                 private var downX:Number;                                               //  |
59                 private var downY:Number;                                               //  |
60                 private var downTime:Number;                                    //  |
61                 public const NOT_DRAGGING:uint=0;                               //  |
62                 public const NOT_MOVED:uint=1;                                  //  |
63                 public const DRAGGING:uint=2;                                   //  |
64                 public const TOLERANCE:uint=7;                                  //  |
65                 
66                 public var initparams:Object;                                   // object containing HTML page parameters
67
68                 public var backdrop:Object;                                             // reference to backdrop sprite
69                 public var tileset:TileSet;                                             // 900913 tile background
70                 private var tileurl:String='';                                  // internal tile URL
71                 private var styleurl:String='';                                 // internal style URL
72                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
73                 
74                 public var connection:Connection;                               // server connection
75                 public var vectorlayers:Object={};                              // VectorLayer objects 
76
77                 public const TILESPRITE:uint=0;
78                 public const VECTORSPRITE:uint=1;
79                 public const WAYSPRITE:uint=2;
80                 public const NAMESPRITE:uint=13;
81                 
82                 // ------------------------------------------------------------------------------------------
83                 // Map constructor function
84
85         public function Map(initparams:Object) {
86
87                         this.initparams=initparams;
88                         connection = Connection.getConnection(initparams);
89             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
90             connection.addEventListener(Connection.NEW_POI, newPOICreated);
91             connection.addEventListener(Connection.WAY_RENUMBERED, wayRenumbered);
92             connection.addEventListener(Connection.NODE_RENUMBERED, nodeRenumbered);
93                         gotEnvironment(null);
94
95                         addEventListener(Event.ENTER_FRAME, everyFrame);
96         }
97
98                 public function gotEnvironment(r:Object):void {
99                         var loader:Loader = new Loader();
100                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
101                         loader.load(new URLRequest("FontLibrary.swf"));
102                 }
103                 
104                 public function gotFont(r:Event):void {
105                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
106                         Font.registerFont(FontLibrary.DejaVu);
107
108                         if (initparams['lat'] != null) {
109                                 // parameters sent from HTML
110                                 init(initparams['lat'],
111                                          initparams['lon'],
112                                          initparams['zoom']);
113
114                         } else {
115                                 // somewhere innocuous
116                                 init(53.09465,-2.56495,17);
117                         }
118                 }
119
120                 // ------------------------------------------------------------------------------------------
121                 // Initialise map at a given lat/lon
122
123         public function init(startlat:Number,startlon:Number,startscale:uint=0):void {
124                         while (numChildren) { removeChildAt(0); }
125
126                         tileset=new TileSet(this);                                      // 0 - 900913 background
127                         addChild(tileset);                                                      //   |
128                         tileset.init(tileurl);                                          //   |
129
130                         vectorbg = new Sprite();                                        // 1 - vector background layers
131                         addChild(vectorbg);                                                     //   |
132
133                         paint = new MapPaint(this,-5,5);                        // 2 - core paint object
134                         addChild(paint);                                                        //   |
135                         paint.isBackground=false;                                       //   |
136
137                         if (styleurl) {                                                         // if we've only just set up paint, then setStyle won't have created the RuleSet
138                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
139                                 paint.ruleset.loadFromCSS(styleurl);
140                         }
141                         if (startscale>0) { scale=startscale; }
142
143                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
144                         baselon    =startlon          -(mapwidth /2)/scalefactor;
145                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
146                         addDebug("Baselon "+baselon+", basey "+basey);
147                         updateCoords(0,0);
148                         download();
149                         
150         }
151
152                 // ------------------------------------------------------------------------------------------
153                 // Recalculate co-ordinates from new Flash origin
154
155                 public function updateCoords(tx:Number,ty:Number):void {
156                         x=tx; y=ty;
157
158                         edge_t=coord2lat(-y          );
159                         edge_b=coord2lat(-y+mapheight);
160                         edge_l=coord2lon(-x          );
161                         edge_r=coord2lon(-x+mapwidth );
162                         setCentre();
163
164                         tileset.update();
165                 }
166                 
167                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
168                         var cy:Number=-(lat2coord(lat)-mapheight/2);
169                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
170                         updateCoords(cx,cy);
171                 }
172                 
173                 private function setCentre():void {
174                         centre_lat=coord2lat(-y+mapheight/2);
175                         centre_lon=coord2lon(-x+mapwidth/2);
176                         this.dispatchEvent(new MapEvent(MapEvent.MOVE, {lat:centre_lat, lon:centre_lon, scale:scale}));
177                 }
178                 
179                 public function nudgeBackground(x:Number,y:Number):void {
180                         this.dispatchEvent(new MapEvent(MapEvent.NUDGE_BACKGROUND, { x: x, y: y }));
181                 }
182
183                 private function moveMap(dx:Number,dy:Number):void {
184                         updateCoords(x+dx,y+dy);
185                         updateEntityUIs(false, false);
186                         download();
187                 }
188
189                 // Co-ordinate conversion functions
190
191                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
192                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
193                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
194                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
195
196                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
197                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
198
199                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
200                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
201
202 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
203 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
204
205
206                 // ------------------------------------------------------------------------------------------
207                 // Resize map size based on current stage and height
208
209                 public function updateSize(w:uint, h:uint):void {
210                         this.dispatchEvent(new MapEvent(MapEvent.RESIZE, {width:w, height:h}));
211                         
212                         mapwidth = w;
213                         mapheight= h;
214             if ( backdrop != null ) {
215                 backdrop.width=mapwidth;
216                 backdrop.height=mapheight;
217             }
218             if ( mask != null ) {
219                 mask.width=mapwidth;
220                 mask.height=mapheight;
221             }
222                 }
223
224                 // ------------------------------------------------------------------------------------------
225                 // Download map data
226                 // (typically from whichways, but will want to add more connections)
227
228                 public function download():void {
229                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD, {minlon:edge_l, maxlon:edge_r, maxlat:edge_t, minlat:edge_b} ));
230                         
231                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
232                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
233                         bigedge_l=edge_l; bigedge_r=edge_r;
234                         bigedge_b=edge_b; bigedge_t=edge_t;
235                         if (connection.waycount>1000) {
236                                 connection.purgeOutside(edge_l,edge_r,edge_t,edge_b);
237                         }
238                         addDebug("Calling download with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
239                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
240                 }
241
242         private function newWayCreated(event:EntityEvent):void {
243             var way:Way = event.entity as Way;
244                         if (!way.loaded || !way.within(edge_l,edge_r,edge_t,edge_b)) { return; }
245                         paint.createWayUI(way);
246         }
247
248         private function newPOICreated(event:EntityEvent):void {
249             var node:Node = event.entity as Node;
250                         if (!node.within(edge_l,edge_r,edge_t,edge_b)) { return; }
251                         paint.createNodeUI(node);
252         }
253
254                 private function wayRenumbered(event:EntityRenumberedEvent):void {
255             var way:Way = event.entity as Way;
256                         paint.renumberWayUI(way,event.oldID);
257                 }
258
259                 private function nodeRenumbered(event:EntityRenumberedEvent):void {
260             var node:Node = event.entity as Node;
261                         paint.renumberNodeUI(node,event.oldID);
262                 }
263
264         public function setHighlight(entity:Entity, settings:Object):void {
265                         if      ( entity is Way  ) { paint.wayuis[entity.id].setHighlight(settings); }
266                         else if ( entity is Node ) { paint.nodeuis[entity.id].setHighlight(settings); }
267         }
268
269         public function setHighlightOnNodes(way:Way, settings:Object):void {
270                         paint.wayuis[way.id].setHighlightOnNodes(settings);
271         }
272
273                 public function setPurgable(entity:Entity, purgable:Boolean):void {
274                         if ( entity is Way  ) {
275                                 var way:Way=entity as Way;
276                                 paint.wayuis[way.id].purgable=purgable;
277                                 for (var i:uint=0; i<way.length; i++) {
278                                         if (paint.nodeuis[way.getNode(i).id]) {
279                                                 paint.nodeuis[way.getNode(i).id].purgable=purgable;
280                                         }
281                                 }
282                         } else if ( entity is Node ) { 
283                                 paint.nodeuis[entity.id].purgable=purgable;
284                         }
285                 }
286
287         // Handle mouse events on ways/nodes
288         private var mapController:MapController = null;
289
290         public function setController(controller:MapController):void {
291             this.mapController = controller;
292         }
293
294         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
295             if ( mapController != null )
296                 mapController.entityMouseEvent(event, entity);
297                                 
298         }
299
300                 // ------------------------------------------------------------------------------------------
301                 // Add vector layer
302                 
303                 public function addVectorLayer(layer:VectorLayer):void {
304                         vectorlayers[layer.name]=layer;
305                         vectorbg.addChild(layer.paint);
306                 }
307
308                 // ------------------------------------------------------------------------------------------
309                 // Redraw all items, zoom in and out
310                 
311                 public function updateEntityUIs(redraw:Boolean,remove:Boolean):void {
312                         paint.updateEntityUIs(connection.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
313                         for each (var v:VectorLayer in vectorlayers) {
314                                 v.paint.updateEntityUIs(v.getObjectsByBbox(edge_l, edge_r, edge_t, edge_b), redraw, remove);
315                         }
316                 }
317                 public function redraw():void {
318                         paint.redraw();
319                         for each (var v:VectorLayer in vectorlayers) { v.paint.redraw(); }
320                 }
321                 public function redrawPOIs():void { 
322                         paint.redrawPOIs();
323                         for each (var v:VectorLayer in vectorlayers) { v.paint.redrawPOIs(); }
324                 }
325                 
326                 public function zoomIn():void {
327                         if (scale==MAXSCALE) { return; }
328                         changeScale(scale+1);
329                 }
330
331                 public function zoomOut():void {
332                         if (scale==MINSCALE) { return; }
333                         changeScale(scale-1);
334                 }
335
336                 private function changeScale(newscale:uint):void {
337                         addDebug("new scale "+newscale);
338                         scale=newscale;
339                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
340                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
341                         tileset.changeScale(scale);
342                         updateEntityUIs(true,true);
343                         download();
344                 }
345
346                 private function reportPosition():void {
347                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
348                 }
349                 
350                 public function setStyle(url:String):void {
351                         styleurl=url;
352                         if (paint) { 
353                                 paint.ruleset=new RuleSet(MINSCALE,MAXSCALE,redraw,redrawPOIs);
354                                 paint.ruleset.loadFromCSS(url);
355                         }
356         }
357
358                 public function setBackground(url:String):void {
359                         tileurl=url;
360                         if (tileset) { tileset.init(url, url!=''); }
361                 }
362
363                 public function setDimming(dim:Boolean):void {
364                         if (tileset) { tileset.setDimming(dim); }
365                 }
366
367                 // ------------------------------------------------------------------------------------------
368                 // Export (experimental)
369                 // ** just a bit of fun for now!
370                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
371                 // to that area (will probably require creating a new DisplayObject with a different origin
372                 // and mask)
373 /*              
374                 public function export():void {
375                         addDebug("size is "+this.width+","+this.height);
376                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
377                         jpgSource.draw(this);
378                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
379                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
380                         var fileRef:FileReference = new FileReference();
381 //                      fileRef.save(jpgStream,'map.jpeg');
382                 }
383
384 */
385
386                 // ==========================================================================================
387                 // Events
388                 
389                 // ------------------------------------------------------------------------------------------
390                 // Mouse events
391                 
392                 public function set draggable(draggable:Boolean):void {
393                         _draggable=draggable;
394                         dragstate=NOT_DRAGGING;
395                 }
396
397                 public function mouseDownHandler(event:MouseEvent):void {
398                         if (!_draggable) { return; }
399                         dragstate=NOT_MOVED;
400                         lastxmouse=mouseX; downX=stage.mouseX;
401                         lastymouse=mouseY; downY=stage.mouseY;
402                         downTime=new Date().getTime();
403                 }
404         
405                 public function mouseUpHandler(event:MouseEvent=null):void {
406                         if (dragstate==DRAGGING) { moveMap(0,0); }
407                         dragstate=NOT_DRAGGING;
408                 }
409         
410                 public function mouseMoveHandler(event:MouseEvent):void {
411                         if (!_draggable) { return; }
412                         if (dragstate==NOT_DRAGGING) { return; }
413                         
414                         if (dragstate==NOT_MOVED) {
415                                 if (new Date().getTime()-downTime<300) {
416                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE   && Math.abs(downY-stage.mouseY)<=TOLERANCE  ) return;
417                                 } else {
418                                         if (Math.abs(downX-stage.mouseX)<=TOLERANCE/2 && Math.abs(downY-stage.mouseY)<=TOLERANCE/2) return;
419                                 }
420                                 dragstate=DRAGGING;
421                         }
422                         
423                         x+=mouseX-lastxmouse;
424                         y+=mouseY-lastymouse;
425                         lastxmouse=mouseX; lastymouse=mouseY;
426                         setCentre();
427                 }
428         
429                 // ------------------------------------------------------------------------------------------
430                 // Do every frame
431
432                 private function everyFrame(event:Event):void {
433                         if (tileset) { tileset.serviceQueue(); }
434                 }
435
436                 // ------------------------------------------------------------------------------------------
437                 // Miscellaneous events
438                 
439                 public function keyUpHandler(event:KeyboardEvent):void {
440                         addDebug("pressed "+event.keyCode);
441                         switch (event.keyCode) {
442                                 case 33:        zoomIn(); break;                                        // Page Up - zoom in
443                                 case 34:        zoomOut(); break;                                       // Page Down - zoom out
444                                 case 37:        moveMap(mapwidth/2,0); break;           // left cursor
445                                 case 38:        moveMap(0,mapheight/2); break;          // up cursor
446                                 case 39:        moveMap(-mapwidth/2,0); break;          // right cursor
447                                 case 40:        moveMap(0,-mapheight/2); break;         // down cursor
448 //                              case 76:        reportPosition(); break;                        // L - report lat/long
449                         }
450                 }
451
452                 public function connectionError(err:Object=null): void {
453                         addDebug("got error"); 
454                 }
455
456                 // ------------------------------------------------------------------------------------------
457                 // Debugging
458                 
459                 public function clearDebug():void {
460                         if (!Globals.vars.hasOwnProperty('debug')) return;
461                         Globals.vars.debug.text='';
462                 }
463                         
464                 public function addDebug(text:String):void {
465                         if (!Globals.vars.hasOwnProperty('debug')) return;
466                         if (!Globals.vars.debug.visible) return;
467                         Globals.vars.debug.appendText(text+"\n");
468                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
469                 }
470
471         }
472 }