net/systemeD/halcyon/connection/MainUndoStack.as

   1 package net.systemeD.halcyon.connection {
   2
   3     import flash.events.*;
   4
   5     public class MainUndoStack extends EventDispatcher {
   6         private static const GLOBAL_INSTANCE:MainUndoStack = new MainUndoStack();
   7
   8         public static function getGlobalStack():MainUndoStack {
   9             return GLOBAL_INSTANCE;
  10         }
  11
  12         private var undoActions:Array = [];
  13         private var redoActions:Array = [];
  14
  15         /*
  16          * Performs the action, then puts it on the undo stack.
  17          *
  18          * If you want to delay execution don't put it on this
  19          * stack -- find another one.
  20          */
  21         public function addAction(action:UndoableAction):void {
  22             trace("doing "+action);
  23             var result:uint = action.doAction();
  24
  25             switch ( result ) {
  26
  27             case UndoableAction.FAIL:
  28                 throw new Error("Failure performing "+action);
  29
  30             case UndoableAction.NO_CHANGE:
  31                 // nothing to do, and don't add to stack
  32                 break;
  33
  34             case UndoableAction.SUCCESS:
  35             default:
  36                 if ( undoActions.length > 0 ) {
  37                     var previous:UndoableAction = undoActions[undoActions.length - 1];
  38                     var isMerged:Boolean = action.mergePrevious(previous);
  39                     if ( isMerged )
  40                         undoActions.pop();
  41                 }
  42                 undoActions.push(action);
  43                 redoActions = [];
  44                 dispatchEvent(new Event("new_undo_item"));
  45                 dispatchEvent(new Event("new_redo_item"));
  46                 break;
  47
  48             }
  49         }
  50
  51         /*
  52          * Call to kill the undo queue -- the user will not be able to undo
  53          * anything they previously did after this is called.
  54          */
  55         public function breakUndo():void {
  56             undoActions = [];
  57             redoActions = [];
  58         }
  59
  60         [Bindable(event="new_undo_item")]
  61         public function canUndo():Boolean {
  62             return undoActions.length > 0;
  63         }
  64
  65         [Bindable(event="new_redo_item")]
  66         public function canRedo():Boolean {
  67             return redoActions.length > 0;
  68         }
  69
  70         public function undo():void {
  71                         if (!undoActions.length) { return; }
  72             var action:UndoableAction = undoActions.pop();
  73             trace("undoing "+action);
  74             action.undoAction();
  75             redoActions.push(action);
  76             dispatchEvent(new Event("new_undo_item"));
  77             dispatchEvent(new Event("new_redo_item"));
  78         }
  79
  80         public function redo():void {
  81                         if (!redoActions.length) { return; }
  82             var action:UndoableAction = redoActions.pop();
  83             trace("redoing "+action);
  84             action.doAction();
  85             undoActions.push(action);
  86             dispatchEvent(new Event("new_undo_item"));
  87             dispatchEvent(new Event("new_redo_item"));
  88         }
  89
  90     }
  91 }