Change wiki preprocessing script to read redirect pages
[rails.git] / script / misc / update-wiki-pages
1 #!/usr/bin/env perl
2 use 5.010;
3 use strict;
4 use warnings;
5
6 use Pod::Usage ();
7 use Getopt::Long ();
8
9 BEGIN {
10     eval "require MediaWiki::API; require YAML::XS;" or do {
11         print "You have to install some modules via CPAN to run this:\n";
12         print "   sudo cpanp MediaWiki::API YAML::XS\n";
13         exit 1;
14     };
15 }
16
17 use MediaWiki::API;
18 use YAML::XS qw(Dump);
19 use Test::More 'no_plan';
20
21 =head1 NAME
22
23 update-wiki-pages - Scrape the wiki for key/value wiki description pages
24
25 =head1 SYNOPSIS
26
27     perl script/misc/update-wiki-pages config/wiki_pages.yml 
28
29 Or with prove(1):
30
31     prove -e 'perl script/misc/update-wiki-pages' config/wiki_pages.yml
32
33 =cut
34
35 # Get the command-line options
36 Getopt::Long::Parser->new(
37     config => [ qw< bundling no_ignore_case no_require_order pass_through > ],
38 )->getoptions(
39     'h|help' => \my $help,
40 ) or help();
41
42 # On --help
43 help() if $help;
44
45 my $out_file = $ARGV[0];
46 $out_file //= 'config/wiki_pages.yml';
47
48 help() unless -f $out_file;
49
50 # Get a API interface
51 my $mw = MediaWiki::API->new();
52 ok($mw, "Got a MediaWiki API");
53 $mw->{config}->{api_url} = 'http://wiki.openstreetmap.org/w/api.php';
54
55 # All our goodies
56 my (%feature, %count);
57
58 # This is what you get on:
59 ## http://wiki.openstreetmap.org/w/index.php?search=Template:KeyDescription&fulltext=Search&fulltext=Search
60 for my $lang ('', map { "${_}:" } qw[ Pt Fi De It HU Cz Fr RU Pl ]) {
61     ok(1, "  Templates for language '$lang'");
62
63     # Key pages
64     ok(1, "    Getting key pages");
65     my $cnt = stick_content_in_hash("key", "Template:${lang}KeyDescription", \%feature);
66     ok(1, "    Got $cnt key pages");
67     $count{key} += $cnt;
68
69     # Value pages
70     ok(1, "    Getting value pages");
71     $cnt = stick_content_in_hash("tag", "Template:${lang}ValueDescription", \%feature);
72     ok(1, "    Got $cnt value pages");
73     $count{value} += $cnt;
74 }
75
76 ok(1, "Got a total of $count{$_} ${_}s") for qw[ key value ];
77
78 # Dump to .yml file
79 open my $out, ">", $out_file or die "Can't open file '$out_file' supplied on the command line";
80 say $out "# THIS FILE IS AUTOGENERATED WITH THE script/misc/update-wiki-pages";
81 say $out "# PROGRAM DO NOT MANUALLY EDIT IT";
82 say $out "";
83 say $out Dump(\%feature);
84 close $out;
85
86 exit 0;
87
88 sub stick_content_in_hash
89 {
90     my ($key, $title, $hash) = @_;
91     my $ukey = ucfirst $key;
92
93     my $space_to_underscore = sub {
94         my $txt = shift;
95         $txt =~ s/ /_/g;
96         $txt;
97     };
98
99     my $count = 0;
100     get_embeddedin(
101         $title,
102         sub {
103             my ($links) = @_;
104             my (@links) = @$links;
105             ok(1, "    ... got " . scalar(@links) . " more links");
106             for my $link (@links) {
107                 $count++;
108                 my $title = $link->{title};
109
110                 if ($title =~ /^$ukey:(?<key_name>.*?)$/) {
111                     # English by default
112                     $hash->{en}->{$key}->{ $space_to_underscore->($+{key_name}) } = $title;
113                 } elsif ($title =~ /^(?<lang>[^:]+):$ukey:(?<key_name>.*?)$/) {
114                     $hash->{lc $+{lang}}->{$key}->{ $space_to_underscore->($+{key_name}) } = $title;
115                 }
116             }
117         }
118     );
119
120     return $count;
121 }
122
123 sub get_embeddedin
124 {
125     my ($title, $callback) = @_;
126     my $articles = $mw->list(
127         {
128             action => 'query',
129             list => 'embeddedin',
130             eititle => $title,
131             eifilterredir => 'all',
132             # Doesn't work for De:* and anything non-en. Odd.
133             # einamespace => '0|8',
134             eilimit => '200',
135         },
136         {
137             max => '0',
138             hook => $callback,
139             skip_encoding => 1,
140         }
141     ) || die $mw->{error}->{code} . ': ' . $mw->{error}->{details};
142 }
143
144 sub help
145 {
146     my %arg = @_;
147
148     Pod::Usage::pod2usage(
149         -verbose => $arg{ verbose },
150         -exitval => $arg{ exitval } || 0,
151     );
152 }