Merge branch 'master' into snapshotserver
[potlatch2.git] / net / systemeD / potlatch2 / mapfeatures / MapFeatures.as
1 package net.systemeD.potlatch2.mapfeatures {
2
3     import flash.events.Event;
4     import flash.events.EventDispatcher;
5     import flash.net.*;
6     
7     import net.systemeD.halcyon.NestedXMLLoader;
8     import net.systemeD.halcyon.connection.*;
9
10     /** All the information about all available map features that can be selected by the user or matched against entities in the map.
11     * The list of map features is populated from an XML file the first time the MapFeatures instance is accessed.
12     *
13     * <p>There are four "types" of features: point, line, area, relation. However, the autocomplete functions refer to these as node,
14     * way (line/area) and relation.</p>
15     */
16         public class MapFeatures extends EventDispatcher {
17         private static var instance:MapFeatures;
18
19         /** Instantiates MapFeatures by loading it if required. */
20         public static function getInstance():MapFeatures {
21             if ( instance == null ) {
22                 instance = new MapFeatures();
23                 instance.loadFeatures();
24             }
25             return instance;
26         }
27
28         private var xml:XML = null;
29         private var _features:Array = null;
30         private var _categories:Array = null;
31 //              private var _keys:Array = null;
32                 private var _tags:Object = null;
33
34         /** Loads list of map features from XML file which it first retrieves. */
35         protected function loadFeatures():void {
36             var xmlLoader:NestedXMLLoader = new NestedXMLLoader();
37             xmlLoader.addEventListener(Event.COMPLETE, onFeatureLoad);
38             xmlLoader.load("map_features.xml");
39         }
40
41         /** The loaded source XML file itself. */
42         internal function get definition():XML {
43             return xml;
44         }
45
46         /** Load XML file, then trawl over it, setting up convenient indexes into the list of map features. */
47         private function onFeatureLoad(event:Event):void {
48                         var f:Feature;
49
50             xml = NestedXMLLoader(event.target).xml;
51             _features = [];
52             _tags = { relation:{}, way:{}, node:{} };
53
54             for each(var feature:XML in xml..feature) {
55                 f=new Feature(this,feature);
56                 _features.push(f);
57                 for each (var tag:Object in f.tags) {
58                     if (f.isType('line') || f.isType('area')) { addToTagList('way',tag); }
59                     if (f.isType('relation'))                 { addToTagList('relation',tag); }
60                     if (f.isType('point'))                    { addToTagList('node',tag); }
61                 }
62
63                 for each (var inputSet:XML in feature..inputSet) {
64                     tagsFromInputSet(definition.inputSet.(@id == String(inputSet.@ref)), f);
65                 }
66             }
67
68             _categories = new Array();
69             for each(var catXML:XML in xml.category) {
70                 if ( catXML.child("category").length() == 0 )
71                   _categories.push(new Category(this, catXML.@name, catXML.@id, _categories.length));
72             }
73             dispatchEvent(new Event("featuresLoaded"));
74         }
75
76         private function tagsFromInputSet(inputSet:XMLList, f:Feature):void {
77             for each (var input:XML in inputSet.input) {
78                 // Take all the k/v pairs from inputs that have choice
79                 for each (var choice:XML in input..choice ) {
80                     if (f.isType('line') || f.isType('area')) { addToTagList('way', {k:String(input.@key), v:String(choice.@value)}); }
81                     if (f.isType('relation'))                 { addToTagList('relation',{k:String(input.@key), v:String(choice.@value)}); }
82                     if (f.isType('point'))                    { addToTagList('node',{k:String(input.@key), v:String(choice.@value)}); }
83                 }
84
85                 if (input.@type == 'freetext') {
86                     if (f.isType('line') || f.isType('area')) { addToTagList('way', {k:String(input.@key), v:''}); }
87                     if (f.isType('relation'))                 { addToTagList('relation',{k:String(input.@key), v:''}); }
88                     if (f.isType('point'))                    { addToTagList('node',{k:String(input.@key), v:''}); }
89                 }
90             }
91
92             // inputSets can have their own inputSets, so recurse
93             for each (var i:XML in inputSet.inputSet) {
94                 tagsFromInputSet(definition.inputSet.(@id == String(i.@ref)), f);
95             }
96         }
97
98         /** Add one item to tagList index, which will end up being a list like: ["way"]["highway"]["residential"] */
99                 private function addToTagList(type:String,tag:Object):void {
100                         if (tag.v=='*') { return; }
101                         if (!_tags[type][tag.k]) { _tags[type][tag.k]=new Array(); }
102                         if (_tags[type][tag.k].indexOf(tag.v)==-1) { _tags[type][tag.k].push(tag.v); }
103                 }
104
105         /** Indicates whether the XML file has finished being loaded. */
106         public function hasLoaded():Boolean {
107             return xml != null;
108         }
109
110         /** Find the first Feature (template) that matches the given Entity (actual existing object in the map).
111          *
112          * This is done to provide appropriate editing controls that correspond to the selected Entity.
113          *
114          * @param entity The Entity to try and match against.
115          * @return The first suitable Feature, or null. */
116
117         public function findMatchingFeature(entity:Entity):Feature {
118             if ( xml == null )
119                 return null;
120
121             for each(var feature:Feature in features) {
122                 var match:Boolean = true;
123
124                 // check for matching tags
125                 // the "match" attribute lets you specify other values that will match this feature
126                 // but won't affect the default value assigned. format is "*" or a regex.
127                 for each(var tag:Object in feature.tags) {
128                     var entityTag:String = entity.getTag(tag.k);
129                     if (entityTag == null) { match = false; break; }
130                     match = 
131                         tag.v == entityTag 
132                      || tag.v == "*"
133                      || tag.vmatch == "*"
134                      || tag.vmatch != "" && entityTag.match(new RegExp("^" + tag.vmatch + "$"));
135                     if ( !match ) break;
136                 }
137
138                 // check for matching withins
139                 if (match) {
140                     for each (var within:Object in feature.withins) {
141                         match = entity.countParentObjects(within) >= (within.minimum ? within.minimum : 1);
142                         if (!match) { break; }
143                     }
144                 }
145
146                 if (match) {
147                     return feature;
148                 }
149             }
150             return null;
151         }
152
153
154         /** Array of every Category found in the map features file. */
155         [Bindable(event="featuresLoaded")]
156         public function get categories():Array {
157             if ( xml == null )
158                 return null;
159             return _categories;
160         }
161
162         /** Categories that contain at least one Feature corresponding to a certain type, such as "area" or "point".
163         *
164         * @return Filtered Array of Category objects, possibly empty. null if XML file is not yet processed.
165         */
166         [Bindable(event="featuresLoaded")]
167         public function getCategoriesForType(type:String):Array {
168             if ( xml == null )
169                 return null;
170             if ( type == null || type == "" )
171                 return []; //_categories;
172
173             var filteredCategories:Array = new Array();
174             for each( var cat:Category in _categories ) {
175                 if ( cat.getFeaturesForType(type).length > 0 )
176                     filteredCategories.push(cat);
177             }
178             return filteredCategories;
179         }
180
181         /** All features.
182         *
183         * @return null if XML file not yet processed. */
184         [Bindable(event="featuresLoaded")]
185         public function get features():Array {
186             if ( xml == null )
187                 return null;
188             return _features;
189         }
190
191         /** All Features of type "point".
192         *
193         * @return null if XML file not yet processed.
194         */
195         [Bindable(event="featuresLoaded")]
196         public function get pois():Array {
197             if (xml == null )
198                 return null;
199             var pois:Array = [];
200             var counter:int = 0;
201             for each ( var feature:Feature in _features ) {
202                   if (feature.isType("point")) {
203                   pois.push(feature);
204                   }
205             }
206             return pois;
207         }
208
209         /** A list of all Keys for all features of the given type, sorted.
210          * @example <listing version="3.0">getAutoCompleteKeys ("way")</listing>
211          * Returns: [{name: "building"}, {name: "highway"}...]
212          */
213         [Bindable(event="featuresLoaded")]
214         public function getAutoCompleteKeys(type:String):Array {
215             var list:Array=[];
216             var a:Array=[];
217
218             for (var k:String in _tags[type]) { list.push(k); }
219             list.sort();
220
221             for each (k in list) { a.push( { name: k } ); }
222             return a;
223         }
224
225         /** Get all the possible values that could go with a given key and type.
226         * TODO: Include values previously entered by the user, but not existent in XML file.
227         *
228         * @example <listing version="3.0">getAutoCompleteValues("way", "highway")</listing>
229         * Returns: [{name: "motorway"}, {name: "residential"}...]
230         */
231         [Bindable(event="featuresLoaded")]
232         public function getAutoCompleteValues(type:String,key:String):Array {
233             var a:Array=[];
234             if (_tags[type][key]) {
235                 _tags[type][key].sort();
236                 for each (var v:String in _tags[type][key]) { a.push( { name: v } ); }
237             }
238             return a;
239         }
240
241     }
242
243 }
244
245