add more ways to control the viewer from JavaScript
[potlatch2.git] / net / systemeD / halcyon / Map.as
1 package net.systemeD.halcyon {
2
3         import flash.text.TextField;
4         import flash.display.DisplayObjectContainer;
5         import flash.display.Loader;
6         import flash.display.Sprite;
7         import flash.display.Shape;
8         import flash.display.Stage;
9         import flash.display.BitmapData;
10         import flash.display.LoaderInfo;
11         import flash.text.Font;
12         import flash.utils.ByteArray;
13         import flash.events.*;
14         import flash.net.*;
15
16     import net.systemeD.halcyon.connection.*;
17     import net.systemeD.halcyon.connection.EntityEvent;
18         import net.systemeD.halcyon.styleparser.*;
19
20 //      for experimental export function:
21 //      import flash.net.FileReference;
22 //      import com.adobe.images.JPGEncoder;
23
24     public class Map extends Sprite {
25
26                 public const MASTERSCALE:Number=5825.4222222222;// master map scale - how many Flash pixels in 1 degree longitude
27                                                                                                                 // (for Landsat, 5120)
28                 public const MINSCALE:uint=13;                                  // don't zoom out past this
29                 public const MAXSCALE:uint=19;                                  // don't zoom in past this
30
31                 public var ruleset:RuleSet;                                             // rules
32                 
33                 public var ways:Object=new Object();                    // geodata
34                 public var nodes:Object=new Object();                   //  |
35                 public var pois:Object=new Object();                    //  |
36                 public var relations:Object=new Object();               //  |
37
38                 public var scale:uint=14;                                               // map scale
39                 public var scalefactor:Number=MASTERSCALE;              // current scaling factor for lon/latp
40                 public var bigedge_l:Number= 999999;                    // area of largest whichways
41                 public var bigedge_r:Number=-999999;                    //  |
42                 public var bigedge_b:Number= 999999;                    //  |
43                 public var bigedge_t:Number=-999999;                    //  |
44
45                 public var waycount:uint=0;                                             // ways:                number currently loaded
46                 public var waysrequested:uint=0;                                //                              total number requested
47                 public var waysreceived:uint=0;                                 //                              total number received
48                 public var relcount:uint=0;                                             // relations:   number currently loaded
49                 public var relsrequested:uint=0;                                //                              total number requested
50                 public var relsreceived:uint=0;                                 //                              total number received
51                 public var poicount:uint=0;                                             // POIs:                number currently loaded
52                 public var whichrequested:uint=0;                               // whichways:   total number requested
53                 public var whichreceived:uint=0;                                //                              total number received
54
55                 public var edge_l:Number;                                               // current bounding box
56                 public var edge_r:Number;                                               //  |
57                 public var edge_t:Number;                                               //  |
58                 public var edge_b:Number;                                               //  |
59
60                 public var baselon:Number;                                              // urllon-xradius/masterscale;
61                 public var basey:Number;                                                // lat2lat2p(urllat)+yradius/masterscale;
62                 public var mapwidth:uint;                                               // width (Flash pixels)
63                 public var mapheight:uint;                                              // height (Flash pixels)
64
65                 private var dragging:Boolean=false;                             // dragging map?
66                 private var lastxmouse:Number;                                  //  |
67                 private var lastymouse:Number;                                  //  |
68                 
69                 public var initparams:Object;                                   // object containing 
70
71                 public var backdrop:Object;                                             // reference to backdrop sprite
72                 public var tileset:TileSet;                                             // 900913 tile background
73                 public var showall:Boolean=true;                                // show all objects, even if unstyled?
74                 
75                 public var connection:Connection;                               // server connection
76
77                 public const TILESPRITE:uint=0;
78                 public const GPSSPRITE:uint=1;
79                 public const WAYSPRITE:uint=2;
80                 public const POISPRITE:uint=13;
81                 public const NAMESPRITE:uint=14;
82
83                 // ------------------------------------------------------------------------------------------
84                 // Map constructor function
85
86         public function Map(initparams:Object) {
87                         this.initparams=initparams;
88                         connection = Connection.getConnection(initparams);
89             connection.addEventListener(Connection.NEW_WAY, newWayCreated);
90             connection.addEventListener(Connection.NEW_POI, newPOICreated);
91                         gotEnvironment(null);
92
93                         addEventListener(Event.ENTER_FRAME, everyFrame);
94         }
95
96                 // Set up layering
97                 // [layer][3]                   - names
98                 // [layer][2][sublayer] - stroke
99                 // [layer][1]                   - casing
100                 // [layer][0]                   - fill
101
102                 private function createSprites():void {
103                         tileset=new TileSet(this);                                      // 900913 background
104                         addChild(tileset);                                                      //  |
105                         addChild(new Sprite());                                         // GPS
106
107                         for (var l:int=0; l<13; l++) {                          // 11 layers (11 is +5, 1 is -5)
108                                 var s:Sprite = getHitSprite();          //  |
109                                 s.addChild(getPaintSprite());                   //      | 0 fill
110                                 s.addChild(getPaintSprite());                   //      | 1 casing
111                                 var t:Sprite = getPaintSprite();                //  | 2 stroke
112                                 for (var j:int=0; j<11; j++) {                  //      |  | ten sublayers
113                                         t.addChild(getPaintSprite());           //  |  |  |
114                                 }                                                                               //  |  |  |
115                                 s.addChild(t);                                                  //  |  |
116                                 s.addChild(getPaintSprite());                   //      | 3 names
117                                 s.addChild(getPaintSprite());                   //      | 4 nodes
118                                 s.addChild(getHitSprite());                         //  | 5 entity hit tests
119                                 addChild(s);                                                    //  |
120                         }
121                         addChild(getPaintSprite());                             // 12 - POIs
122                         addChild(getPaintSprite());                             // 13 - shields and POI names
123                 }
124                 
125                 private function removeSprites():void {
126                         while (numChildren) { removeChildAt(0); }
127                 }
128
129         private function getPaintSprite():Sprite {
130             var s:Sprite = new Sprite();
131             s.mouseEnabled = false;
132             s.mouseChildren = false;
133             return s;
134         }
135
136         private function getHitSprite():Sprite {
137             var s:Sprite = new Sprite();
138             return s;
139         }
140
141                 public function gotEnvironment(r:Object):void {
142                         var loader:Loader = new Loader();
143                         loader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotFont);
144                         loader.load(new URLRequest("FontLibrary.swf"));
145                 }
146                 
147                 public function gotFont(r:Event):void {
148                         var FontLibrary:Class = r.target.applicationDomain.getDefinition("FontLibrary") as Class;
149                         Font.registerFont(FontLibrary.DejaVu);
150
151                         if (initparams['lat'] != null) {
152                                 // parameters sent from HTML
153                                 init(initparams['lat'],
154                                          initparams['lon'],
155                                          initparams['zoom'],
156                                          initparams['style'],
157                                          initparams['tileurl']);
158
159                         } else {
160                                 // somewhere innocuous
161                                 init(53.09465,-2.56495,17,"test.css?d="+Math.random(),"");
162                         }
163                 }
164
165                 // ------------------------------------------------------------------------------------------
166                 // Initialise map at a given lat/lon
167
168         public function init(startlat:Number,startlon:Number,startscale:uint=0,style:String=null,tileurl:String=''):void {
169                         removeSprites();
170                         createSprites();
171                         tileset.init(tileurl);
172
173                         if (style) {
174                                 ruleset=new RuleSet(this,redrawPOIs);
175                                 ruleset.loadFromCSS(style);
176                         }
177                         if (startscale>0) { scale=startscale; }
178
179                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
180                         baselon    =startlon          -(mapwidth /2)/scalefactor;
181                         basey      =lat2latp(startlat)+(mapheight/2)/scalefactor;
182                         addDebug("Baselon "+baselon+", basey "+basey);
183                         updateCoords(0,0);
184                         download();
185                         
186         }
187
188                 // ------------------------------------------------------------------------------------------
189                 // Recalculate co-ordinates from new Flash origin
190
191                 public function updateCoords(tx:Number,ty:Number):void {
192                         x=tx; y=ty;
193
194                         edge_t=coord2lat(-y          );
195                         edge_b=coord2lat(-y+mapheight);
196                         edge_l=coord2lon(-x          );
197                         edge_r=coord2lon(-x+mapwidth );
198                         addDebug("Lon "+edge_l+"-"+edge_r);
199                         addDebug("Lat "+edge_b+"-"+edge_t);
200
201                         tileset.update();
202                 }
203                 
204                 public function updateCoordsFromLatLon(lat:Number,lon:Number):void {
205                         var cy:Number=-(lat2coord(lat)-mapheight/2);
206                         var cx:Number=-(lon2coord(lon)-mapwidth/2);
207                         updateCoords(cx,cy);
208                 }
209
210
211                 // Co-ordinate conversion functions
212
213                 public function latp2coord(a:Number):Number     { return -(a-basey)*scalefactor; }
214                 public function coord2latp(a:Number):Number     { return a/-scalefactor+basey; }
215                 public function lon2coord(a:Number):Number      { return (a-baselon)*scalefactor; }
216                 public function coord2lon(a:Number):Number      { return a/scalefactor+baselon; }
217
218                 public function latp2lat(a:Number):Number       { return 180/Math.PI * (2 * Math.atan(Math.exp(a*Math.PI/180)) - Math.PI/2); }
219                 public function lat2latp(a:Number):Number       { return 180/Math.PI * Math.log(Math.tan(Math.PI/4+a*(Math.PI/180)/2)); }
220
221                 public function lat2coord(a:Number):Number      { return -(lat2latp(a)-basey)*scalefactor; }
222                 public function coord2lat(a:Number):Number      { return latp2lat(a/-scalefactor+basey); }
223
224 //              public function centrelat(o) { return coord2lat((yradius-_root.map._y-o)/Math.pow(2,_root.scale-13)); }
225 //              public function centrelon(o) { return coord2lon((xradius-_root.map._x-o)/Math.pow(2,_root.scale-13)); }
226
227
228                 // ------------------------------------------------------------------------------------------
229                 // Resize map size based on current stage and height
230
231                 public function updateSize(w:uint, h:uint):void {
232                         mapwidth = w;
233                         mapheight= h;
234             if ( backdrop != null ) {
235                 backdrop.width=mapwidth;
236                 backdrop.height=mapheight;
237             }
238             if ( mask != null ) {
239                 mask.width=mapwidth;
240                 mask.height=mapheight;
241             }
242                 }
243
244                 // ------------------------------------------------------------------------------------------
245                 // Download map data
246                 // (typically from whichways, but will want to add more connections)
247
248                 public function download():void {
249                         this.dispatchEvent(new MapEvent(MapEvent.DOWNLOAD,edge_l,edge_r,edge_t,edge_b));
250                         
251                         if (edge_l>=bigedge_l && edge_r<=bigedge_r &&
252                                 edge_b>=bigedge_b && edge_t<=bigedge_t) { return; }     // we have already loaded this area, so ignore
253                         bigedge_l=edge_l; bigedge_r=edge_r;
254                         bigedge_b=edge_b; bigedge_t=edge_t;
255                         addDebug("Calling with "+edge_l+"-"+edge_r+", "+edge_t+"-"+edge_b);
256                         connection.loadBbox(edge_l,edge_r,edge_t,edge_b);
257                 }
258
259
260
261         private function newWayCreated(event:EntityEvent):void {
262             var way:Way = event.entity as Way;
263                         if (!way.loaded) { return; }
264             ways[way.id] = new WayUI(way, this);
265         }
266
267         private function newPOICreated(event:EntityEvent):void {
268             var node:Node = event.entity as Node;
269             pois[node.id] = new POI(node, this);
270         }
271
272         public function setHighlight(entity:Entity, stateType:String, isOn:Boolean):void {
273             if ( entity is Way ) {
274                 var wayUI:WayUI = ways[entity.id];
275                 if ( wayUI != null )
276                     wayUI.setHighlight(stateType, isOn);
277             }
278         }
279
280         // Handle mouse events on ways/nodes
281         private var mapController:MapController = null;
282
283         public function setController(controller:MapController):void {
284             this.mapController = controller;
285         }
286
287         public function entityMouseEvent(event:MouseEvent, entity:Entity):void {
288             if ( mapController != null )
289                 mapController.entityMouseEvent(event, entity);
290                                 
291         }
292
293                 // ------------------------------------------------------------------------------------------
294                 // Redraw all items, zoom in and out
295                 
296                 public function redraw():void {
297                         for each (var w:WayUI in ways) { w.recalculate(); w.redraw(); }
298                         for each (var p:POI in pois) { p.redraw(); }
299                 }
300
301                 public function redrawPOIs():void {
302                         for each (var p:POI in pois) { p.redraw(); }
303                 }
304
305                 public function zoomIn():void {
306                         if (scale==MAXSCALE) { return; }
307                         changeScale(scale+1);
308                 }
309
310                 public function zoomOut():void {
311                         if (scale==MINSCALE) { return; }
312                         changeScale(scale-1);
313                 }
314
315                 private function changeScale(newscale:uint):void {
316                         addDebug("new scale "+newscale);
317                         scale=newscale;
318                         scalefactor=MASTERSCALE/Math.pow(2,13-scale);
319                         updateCoordsFromLatLon((edge_t+edge_b)/2,(edge_l+edge_r)/2);    // recentre
320                         tileset.changeScale(scale);
321                         download();
322                         redraw();
323                 }
324
325                 private function reportPosition():void {
326                         addDebug("lon "+coord2lon(mouseX)+", lat "+coord2lat(mouseY));
327                 }
328
329                 // ------------------------------------------------------------------------------------------
330                 // Export (experimental)
331                 // ** just a bit of fun for now!
332                 // really needs to take a bbox, and make sure that the image is correctly cropped/resized 
333                 // to that area (will probably require creating a new DisplayObject with a different origin
334                 // and mask)
335 /*              
336                 public function export():void {
337                         addDebug("size is "+this.width+","+this.height);
338                         var jpgSource:BitmapData = new BitmapData(800,800); // (this.width, this.height);
339                         jpgSource.draw(this);
340                         var jpgEncoder:JPGEncoder = new JPGEncoder(85);
341                         var jpgStream:ByteArray = jpgEncoder.encode(jpgSource);
342                         var fileRef:FileReference = new FileReference();
343 //                      fileRef.save(jpgStream,'map.jpeg');
344                 }
345
346 */
347
348                 // ==========================================================================================
349                 // Events
350                 
351                 // ------------------------------------------------------------------------------------------
352                 // Mouse events
353                 
354                 public function mouseDownHandler(event:MouseEvent):void {
355                         dragging=true;
356                         lastxmouse=mouseX; lastymouse=mouseY;
357                 }
358         
359                 public function mouseUpHandler(event:MouseEvent):void {
360                         if (!dragging) { return; }
361                         dragging=false;
362                         updateCoords(x,y);
363                         download();
364                 }
365         
366                 public function mouseMoveHandler(event:MouseEvent):void {
367                         if (!dragging) { return; }
368                         x+=mouseX-lastxmouse;
369                         y+=mouseY-lastymouse;
370                         lastxmouse=mouseX; lastymouse=mouseY;
371                 }
372         
373                 // ------------------------------------------------------------------------------------------
374                 // Do every frame
375
376                 private function everyFrame(event:Event):void {
377                         if (tileset) { tileset.serviceQueue(); }
378                 }
379
380                 // ------------------------------------------------------------------------------------------
381                 // Miscellaneous events
382                 
383                 public function keyUpHandler(event:KeyboardEvent):void {
384 // addDebug("pressed "+event.keyCode);
385             if ( !event.ctrlKey ) return;
386                         if (event.keyCode==82) { this.redraw(); }                       // R - redraw
387                         if (event.keyCode==73) { this.zoomIn(); }                       // I - zoom in
388                         if (event.keyCode==79) { this.zoomOut(); }                      // O - zoom out
389                         if (event.keyCode==76) { this.reportPosition(); }       // L - report lat/long
390 //                      if (event.keyCode==69) { this.export(); }                       // E - export
391                 }
392
393                 public function connectionError(err:Object=null): void {
394                         addDebug("got error"); 
395                 }
396
397                 // ------------------------------------------------------------------------------------------
398                 // Debugging
399                 
400                 public function addDebug(text:String):void {
401                         if (!Globals.vars.hasOwnProperty('debug')) return;
402                         if (!Globals.vars.debug.visible) return;
403                         Globals.vars.debug.appendText(text+"\n");
404                         Globals.vars.debug.scrollV=Globals.vars.debug.maxScrollV;
405                 }
406                 
407         }
408 }