Merge branch 'master' into snapshotserver
[potlatch2.git] / net / systemeD / potlatch2 / mapfeatures / Feature.as
1 package net.systemeD.potlatch2.mapfeatures {
2
3     import flash.events.Event;
4     import flash.events.EventDispatcher;
5     import flash.net.*;
6     import flash.utils.ByteArray;
7     
8     import mx.core.BitmapAsset;
9     import mx.graphics.codec.PNGEncoder;
10     
11     import net.systemeD.halcyon.connection.Entity;
12     import net.systemeD.potlatch2.utils.CachedDataLoader;
13
14         /** A "map feature" is sort of a template for a map entity. It consists of a few crucial key/value pairs that define the feature, so that
15          * entities can be recognised. It also contains optional keys, with associated editing controls, that are defined as being appropriate
16          * for the feature. */
17         public class Feature extends EventDispatcher {
18         private var mapFeatures:MapFeatures;
19         private var _xml:XML;
20         private static var variablesPattern:RegExp = /[$][{]([^}]+)[}]/g;
21         private var _tags:Array;
22         private var _withins:Array;
23         private var _editors:Array;
24
25         [Embed(source="../../../../embedded/missing_icon.png")]
26         [Bindable]
27         public var missingIconCls:Class;
28
29
30         /** Create this Feature from an XML subtree. */
31         public function Feature(mapFeatures:MapFeatures, _xml:XML) {
32             this.mapFeatures = mapFeatures;
33             this._xml = _xml;
34             parseConditions();
35             parseEditors();
36         }
37
38         private function parseConditions():void {
39             _tags = [];
40            _withins = [];
41
42                         // parse tags
43             for each(var tag:XML in definition.tag) {
44                 _tags.push( { k:String(tag.@k), v:String(tag.@v), vmatch:String(tag.@vmatch)} );
45             }
46
47                         // parse 'within'
48             for each(var within:XML in definition.within) {
49                                 var obj:Object= { entity:within.@entity, k:within.@k };
50                                 if (within.attribute('v'      ).length()>0) { obj['v'      ]=within.@v;       }
51                                 if (within.attribute('minimum').length()>0) { obj['minimum']=within.@minimum; }
52                                 if (within.attribute('role'   ).length()>0) { obj['role'   ]=within.@role;    }
53                 _withins.push(obj);
54             }
55         }
56
57         private function parseEditors():void {
58             _editors = new Array();
59
60             addEditors(definition);
61
62             _editors.sortOn(["sortOrder", "name"], [Array.DESCENDING | Array.NUMERIC, Array.CASEINSENSITIVE]);
63         }
64
65         private function addEditors(xml:XML):void {
66             var inputXML:XML;
67
68             for each(var inputSetRef:XML in xml.inputSet) {
69                 var setName:String = String(inputSetRef.@ref);
70                 for each (inputXML in mapFeatures.definition.inputSet.(@id==setName)) {
71                     addEditors(inputXML);
72                 }
73             }
74
75             for each(inputXML in xml.input) {
76                 addEditor(inputXML);
77             }
78         }
79
80         private function addEditor(inputXML:XML):void {
81             var inputType:String = inputXML.@type;
82             var presenceStr:String = inputXML.@presence;
83             var sortOrderStr:String = inputXML.@priority;
84             var editor:EditorFactory = EditorFactory.createFactory(inputType, inputXML);
85             if ( editor != null ) {
86                 editor.presence = Presence.getPresence(presenceStr);
87                 editor.sortOrder = EditorFactory.getPriority(sortOrderStr);
88                 _editors.push(editor);
89             }
90         }
91
92         /** List of editing controls associated with this feature. */
93         public function get editors():Array {
94             return _editors;
95         }
96
97         /** The XML subtree that this feature was loaded from. */
98         public function get definition():XML {
99             return _xml;
100         }
101
102         [Bindable(event="nameChanged")]
103         /** The human-readable name of the feature (@name), or null if none. */
104         public function get name():String {
105                         if (_xml.attribute('name').length()>0) { return _xml.@name; }
106                         return null;
107         }
108
109         [Bindable(event="descriptionChanged")]
110         /** The human-readable description of the feature, or null if none. */
111         public function get description():String {
112             var desc:XMLList = _xml.description
113             if (desc.length()>0) { return desc[0]; }
114             return null;
115         }
116
117         /** Returns the icon defined for the feature.
118         * This uses the "image" property of the feature's icon element. If no image property is defined, returns a default "missing icon".
119         */
120         [Bindable(event="imageChanged")]
121         public function get image():ByteArray {
122             return getImage();
123         }
124
125         /** Returns the drag+drop override-icon defined for the feature.
126         * This uses the "dnd" property of the feature's icon element, or if there is no override-icon it falls back to the standard image.
127         */
128         [Bindable(event="imageChanged")]
129         public function get dndimage():ByteArray {
130             return getImage(true);
131         }
132
133         /** Fetches the feature's image, as defined by the icon element in the feature definition.
134         * @param dnd if true, overrides the normal image and returns the one defined by the dnd property instead. */
135         private function getImage(dnd:Boolean = false):ByteArray {
136             var icon:XMLList = _xml.icon;
137             var imageURL:String = null;
138             var img:ByteArray;
139
140             if ( dnd && icon.length() > 0 && icon[0].hasOwnProperty("@dnd") ) {
141                 imageURL = icon[0].@dnd;
142             } else if ( icon.length() > 0 && icon[0].hasOwnProperty("@image") ) {
143                 imageURL = icon[0].@image;
144             }
145
146             if ( imageURL != null ) {
147                 img = CachedDataLoader.loadData(imageURL, imageLoaded);
148             }
149             if (img) {
150               return img;
151             }
152             var bitmap:BitmapAsset = new missingIconCls() as BitmapAsset;
153             return new PNGEncoder().encode(bitmap.bitmapData);
154         }
155         
156         /** Can this feature be drag-and-dropped from the side panel? By default, any "point" feature can,
157         *   unless it has <point draganddrop="no"/> 
158         * */
159         public function canDND():Boolean {
160                 var point:XMLList = _xml.elements("point");
161                 return point.length() > 0 && !(XML(point[0]).attribute("draganddrop")[0] == "no");
162         }
163
164         private function imageLoaded(url:String, data:ByteArray):void {
165             dispatchEvent(new Event("imageChanged"));
166         }
167
168         public function htmlDetails(entity:Entity):String {
169             var icon:XMLList = _xml.icon;
170             return makeHTMLIcon(icon, entity);
171         }
172
173         /** Convert the contents of the "icon" tag as an HTML string, with variable substitution. */
174         public static function makeHTMLIcon(icon:XMLList, entity:Entity):String {
175             if ( icon == null )
176                 return "";
177
178             var txt:String = icon.children().toXMLString();
179             var replaceTag:Function = function():String {
180                 var value:String = entity.getTag(arguments[1]);
181                 return value == null ? "" : htmlEscape(value);
182             };
183             txt = txt.replace(variablesPattern, replaceTag);
184             return txt;
185         }
186
187         /** Basic HTML escaping. */
188         public static function htmlEscape(str:String):String {
189             var newStr:String = str.replace(/&/g, "&amp;");
190             newStr = newStr.replace(/</g, "&lt;");
191             newStr = newStr.replace(/>/g, "&gt;");
192             newStr = newStr.replace(/"/g, "&quot;");    // "
193             newStr = newStr.replace(/'/g, "&apos;");    // '
194             return newStr;
195         }
196
197         /** Whether this feature belongs to the given category or not, as defined by its definition in the XML file. */
198         public function isInCategory(category:String):Boolean {
199             var cats:XMLList = _xml.category;
200             if ( cats.length() == 0 )
201                 return false;
202
203             for each( var cat:XML in cats )
204                 if ( cat.text()[0] == category )
205                     return true;
206             return false;
207         }
208
209
210         /** List of {k, v} pairs that define the feature. */
211         public function get tags():Array {
212             return _tags;
213         }
214
215         /** List of "withins" which further restrict the applicability of the feature. Each within is a {entity, k, ?v, ?minimum, ?role} object. */
216         public function get withins():Array {
217             return _withins;
218         }
219
220         /** The first category that the feature belongs to, as defined by the order of the map features XML file. */
221         public function findFirstCategory():Category {
222             for each( var cat:Category in mapFeatures.categories ) {
223                 if ( isInCategory(cat.id) )
224                     return cat;
225             }
226             return null;
227         }
228
229         /** Whether the feature is of the given type (point, line/area, relation). */
230         public function isType(type:String):Boolean {
231             if (type=='area') {
232                             return (_xml.elements(type).length() > 0) || (_xml.elements('line').length() > 0);
233             } else {
234                             return _xml.elements(type).length() > 0;
235                         }
236         }
237
238         /** Whether there is a help string defined or one can be derived from tags. */
239         public function hasHelpURL():Boolean {
240             return _xml.help.length() > 0 || _tags.length > 0;
241         }
242
243         /** The defined help string, if any. If none, generate one from tags on the feature, pointing to the OSM wiki. */
244         public function get helpURL():String {
245                 if (_xml.help.length() > 0)
246                 return _xml.help;
247             else if (_tags.length > 0) {
248                 if (_tags[0].v == "*")
249                     return "http://www.openstreetmap.org/wiki/Key:" + _tags[0].k;
250                 else
251                     return "http://www.openstreetmap.org/wiki/Tag:" + _tags[0].k + "=" + _tags[0].v;                
252             } else
253                 return "";
254
255         }
256     }
257 }
258