d269b0b607132b547c7065813b5f9f932fa0cd98
[potlatch2.git] / net / systemeD / potlatch2 / controller / DrawWay.as
1 package net.systemeD.potlatch2.controller {
2         import flash.events.*;
3         import flash.geom.*;
4         import flash.display.DisplayObject;
5         import flash.ui.Keyboard;
6         import net.systemeD.potlatch2.EditController;
7         import net.systemeD.halcyon.connection.*;
8     import net.systemeD.halcyon.connection.actions.*;
9         import net.systemeD.halcyon.Elastic;
10         import net.systemeD.halcyon.MapPaint;
11
12         public class DrawWay extends SelectedWay {
13                 private var elastic:Elastic;
14                 private var editEnd:Boolean;            // if true, we're drawing from node[n-1], else "backwards" from node[0] 
15                 private var leaveNodeSelected:Boolean;
16                 private var lastClick:Entity=null;
17                 private var lastClickTime:Date;
18                 private var hoverEntity:Entity;                 // keep track of the currently rolled-over object, because
19                                                                                                 // Flash can fire a mouseDown from the map even if you
20                                                                                                 // haven't rolled out of the way
21                 
22                 public function DrawWay(way:Way, editEnd:Boolean, leaveNodeSelected:Boolean) {
23                         super(way);
24                         this.editEnd = editEnd;
25                         this.leaveNodeSelected = leaveNodeSelected;
26                         if (way.length==1) {
27                                 // drawing new way, so keep track of click in case creating a POI
28                                 lastClick=way.getNode(0);
29                                 lastClickTime=new Date();
30                         }
31                 }
32                 
33                 override public function processMouseEvent(event:MouseEvent, entity:Entity):ControllerState {
34                         if (firstSelected.deleted) return new NoSelection();    // in case user has clicked Undo
35
36                         var mouse:Point;
37                         var node:Node;
38                         var paint:MapPaint = getMapPaint(DisplayObject(event.target));
39                         var isBackground:Boolean = paint && paint.isBackground;
40
41                         if (entity == null && hoverEntity) { entity=hoverEntity; }
42                         var focus:Entity = getTopLevelFocusEntity(entity);
43
44                         if ( event.type == MouseEvent.MOUSE_UP ) {
45                 controller.map.mouseUpHandler(); // in case you're still in the drag-tolerance zone, and mouse up over something.
46                                 if ( entity == null || isBackground ) { // didn't hit anything: extend the way by one node.
47                                         node = createAndAddNode(event, MainUndoStack.getGlobalStack().addAction);
48                     layer.setHighlight(node, { selectedway: true });
49                     layer.setPurgable([node], false);
50                                         resetElastic(node);
51                                         lastClick=node;
52                                         controller.updateSelectionUIWithoutTagChange();
53                                 } else if ( entity is Node ) {
54                                         if (entity==lastClick && (new Date().getTime()-lastClickTime.getTime())<1000) {
55                                                 if (Way(firstSelected).length==1 && Way(firstSelected).getNode(0).parentWays.length==1) {
56                                                         // Actually the user double-clicked to make a new node, they didn't want to draw a way at all.
57                             stopDrawing();
58                             MainUndoStack.getGlobalStack().undo(); // undo the BeginWayAction that (presumably?) just happened
59                             
60                             var newPoiAction:CreatePOIAction = new CreatePOIAction(
61                                                                 layer.connection,
62                                                                 {},
63                                                                 controller.map.coord2lat(event.localY),
64                                                                 controller.map.coord2lon(event.localX));
65                             MainUndoStack.getGlobalStack().addAction(newPoiAction);
66                             return new SelectedPOINode(newPoiAction.getNode());
67                         } else if (Way(firstSelected).length==1) {
68                             // It's not a poi, but they've double-clicked or clicked-twice the first node - do nothing
69                             return this;
70                                                 } else {
71                                                         // double-click at end of way
72                                                         return stopDrawing();
73                                                 }
74                     } else if (entity==lastClick) {
75                         // clicked slowly on the end node - do nothing
76                         return this;
77                                         } else {
78                                                 // hit a node, add it to this way and carry on
79                                                 appendNode(entity as Node, MainUndoStack.getGlobalStack().addAction);
80                                                 if (focus is Way) {
81                           layer.setHighlightOnNodes(focus as Way, { hoverway: false });
82                         }
83                                                 layer.setHighlight(entity, { selectedway: true });
84                                                 resetElastic(entity as Node);
85                                                 lastClick=entity;
86                                                 if (Way(firstSelected).getNode(0)==Way(firstSelected).getLastNode()) {
87                                                         // the node just hit completes a loop, so stop drawing.
88                                                         return new SelectedWay(firstSelected as Way);
89                                                 }
90                                         }
91                                 } else if ( entity is Way ) {
92                                         if (entity==firstSelected) {
93                                                 // add junction node - self-intersecting way
94                                     var lat:Number = controller.map.coord2lat(event.localY);
95                                     var lon:Number = controller.map.coord2lon(event.localX);
96                                     var undo:CompositeUndoableAction = new CompositeUndoableAction("Insert node");
97                                     node = firstSelected.connection.createNode({}, lat, lon, undo.push);
98                                     Way(firstSelected).insertNodeAtClosestPosition(node, true, undo.push);
99                                                 appendNode(node,undo.push);
100                                     MainUndoStack.getGlobalStack().addAction(undo);
101                                         } else {
102                         // add junction node - another way
103                         var jnct:CompositeUndoableAction = new CompositeUndoableAction("Junction Node");
104                         var ways:Array = layer.findWaysAtPoint(event.stageX, event.stageY, selectedWay);
105                         node = createAndAddNode(event, jnct.push);
106                         for each (var w:Way in ways) { w.insertNodeAtClosestPosition(node, true, jnct.push); }
107                         MainUndoStack.getGlobalStack().addAction(jnct);
108                         layer.setHighlight(node, { selectedway: true });
109                         layer.setPurgable([node], false);
110                                         }
111                                         resetElastic(node);
112                                         lastClick=node;
113                                         layer.setHighlightOnNodes(entity as Way, { hoverway: false });
114                                         layer.setHighlightOnNodes(firstSelected as Way, { selectedway: true });
115                                 }
116                                 lastClickTime=new Date();
117                         } else if ( event.type == MouseEvent.MOUSE_MOVE && elastic ) {
118                                 // mouse is roaming around freely
119                                 mouse = new Point(
120                                                   controller.map.coord2lon(event.localX),
121                                                   controller.map.coord2latp(event.localY));
122                                 elastic.end = mouse;
123                         } else if ( event.type == MouseEvent.ROLL_OVER && !isBackground ) {
124                                 // mouse has floated over something
125                                 if (focus is Way && focus!=firstSelected) {
126                                         // floating over another way, highlight its nodes
127                                         hoverEntity=focus;
128                                         layer.setHighlightOnNodes(focus as Way, { hoverway: true });
129                                 }
130                                 // set cursor depending on whether we're floating over the start of this way, 
131                                 // another random node, a possible junction...
132                                 if (entity is Node && focus is Way && Way(focus).endsWith(Node(entity))) {
133                                         if (focus==firstSelected) { controller.setCursor(controller.pen_so); }
134                                                              else { controller.setCursor(controller.pen_o); }
135                                 } else if (entity is Node) {
136                                         controller.setCursor(controller.pen_x);
137                                 } else {
138                                         controller.setCursor(controller.pen_plus);
139                                 }
140                         } else if ( event.type == MouseEvent.MOUSE_OUT && !isBackground ) {
141                                 if (focus is Way && entity!=firstSelected) {
142                                         hoverEntity=null;
143                                         layer.setHighlightOnNodes(focus as Way, { hoverway: false });
144                                         // ** We could do with an optional way of calling WayUI.redraw to only do the nodes, which would be a
145                                         // useful optimisation.
146                                 }
147                                 controller.setCursor(controller.pen);
148                         }
149
150                         return this;
151                 }
152                 
153                 protected function resetElastic(node:Node):void {
154                         elastic.start = new Point(node.lon, node.latp);
155                         elastic.end   = new Point(controller.map.coord2lon(controller.map.mouseX),
156                                                   controller.map.coord2latp(controller.map.mouseY));
157                 }
158
159         /* Fix up the elastic after a WayNode event - e.g. triggered by undo */
160         private function fixElastic(event:Event):void {
161             if (firstSelected == null) return;
162             var node:Node;
163             if (editEnd) {
164               node = Way(firstSelected).getLastNode();
165             } else {
166               node = Way(firstSelected).getNode(0);
167             }
168             if (node) { //maybe selectedWay doesn't have any nodes left
169               elastic.start = new Point(node.lon, node.latp);
170             }
171         }
172
173                 override public function processKeyboardEvent(event:KeyboardEvent):ControllerState {
174                         switch (event.keyCode) {
175                                 case Keyboard.ENTER:                                    return keyExitDrawing();
176                                 case Keyboard.ESCAPE:                                   return keyExitDrawing();
177                                 case Keyboard.DELETE:           
178                                 case Keyboard.BACKSPACE:        
179                                 case 189: /* minus */       return backspaceNode(MainUndoStack.getGlobalStack().addAction);
180                                 case 79: /* O */                        return new SelectedWayNode(firstSelected as Way, editEnd ? Way(firstSelected).length-1 : 0); //, event);
181                                 case 82: /* R */            repeatTags(firstSelected); return this;
182                                 case 70: /* F */            followWay(); return this;
183                         }
184                         var cs:ControllerState = sharedKeyboardEvents(event);
185                         return cs ? cs : this;
186                         
187                 }
188                 
189                 protected function keyExitDrawing():ControllerState {
190                         var cs:ControllerState=stopDrawing();
191                         if (selectedWay.length==1) { 
192                                 if (MainUndoStack.getGlobalStack().undoIfAction(BeginWayAction)) { 
193                                         return new NoSelection();
194                                 }
195                                 return deleteWay();
196                         }
197                         return cs;
198                 }
199                 
200                 protected function stopDrawing():ControllerState {
201                         if ( hoverEntity ) {
202                                 layer.setHighlightOnNodes(hoverEntity as Way, { hoverway: false });
203                                 hoverEntity = null;
204                         }
205
206                         if ( leaveNodeSelected ) {
207                             return new SelectedWayNode(firstSelected as Way, editEnd ? Way(firstSelected).length-1 : 0);
208                         } else {
209                             return new SelectedWay(firstSelected as Way);
210                         }
211                 }
212
213                 public function createAndAddNode(event:MouseEvent, performAction:Function):Node {
214                     var undo:CompositeUndoableAction = new CompositeUndoableAction("Add node");
215                     
216                         var lat:Number = controller.map.coord2lat(event.localY);
217                         var lon:Number = controller.map.coord2lon(event.localX);
218                         var node:Node = firstSelected.connection.createNode({}, lat, lon, undo.push);
219                         appendNode(node, undo.push);
220                         
221                         performAction(undo);
222                         return node;
223                 }
224                 
225                 protected function appendNode(node:Node, performAction:Function):void {
226                         if ( editEnd )
227                                 Way(firstSelected).appendNode(node, performAction);
228                         else
229                                 Way(firstSelected).prependNode(node, performAction);
230                 }
231                 
232                 protected function backspaceNode(performAction:Function):ControllerState {
233                         if (selectedWay.length==1) return keyExitDrawing();
234
235                         var node:Node;
236                         var undo:CompositeUndoableAction = new CompositeUndoableAction("Remove node");
237                         var newDraw:int;
238             var state:ControllerState;
239
240                         if (editEnd) {
241                                 node=Way(firstSelected).getLastNode();
242                                 Way(firstSelected).removeNodeByIndex(Way(firstSelected).length-1, undo.push);
243                                 newDraw=Way(firstSelected).length-2;
244                         } else {
245                                 node=Way(firstSelected).getNode(0);
246                                 Way(firstSelected).removeNodeByIndex(0, undo.push);
247                                 newDraw=0;
248                         }
249                         // Only actually delete the node if it has no other tags, and is not part of other ways (or part of this way twice)
250                         if (node.numParentWays==1 && Way(firstSelected).hasOnceOnly(node) && !node.hasInterestingTags()) {
251                                 layer.setPurgable([node], true);
252                                 node.connection.unregisterPOI(node);
253                                 node.remove(undo.push);
254                         }
255
256                         if (newDraw>=0 && newDraw<=Way(firstSelected).length-2) {
257                                 var mouse:Point = new Point(Way(firstSelected).getNode(newDraw).lon, Way(firstSelected).getNode(newDraw).latp);
258                                 elastic.start = mouse;
259                                 state = this;
260                         } else {
261                 Way(firstSelected).remove(undo.push);
262                 state = new NoSelection();
263                         }
264
265             performAction(undo);
266
267             if(!node.isDeleted()) { // i.e. was junction with another way (or is now POI)
268               layer.setHighlight(node, {selectedway: false});
269             }
270             return state;
271                 }
272                 
273                 /** Extends the current way by "following" an existing way, after the user has already selected two nodes in a row. 
274                         If drawing way has at least two nodes, and both belong to another way, and those ways are the same,
275                         then find the next node, add that node, update screen and scroll the new node into shot if necessary.
276                         TODO: add a bit of feedback (FloatingAlert?) when following can't be carried out for some reason. */
277                 protected function followWay():void {
278                         var curnode:Node;
279                         var prevnode:Node;
280                         if (Way(firstSelected).length < 2) return;
281
282                         if (editEnd) {
283                                 curnode = Way(firstSelected).getLastNode();
284                                 prevnode = Way(firstSelected).getNode(Way(firstSelected).length-2);
285                         } else {
286                                 curnode = Way(firstSelected).getNode(0);
287                                 prevnode = Way(firstSelected).getNode(1);
288                         }
289                         if (curnode.numParentWays <2 || prevnode.numParentWays <2) return;
290
291                         var followedWay:Way;
292                         for each (var way:Way in curnode.parentWays) {
293                                 if (way!=firstSelected && prevnode.hasParent(way))
294                                         followedWay = way;              // FIXME: could be smarter when there's more than one candidate
295                         }
296                         if (!followedWay) return;
297
298                         var nextNode:Node;
299                         if (followedWay.getNextNode(prevnode) == curnode) {
300                                 nextNode = followedWay.getNextNode(curnode);
301                         } else if (followedWay.getNextNode(curnode) == prevnode){
302                                 nextNode = followedWay.getPrevNode(curnode);
303                         } else if (followedWay.indexOfNode(curnode) > followedWay.indexOfNode(prevnode)) {
304                                 // The two nodes selected aren't actually consecutive. Make a half-hearted
305                                 // guess at which way to follow. Will be "incorrect" if the join in the loop
306                                 // is between the two points. 
307                                 nextNode = followedWay.getNextNode(curnode);
308                         } else {
309                                 nextNode = followedWay.getPrevNode(curnode);
310                         }
311                         if (!nextNode) return;
312                         if (nextNode.hasParent(firstSelected) && !(firstSelected as Way).hasOnceOnly(curnode)) return;
313
314                         appendNode(nextNode as Node, MainUndoStack.getGlobalStack().addAction);
315                         resetElastic(nextNode as Node);
316                         lastClick=nextNode;
317                         layer.setHighlight(nextNode, { selectedway: true });
318
319                         // recentre the map if the new lat/lon is offscreen
320                         controller.map.scrollIfNeeded(nextNode.lat,nextNode.lon);
321                 }
322                 
323                 override public function enterState():void {
324                         super.enterState();
325                         
326             Way(firstSelected).addEventListener(Connection.WAY_NODE_REMOVED, fixElastic);
327             Way(firstSelected).addEventListener(Connection.WAY_NODE_ADDED, fixElastic);
328
329                         var node:Node = Way(firstSelected).getNode(editEnd ? Way(firstSelected).length-1 : 0);
330                         var start:Point = new Point(node.lon, node.latp);
331                         elastic = new Elastic(controller.map, start, start);
332                         controller.setCursor(controller.pen);
333                 }
334                 override public function exitState(newState:ControllerState):void {
335             Way(firstSelected).removeEventListener(Connection.WAY_NODE_REMOVED, fixElastic);
336             Way(firstSelected).removeEventListener(Connection.WAY_NODE_ADDED, fixElastic);
337
338                         super.exitState(newState);
339                         controller.setCursor(null);
340                         elastic.removeSprites();
341                         elastic = null;
342                 }
343                 override public function toString():String {
344                         return "DrawWay";
345                 }
346         }
347 }