net/systemeD/halcyon/WayUI.as

   1 package net.systemeD.halcyon {
   2
   3         import flash.display.*;
   4         import flash.geom.Matrix;
   5         import flash.geom.Point;
   6         import flash.geom.Rectangle;
   7         import flash.text.TextField;
   8         import flash.text.TextFormat;
   9         import flash.events.*;
  10         import net.systemeD.halcyon.styleparser.*;
  11     import net.systemeD.halcyon.connection.*;
  12         import net.systemeD.halcyon.Globals;
  13
  14         public class WayUI extends EntityUI {
  15
  16         private var way:Way;
  17                 public var pathlength:Number;                           // length of path
  18                 public var patharea:Number;                                     // area of path
  19                 public var centroid_x:Number;                           // centroid
  20                 public var centroid_y:Number;                           //  |
  21                 public var heading:Array=new Array();           // angle at each node
  22         private var hitzone:Sprite;
  23                 public var nameformat:TextFormat;
  24
  25                 private const NODESIZE:uint=6;
  26
  27                 public function WayUI(way:Way, map:Map) {
  28                         super();
  29                         this.way = way;
  30                         this.map = map;
  31             init();
  32             way.addEventListener(Connection.TAG_CHANGE, wayTagChanged);
  33             way.addEventListener(Connection.WAY_NODE_ADDED, wayNodeAdded);
  34             way.addEventListener(Connection.WAY_NODE_REMOVED, wayNodeRemoved);
  35                         way.addEventListener(Connection.WAY_DELETED, wayDeleted);
  36             attachNodeListeners();
  37                 }
  38
  39                 private function attachNodeListeners():void {
  40             for (var i:uint = 0; i < way.length; i++ ) {
  41                 way.getNode(i).addEventListener(Connection.NODE_MOVED, nodeMoved);
  42             }
  43                 }
  44
  45                 private function wayNodeAdded(event:WayNodeEvent):void {
  46                     event.node.addEventListener(Connection.NODE_MOVED, nodeMoved);
  47                     redraw();
  48                 }
  49
  50                 private function wayNodeRemoved(event:WayNodeEvent):void {
  51                     event.node.removeEventListener(Connection.NODE_MOVED, nodeMoved);
  52                     redraw();
  53                 }
  54
  55         private function wayTagChanged(event:TagEvent):void {
  56             redraw();
  57         }
  58         private function nodeMoved(event:NodeMovedEvent):void {
  59             redraw();
  60         }
  61                 private function wayDeleted(event:EntityEvent):void {
  62                         redraw();
  63                 }
  64
  65                 private function init():void {
  66                         recalculate();
  67                         redraw();
  68                         // updateBbox(lon, lat);
  69                         // ** various other stuff
  70                 }
  71
  72                 // ------------------------------------------------------------------------------------------
  73                 // Calculate length etc.
  74                 // ** this could be made scale-independent - would speed up redraw
  75
  76                 public function recalculate():void {
  77                         var lx:Number, ly:Number, sc:Number;
  78                         var node:Node, latp:Number, lon:Number;
  79                         var cx:Number=0, cy:Number=0;
  80                         pathlength=0;
  81                         patharea=0;
  82                         if (way.length==0) { return; }
  83
  84                         lx = way.getNode(way.length-1).lon;
  85                         ly = way.getNode(way.length-1).latp;
  86                         for ( var i:uint = 0; i < way.length; i++ ) {
  87                 node = way.getNode(i);
  88                 latp = node.latp;
  89                 lon  = node.lon;
  90
  91                                 // length and area
  92                                 if ( i>0 ) { pathlength += Math.sqrt( Math.pow(lon-lx,2)+Math.pow(latp-ly,2) ); }
  93                                 sc = (lx*latp-lon*ly)*map.scalefactor;
  94                                 cx += (lx+lon)*sc;
  95                                 cy += (ly+latp)*sc;
  96                                 patharea += sc;
  97
  98                                 // heading
  99                                 if (i>0) { heading[i-1]=Math.atan2((lon-lx),(latp-ly)); }
 100
 101                                 lx=lon; ly=latp;
 102                         }
 103                         heading[way.length-1]=heading[way.length-2];
 104
 105                         pathlength*=map.scalefactor;
 106                         patharea/=2;
 107                         if (patharea!=0 && way.isArea()) {
 108                                 centroid_x=map.lon2coord(cx/patharea/6);
 109                                 centroid_y=map.latp2coord(cy/patharea/6);
 110                         } else if (pathlength>0) {
 111                                 var c:Array=pointAt(0.5);
 112                                 centroid_x=c[0];
 113                                 centroid_y=c[1];
 114                         }
 115                 }
 116
 117                 // ------------------------------------------------------------------------------------------
 118                 // Redraw
 119
 120                 override public function redraw(sl:StyleList=null):Boolean {
 121                         removeSprites();
 122                         if (way.length==0) { return false; }
 123
 124             // Copy tags object, and add states
 125             var tags:Object = way.getTagsCopy();
 126                         tags=applyStateClasses(tags);
 127                         if (way.isArea()) { tags[':area']='yes'; }
 128
 129                         // Which layer?
 130                         layer=5;
 131                         if ( tags['layer'] )
 132                 layer=Math.min(Math.max(tags['layer']+5,-5),5)+5;
 133
 134                         // Iterate through each sublayer, drawing any styles on that layer
 135                         if (!sl) { sl=map.ruleset.getStyles(this.way, tags); }
 136                         var drawn:Boolean;
 137                         for (var sublayer:int=10; sublayer>=0; sublayer--) {
 138                                 if (sl.shapeStyles[sublayer]) {
 139                                         var s:ShapeStyle=sl.shapeStyles[sublayer];
 140                                         var stroke:Shape, fill:Shape, casing:Shape, roadname:Sprite;
 141                                         var x0:Number=map.lon2coord(way.getNode(0).lon);
 142                                         var y0:Number=map.latp2coord(way.getNode(0).latp);
 143
 144                                         // Stroke
 145                                         if (s.width)  {
 146                                                 stroke=new Shape(); addToLayer(stroke,STROKESPRITE,sublayer);
 147                                                 stroke.graphics.moveTo(x0,y0);
 148                                                 s.applyStrokeStyle(stroke.graphics);
 149                                                 if (s.dashes && s.dashes.length>0) { dashedLine(stroke.graphics,s.dashes); }
 150                                                                                                           else { solidLine(stroke.graphics); }
 151                                                 drawn=true;
 152                                         }
 153
 154                                         // Fill
 155                                         if (s.fill_color || s.fill_image) {
 156                                                 fill=new Shape(); addToLayer(fill,FILLSPRITE);
 157                                                 fill.graphics.moveTo(x0,y0);
 158                                                 if (s.fill_image) { new WayBitmapFiller(this,fill.graphics,s); }
 159                                                                          else { s.applyFill(fill.graphics); }
 160                                                 solidLine(fill.graphics);
 161                                                 fill.graphics.endFill();
 162                                                 drawn=true;
 163                                         }
 164
 165                                         // Casing
 166                                         if (s.casing_width) {
 167                                                 casing=new Shape(); addToLayer(casing,CASINGSPRITE);
 168                                                 casing.graphics.moveTo(x0,y0);
 169                                                 s.applyCasingStyle(casing.graphics);
 170                                                 if (s.casing_dashes && s.casing_dashes.length>0) { dashedLine(casing.graphics,s.casing_dashes); }
 171                                                                                                                                         else { solidLine(casing.graphics); }
 172                                                 drawn=true;
 173                                         }
 174                                 }
 175
 176                                 if (sl.textStyles[sublayer]) {
 177                                         var t:TextStyle=sl.textStyles[sublayer];
 178                                         roadname=new Sprite(); addToLayer(roadname,NAMESPRITE);
 179                                         nameformat = t.getTextFormat();
 180                                         var a:String=tags[t.text];
 181                                         if (a) {
 182                                                 if (t.font_caps) { a=a.toUpperCase(); }
 183                                                 if (t.text_center && centroid_x) {
 184                                                         t.writeNameLabel(roadname,a,centroid_x,centroid_y);
 185                                                 } else {
 186                                                         writeNameOnPath(roadname,a,t.text_offset ? t.text_offset : 0);
 187                                                 }
 188                                                 if (t.text_halo_radius>0) { roadname.filters=t.getHaloFilter(); }
 189                                         }
 190                                 }
 191
 192                                 // ** ShieldStyle to do
 193                         }
 194
 195                         // Draw icons
 196                         // ** there should be huge potential to optimise this - at present we're
 197                         //    running getStyles for every node in the way on every redraw
 198                         // ** fix r/heading behaviour - that doesn't look right
 199                         var r:Number;
 200                         var nodetags:Object;
 201                         var nodeSelected:int=stateClasses["nodeSelected"];
 202                         for (var i:uint = 0; i < way.length; i++) {
 203                 var node:Node = way.getNode(i);
 204                                 nodetags=node.getTagsCopy();
 205                                 if (i==0) { nodetags['_heading']= heading[i]; }
 206                                      else { nodetags['_heading']=(heading[i]+heading[i-1])/2; }
 207                                 if (stateClasses["showNodes"]) { nodetags[':selectedway']='yes'; }
 208                                 if (stateClasses["showNodesHover"]) { nodetags[':hoverway']='yes'; }
 209                                 if (node.id==nodeSelected) { nodetags[':selected']='yes'; }
 210                                 sl=map.ruleset.getStyles(node,nodetags);
 211                                 if (sl.hasStyles()) {
 212                                         if (!map.pois[node.id]) {
 213                                                 map.pois[node.id]=new NodeUI(node,map,r);
 214                                         }
 215                                         map.pois[node.id].redraw(sl);
 216                                 } else if (map.pois[node.id]) {
 217                                         map.pois[node.id].removeSprites();
 218                                         delete map.pois[node.id];
 219                                 }
 220                         }
 221                         if (!drawn) { return false; }
 222
 223             // create a generic "way" hitzone sprite
 224             hitzone = new Sprite();
 225             hitzone.graphics.lineStyle(4, 0x000000, 1, false, "normal", CapsStyle.ROUND, JointStyle.ROUND);
 226             solidLine(hitzone.graphics);
 227             addToLayer(hitzone, CLICKSPRITE);
 228             hitzone.visible = false;
 229                         createListenSprite(hitzone);
 230
 231                         return true;
 232                 }
 233
 234                 // ------------------------------------------------------------------------------------------
 235                 // Drawing support functions
 236
 237                 // Draw solid polyline
 238
 239                 public function solidLine(g:Graphics):void {
 240             var node:Node = way.getNode(0);
 241                         g.moveTo(map.lon2coord(node.lon), map.latp2coord(node.latp));
 242                         for (var i:uint = 1; i < way.length; i++) {
 243                 node = way.getNode(i);
 244                                 g.lineTo(map.lon2coord(node.lon), map.latp2coord(node.latp));
 245                         }
 246                 }
 247
 248                 // Draw dashed polyline
 249
 250                 private function dashedLine(g:Graphics,dashes:Array):void {
 251                         var draw:Boolean=false, dashleft:Number=0, dc:Array=new Array();
 252                         var a:Number, xc:Number, yc:Number;
 253                         var curx:Number, cury:Number;
 254                         var dx:Number, dy:Number, segleft:Number=0;
 255                         var i:int=0;
 256
 257             var node:Node = way.getNode(0);
 258             var nextNode:Node = way.getNode(0);
 259                         g.moveTo(map.lon2coord(node.lon), map.latp2coord(node.latp));
 260                         while (i < way.length-1 || segleft>0) {
 261                                 if (dashleft<=0) {      // should be ==0
 262                                         if (dc.length==0) { dc=dashes.slice(0); }
 263                                         dashleft=dc.shift();
 264                                         draw=!draw;
 265                                 }
 266                                 if (segleft<=0) {       // should be ==0
 267                     node = way.getNode(i);
 268                     nextNode = way.getNode(i+1);
 269                                         curx=map.lon2coord(node.lon);
 270                     dx=map.lon2coord(nextNode.lon)-curx;
 271                                         cury=map.latp2coord(node.latp);
 272                     dy=map.latp2coord(nextNode.latp)-cury;
 273                                         a=Math.atan2(dy,dx); xc=Math.cos(a); yc=Math.sin(a);
 274                                         segleft=Math.sqrt(dx*dx+dy*dy);
 275                                         i++;
 276                                 }
 277
 278                                 if (segleft<=dashleft) {
 279                                         // the path segment is shorter than the dash
 280                                         curx+=dx; cury+=dy;
 281                                         moveLine(g,curx,cury,draw);
 282                                         dashleft-=segleft; segleft=0;
 283                                 } else {
 284                                         // the path segment is longer than the dash
 285                                         curx+=dashleft*xc; dx-=dashleft*xc;
 286                                         cury+=dashleft*yc; dy-=dashleft*yc;
 287                                         moveLine(g,curx,cury,draw);
 288                                         segleft-=dashleft; dashleft=0;
 289                                 }
 290                         }
 291                 }
 292
 293                 private function moveLine(g:Graphics,x:Number,y:Number,draw:Boolean):void {
 294                         if (draw) { g.lineTo(x,y); }
 295                                  else { g.moveTo(x,y); }
 296                 }
 297
 298
 299                 // Find point partway (0-1) along a path
 300                 // returns (x,y,angle)
 301                 // inspired by senocular's Path.as
 302
 303                 private function pointAt(t:Number):Array {
 304                         var totallen:Number = t*pathlength;
 305                         var curlen:Number = 0;
 306                         var dx:Number, dy:Number, seglen:Number;
 307                         for (var i:int = 1; i < way.length; i++){
 308                                 dx=map.lon2coord(way.getNode(i).lon)-map.lon2coord(way.getNode(i-1).lon);
 309                                 dy=map.latp2coord(way.getNode(i).latp)-map.latp2coord(way.getNode(i-1).latp);
 310                                 seglen=Math.sqrt(dx*dx+dy*dy);
 311                                 if (totallen > curlen+seglen) { curlen+=seglen; continue; }
 312                                 return new Array(map.lon2coord(way.getNode(i-1).lon)+(totallen-curlen)/seglen*dx,
 313                                                                  map.latp2coord(way.getNode(i-1).latp)+(totallen-curlen)/seglen*dy,
 314                                                                  Math.atan2(dy,dx));
 315                         }
 316                         return new Array(0, 0, 0);
 317                 }
 318
 319                 // Draw name along path
 320                 // based on code by Tom Carden
 321
 322                 private function writeNameOnPath(s:Sprite,a:String,textOffset:Number=0):void {
 323
 324                         // make a dummy textfield so we can measure its width
 325                         var tf:TextField = new TextField();
 326                         tf.defaultTextFormat = nameformat;
 327                         tf.text = a;
 328                         tf.width = tf.textWidth+4;
 329                         tf.height = tf.textHeight+4;
 330                         if (pathlength<tf.width) { return; }    // no room for text?
 331
 332                         var t1:Number = (pathlength/2 - tf.width/2) / pathlength; var p1:Array=pointAt(t1);
 333                         var t2:Number = (pathlength/2 + tf.width/2) / pathlength; var p2:Array=pointAt(t2);
 334
 335                         var angleOffset:Number; // so we can do a 180º if we're running backwards
 336                         var offsetSign:Number;  // -1 if we're starting at t2
 337                         var tStart:Number;      // t1 or t2
 338
 339                         // make sure text doesn't run right->left or upside down
 340                         if (p1[0] < p2[0] &&
 341                                 p1[2] < Math.PI/2 &&
 342                                 p1[2] > -Math.PI/2) {
 343                                 angleOffset = 0; offsetSign = 1; tStart = t1;
 344                         } else {
 345                                 angleOffset = Math.PI; offsetSign = -1; tStart = t2;
 346                         }
 347
 348                         // make a textfield for each char, centered on the line,
 349                         // using getCharBoundaries to rotate it around its center point
 350                         var chars:Array = a.split('');
 351                         for (var i:int = 0; i < chars.length; i++) {
 352                                 var rect:Rectangle = tf.getCharBoundaries(i);
 353                                 if (rect) {
 354                                         s.addChild(rotatedLetter(chars[i],
 355                                                                                          tStart + offsetSign*(rect.left+rect.width/2)/pathlength,
 356                                                                                          rect.width, tf.height, angleOffset, textOffset));
 357                                 }
 358                         }
 359                 }
 360
 361                 private function rotatedLetter(char:String, t:Number, w:Number, h:Number, a:Number, o:Number):TextField {
 362                         var tf:TextField = new TextField();
 363             tf.mouseEnabled = false;
 364             tf.mouseWheelEnabled = false;
 365                         tf.defaultTextFormat = nameformat;
 366                         tf.embedFonts = true;
 367                         tf.text = char;
 368                         tf.width = tf.textWidth+4;
 369                         tf.height = tf.textHeight+4;
 370
 371                         var p:Array=pointAt(t);
 372                         var matrix:Matrix = new Matrix();
 373                         matrix.translate(-w/2, -h/2-o);
 374                         // ** add (say) -4 to the height to move it up by 4px
 375                         matrix.rotate(p[2]+a);
 376                         matrix.translate(p[0], p[1]);
 377                         tf.transform.matrix = matrix;
 378                         return tf;
 379                 }
 380
 381                 public function getNodeAt(x:Number, y:Number):Node {
 382                         for (var i:uint = 0; i < way.length; i++) {
 383                 var node:Node = way.getNode(i);
 384                 var nodeX:Number = map.lon2coord(node.lon);
 385                 var nodeY:Number = map.latp2coord(node.latp);
 386                 if ( nodeX >= x-NODESIZE && nodeX <= x+NODESIZE &&
 387                      nodeY >= y-NODESIZE && nodeY <= y+NODESIZE )
 388                     return node;
 389             }
 390             return null;
 391                 }
 392
 393         override protected function mouseEvent(event:MouseEvent):void {
 394                         map.entityMouseEvent(event, way);
 395         }
 396
 397         }
 398 }